Topic: Get Polyline inside Polyline

[pedroantonio123]

Hi

anyone have any idea why the object is not found within the Polyline?
For simpler objects such as a rectangle the code works.

Code: [Select]

(defun c:test ( / cdrs plEnt plList ss)

(defun cdrs (DxfKey ImpLst / TmpLst OutLst)
(while (setq TmpLst (assoc DxfKey ImpLst))
(setq OutLst (cons (trans (cdr TmpLst) 0 1) OutLst)
ImpLst (cdr (member TmpLst ImpLst))
)
)
(reverse OutLst)
)

(setq plEnt (entget (car (entsel "\nSelect pline:"))))
(setq plList (cdrs 10 plEnt))
(setq ss (ssget "_WP" plList))

)

Pedro

[hmspe]

Your code works in your test drawing when I run it in Bricscad.

[Lee Mac]

Is the object fully visible in the drawing area when the ssget expression is evaluated? - Note that graphical selection methods such as WP/CP etc will only select objects that reside in the visible drawing area (I believe this is a consequence of the method used by AutoCAD to determine which objects fall within a selection window/polygon).

[pedroantonio123]

Hi Lee,

the object is fully visible,
maybe it has to do with the length of the list passed to ssget?
perhaps there is another method to get the object?
Pedro

[Marc'Antonio Alessi]

Modify this line:
    (setq plList (cdrs 10 plEnt))
to:
    (setq plList (ALE_List_RemoveDupOnLst (cdrs 10 plEnt)))

Code: [Select]

; Function: ALE_List_RemoveDupes
;
; Version 1.00 - 9 Apr 2003
;
; Description:
;   removes all the duplicated elements leaving originals,
;   faster on lists with low number of duplicates
;   For example:
;   (setq alist (atoms-family 1))
;   (setq alist (append alist alist alist alist))
;
; Arguments:
;   In_Lst = A list
;
(defun ALE_List_RemoveDupOnLst (In_Lst / OutLst)
  (reverse
    (foreach ForElm In_Lst
      (if (vl-position ForElm OutLst)
        OutLst
        (setq OutLst (cons ForElm OutLst))
      )
    )
  )
)

[ronjonp]

You will also run into trouble if the polyline is self intersecting.

[pedroantonio123]

Thanks  Marc'Antonio     it works.

[Marc'Antonio Alessi]

Thanks  Marc'Antonio     it works.

Prego, look also at ronjonp warning. 

[lamarn]

follwing the idea to get objects within a closed (not self-intersecting) polyline i was trying to use this to get ALL elements, not just polylines.
This would be beneficial when working with the tool for manupulating viewport. I was thinking the cdrs statement has to be tuned to get this idea working..