Topic: - = { Challenge } = - transform UCS along with entities

[ribarm]

I have a task to perform with commands for modify objects, only now I wish it's applicable to both entities along with UCS entity... I know it's doable, but it would be nice to make it simple like typing original command at command prompt with suffix or prefix for UCS (for ex. rotate3d-U)... It would be nice if all modify commands could be used with calling correct cmdname with just single master routine (code) applicable for all commands for modify... I am little lazy now, but it's just a thought and I don't know if it would be much useful, but if it was possible to make UCS follow VIEW change than this is no big difference only more options to consider (rotate3d, mirror3d, align, rotate, mirror, scale, stretch, move, copy ...) Or I am just silly, no one would need this operational... Maybe to create command reactor that will trigger UCS modification but with the same parameters used while command is processed...

[ribarm]

1. Of course, with mirror or mirror3d commands, you should think if you should invert Z axis of UCS and mark that UCS (-1), so that when used (trans) function correct result should be obtained (trans function should be unchanged) only when computing point to be transformed that (-1) sign of UCS should automatically multiply Z coordinate of point with -1... Maybe for better viewing (blue) color from Z arrow of UCS to be changed to (yellow)...

2. Or this all is complication UCS axis shouldn't be inverted at all while mirror or mirror3d, but then it should point at opposite direction from before transformation so that 3 finger rule wouldn't change (after mirror or mirror3d z coordinate of all transformed entities would become Z original * (-1)...

As my first comment involve more complex change (maybe in future CAD development), I suggest that for start UCS transformation for those commands be like described in my second comment...

[ribarm]

Here is my first attempt on the subject...

It's very simple, so don't laugh...

Code - Auto/Visual Lisp: [Select]

1. (defun c:modents+ucs ( / *error* *adoc* cmde cmd ss xli yli zli o x y z )
2.  
3.   (vl-load-com)
4.  
5.   (defun *error* ( msg )
6.     (if cmde (setvar 'cmdecho cmde))
7.     (if (and xli (entget xli)) (entdel xli))
8.     (if (and yli (entget yli)) (entdel yli))
9.     (if (and zli (entget zli)) (entdel zli))
10.     (if msg (prompt msg))
11.     (vla-endundomark *adoc*)
12.     (command "_.UNDO" "")
13.     (princ)
14.   )
15.  
16.   (setq *adoc* (vla-get-activedocument (vlax-get-acad-object)))
17.   (vla-startundomark *adoc*)
18.   (setq cmde (getvar 'cmdecho))
19.   (setvar 'cmdecho 1)
20.   (initget 1 "MOVE ALIGN ROTATE MIRROR SCALE ROTATE3D 3DMIRROR 3DROTATE STRETCH")
21.   (setq cmd (getkword "\nENTER COMMAND [MOve/ALign/ROtate/MIrror/SCale/ROTATE3D/3DMIrror/3DROtate/STretch] : "))
22.   (prompt "\nSelect object(s) - (ENTER : APPLY COMMAND ONLY TO UCS)...")
23.   (setq ss (ssget "_:L"))
24.   (if (null ss) (setq ss (ssadd)))
25.   (if (eq cmd "3DMIRROR") (setq cmd "MIRROR3D"))
26.   (setq xli (entmakex (list '(0 . "LINE") '(62 . 1) (cons 10 (trans '(0.0 0.0 0.0) 1 0)) (cons 11 (trans '(1.0 0.0 0.0) 1 0)))))
27.   (setq yli (entmakex (list '(0 . "LINE") '(62 . 3) (cons 10 (trans '(0.0 0.0 0.0) 1 0)) (cons 11 (trans '(0.0 1.0 0.0) 1 0)))))
28.   (setq zli (entmakex (list '(0 . "LINE") '(62 . 5) (cons 10 (trans '(0.0 0.0 0.0) 1 0)) (cons 11 (trans '(0.0 0.0 1.0) 1 0)))))
29.   (ssadd xli ss)
30.   (ssadd yli ss)
31.   (ssadd zli ss)
32.   (cond
33.     ( (eq (strcase cmd) "MIRROR")
34.       (command cmd ss "" "\\" "\\" "Y")
35.     )
36.     ( (eq (strcase cmd) "MIRROR3D")
37.       (alert "When asked : Delete source objects? - answer : (Y)es and press ENTER twice...")
38.       (command cmd ss "")
39.       (while (> (getvar 'cmdactive) 0) (command "\\"))
40.     )
41.     ( (eq (strcase cmd) "ALIGN")
42.       (alert "When align command completes and marker icon was aligned press ENTER to change UCS to marker...")
43.       (command cmd ss "")
44.       (while (> (getvar 'cmdactive) 0) (command "\\"))
45.     )
46.     ( t
47.       (command cmd ss "")
48.       (while (> (getvar 'cmdactive) 0) (command "\\"))
49.     )
50.   )
51.   (setq o (trans (cdr (assoc 10 (entget xli))) 0 1))
52.   (setq x (trans (cdr (assoc 11 (entget xli))) 0 1))
53.   (setq y (trans (cdr (assoc 11 (entget yli))) 0 1))
54.   (setq z (trans (cdr (assoc 11 (entget zli))) 0 1))
55.   (entdel xli)
56.   (entdel yli)
57.   (entdel zli)
58.   (command "_.UCS" "_3P" "_non" o "_non" x "_non" y)
59.   (princ)
60. )
61.  
62. (defun c:meu nil (c:modents+ucs))
63.  

M.R.