Topic: Trailing zero issue

[Biscuits]

Good morning all. In using AutoCAD 2013 with Windows 7, the following routine is designed to get the scale of a block called "Border" and rename a particular dimstyle to that value. Regardless of what my units are set at, I get trailing zero's in the renaming process. Any ideas how to correct this issue? Any help would be appreciated...thanks

Code: [Select]

(defun C:STUFF  (/ EE ENT ELIST X)


(setq flag (tblsearch "BLOCK" "Border")) ;looking for Border
;then do this if exist
(if flag
(progn ;grouping statement
 
(setq ee nil)
(setq ee (ssget "X" (list (cons 2 "Border"))))
(setq ent (ssname ee 0)) ;
(setq elist (entget ent)) ; entity list
(setq XB (cdr (assoc 41 elist))) ; X Scale -- 42 Y -- 43 Z


   (princ)

(command "-rename" "D" "Default - Fraction (ANSI)" XB  )

) ;end statement group
;else - and give warning if it doesn't exist
(alert "Border does not exist!")
) ; end if
)


[ronjonp]

Just a guess:

Code - Auto/Visual Lisp: [Select]

1. (vl-string-right-trim "0" (vl-princ-to-string xb))

[Biscuits]

Thank you Sensei.... I added decimal in front of the zero and it works perfect.

[ronjonp]

Thank you Sensei.... I added decimal in front of the zero and it works perfect.

  Glad to help.

[Biscuits]

One issue has come up with this. When a scale of 10, 20, 30, etc. is found the dimstyle in question is renamed 1, 2, 3 etc..
I only want the decimal and following zeros removed. Any ideas?
Thanks

[Crank]

Study the lisp function RTOS and the DIMZIN variable.

[ronjonp]

Perhaps this:

Code - Auto/Visual Lisp: [Select]

1. (setq xb 30.25000)
2. (if (= (type xb) 'real)
3.   (vl-string-right-trim "." (vl-string-right-trim "0" (vl-princ-to-string xb)))
4.   (itoa xb)
5. )

[Lee Mac]

Alternatively, as Crank suggests:

Code - Auto/Visual Lisp: [Select]

1. ;; Number to String  -  Lee Mac
2. ;; Converts a supplied numerical argument to a string
3.  
4. (defun LM:num->str ( num / dim rtn )
5.     (if (equal num (atoi (rtos num 2 0)) 1e-8)
6.         (rtos num 2 0)
7.         (progn
8.             (setq dim (getvar 'dimzin))
9.             (setvar 'dimzin 8)
10.             (setq rtn (rtos num 2 8))
11.             (setvar 'dimzin dim)
12.             rtn
13.         )
14.     )
15. )

Code - Auto/Visual Lisp: [Select]

1. _$ (LM:num->str 30.2500)
2. "30.25"
3. _$ (LM:num->str 30)
4. "30"

[Biscuits]

Works great!
Thanks a lot guys.........we're cookin' with gas now.

[ChrisCarlson]

Alternatively, as Crank suggests:

Code - Auto/Visual Lisp: [Select]

1. ;; Number to String  -  Lee Mac
2. ;; Converts a supplied numerical argument to a string
3.  
4. (defun LM:num->str ( num / dim rtn )
5.     (if (equal num (atoi (rtos num 2 0)) 1e-8)
6.         (rtos num 2 0)
7.         (progn
8.             (setq dim (getvar 'dimzin))
9.             (setvar 'dimzin 8)
10.             (setq rtn (rtos num 2 8))
11.             (setvar 'dimzin dim)
12.             rtn
13.         )
14.     )
15. )

Code - Auto/Visual Lisp: [Select]

1. _$ (LM:num->str 30.2500)
2. "30.25"
3. _$ (LM:num->str 30)
4. "30"

If I'm reading this correctly its an expanded conversion which will take any numerical value (real, integer and angle) and export as a string?

[Lee Mac]

If I'm reading this correctly its an expanded conversion which will take any numerical value (real, integer and angle) and export as a string?

I'm not quite sure what you mean by 'expanded conversion', but the function I have posted will accept any numerical value and will convert the value to a decimal format string with up to 8 decimal places of precision, excluding all trailing zeros. Doubles within 1e-8 of an integer value will be expressed as integers.

Note that there are only two types of numerical values in AutoLISP: integers (represented using signed 32-bit integers) and reals (represented using 64-bit double-precision floating point format); angles may be represented using either of these data types. However, it is usually more useful to use the angtos function for angle formatting.