Topic: Why is this code ca not detect viewport in new file?

[HasanCAD]

I added this code in startup.
It is working with saved files but with new file can not detect viewports

Code - Auto/Visual Lisp: [Select]

1. (setq ViewPortTrgtLyr "0") ;Change Target Layer
2. (setq ViewPortcnt 0)
3. (if (setq ss (ssget "_X" '((0 . "VIEWPORT"))))
4.   (while
5.     (setq ViewPortcntent (ssname ss ViewPortcnt))
6.     (setq ViewPortcntententVL (vlax-ename->vla-object ViewPortcntent))
7.     (vla-put-layer ViewPortcntententVL ViewPortTrgtLyr)
8.     (vla-put-color ViewPortcntententVL 256)
9.     (vla-put-displaylocked ViewPortcntententVL :vlax-true)
10.     (setq ViewPortcnt (1+ ViewPortcnt))
11.     )
12.   )
13. )

Thanks

[roy_043]

This is because your new files do not contain "VIEWPORT" entities.
You may think they do because when you activate a PS layout there is a VP. But this VP has been newly created (notice how any existing MS geometry always fits perfectly inside this VP).

A simple test:
Open an existing dwg with 2 layouts each with 1 VP on the layout:

Code: [Select]

(sslength (ssget "_X" '((0 . "VIEWPORT")))) => 4Create a new layout:

Code: [Select]

(sslength (ssget "_X" '((0 . "VIEWPORT")))) => 4Activate the new layout:

Code: [Select]

(sslength (ssget "_X" '((0 . "VIEWPORT")))) => 6

[Lee Mac]

Perhaps use a vlr-miscellaneous-reactor with callback function triggered on the layoutswitched event.

[HasanCAD]

So is this good solution

Code - Auto/Visual Lisp: [Select]

1. (setq ViewPortTrgtLyr "0") ;Change Target Layer
2. (setq ViewPortcnt 0)
3. (if (= (getvar 'dwgtitled) 1)
4.   (if(> (setq ss (sslength (ssget "_X" '((0 . "VIEWPORT"))))) 0 )
5.     (while
6.       (setq ViewPortcntent (ssname ss ViewPortcnt))
7.       (setq ViewPortcntententVL (vlax-ename->vla-object ViewPortcntent))
8.       (vla-put-layer ViewPortcntententVL ViewPortTrgtLyr)
9.       (vla-put-color ViewPortcntententVL 256)
10.       (vla-put-displaylocked ViewPortcntententVL :vlax-true)
11.       (setq ViewPortcnt (1+ ViewPortcnt))
12.       )
13.     )
14.   (setq ss 0)
15.   )
16. (princ (strcat (rtos ssl 2 0) " Viewports Moved to Layer " ViewPortTrgtLyr ))
17. (Princ)

[HasanCAD]

Perhaps use a vlr-miscellaneous-reactor with callback function triggered on the layoutswitched event.

 
In fact this high level of coding is greater than my poor level
 

[roy_043]

So is this good solution...

I don't think your code works.
FWIW: My suggestion:

Code - Auto/Visual Lisp: [Select]

1. (setq ViewPortTrgtLyr "0") ; Change Target Layer.
2. (if (setq ss (ssget "_X" '((0 . "VIEWPORT") (-4 . "<NOT") (69 . 1) (-4 . "NOT>")))) ; Skip the main PS VP.
3.   (progn
4.     (setq ViewPortCnt 0)
5.     (repeat (sslength ss)
6.       (setq ViewPortEnt (ssname ss ViewPortCnt))
7.       (setq ViewPortObj (vlax-ename->vla-object ViewPortEnt))
8.       (vla-put-layer ViewPortObj ViewPortTrgtLyr)
9.       (vla-put-color ViewPortObj 256)
10.       (vla-put-displaylocked ViewPortObj :vlax-true)
11.       (setq ViewPortCnt (1+ ViewPortCnt))
12.     )
13.     (princ (strcat "\n" (itoa ViewPortCnt) " Viewports Moved to Layer " ViewPortTrgtLyr))
14.   )
15.   (princ "\nNo Viewports ")
16. )

[HasanCAD]

Suppose the new file is very light
What about this

Code - Auto/Visual Lisp: [Select]

1. (if (= (getvar 'dwgtitled) 0)
2.   (progn
3.     (setq Ctab (getvar "CTAB"))
4.     (foreach Layout (layoutlist) (vl-cmdf "LAYOUT" "S" Layout))
5.     (setvar "CTAB" Ctab)))
6. (if (and
7.       (setq ViewPortTrgtLyr "0") ;Change Target Layer
8.       (setq ViewPortcnt 0)
9.      (setq ss (ssget "_X" '((0 . "VIEWPORT") (-4 . "<NOT") (69 . 1) (-4 . "NOT>")))) ; Skip the main PS VP.      
10.       )
11.   (progn
12.     (setq ViewPortCnt 0)
13.     (repeat (sslength ss)
14.       (setq ViewPortcntent (ssname ss ViewPortcnt))
15.       (setq ViewPortcntententVL (vlax-ename->vla-object ViewPortcntent))
16.       (vla-put-layer ViewPortcntententVL ViewPortTrgtLyr)
17.       (vla-put-color ViewPortcntententVL 256)
18.       (vla-put-displaylocked ViewPortcntententVL :vlax-true)
19.       (setq ViewPortcnt (1+ ViewPortcnt))
20.       )
21.     (princ (strcat "\n" (itoa ViewPortCnt) " Viewports Moved to Layer " ViewPortTrgtLyr))
22.     )
23.   (princ "\nNo Viewports ")
24.   )

[Lee Mac]

Perhaps use a vlr-miscellaneous-reactor with callback function triggered on the layoutswitched event.

 
In fact this high level of coding is greater than my poor level
 

Try something like this:

Code - Auto/Visual Lisp: [Select]

1. (defun fixvports ( a b / i o s )
2.     (if (setq s (ssget "_X" '((0 . "VIEWPORT") (-4 . "<>") (69 . 1))))
3.         (repeat (setq i (sslength s))
4.             (if (vlax-write-enabled-p (setq o (vlax-ename->vla-object (ssname s (setq i (1- i))))))
5.                 (progn
6.                     (vla-put-layer o "0")
7.                     (vla-put-color o acbylayer)
8.                     (vla-put-displaylocked o :vlax-true)
9.                 )
10.             )
11.         )
12.     )
13.     (princ)
14. )
15. (   (lambda nil (vl-load-com)
16.         (foreach rtr (cdar (vlr-reactors :vlr-miscellaneous-reactor))
17.             (if (= "fixvports-reactor" (vlr-data rtr))
18.                 (vlr-remove rtr)
19.             )
20.         )
21.         (fixvports nil nil)
22.         (vlr-miscellaneous-reactor "fixvports-reactor"
23.            '((:vlr-layoutswitched . fixvports))
24.         )
25.         (princ)
26.     )
27. )

[HasanCAD]

Thanks Lee