Topic: LISP to populate attributes in hidden visibility state.

[jpcadconsulting]

Hi folks.

I have a LISP routine that inserts a block and populates its attributes, however it's only populating the attributes that are in the visibility state that is current when the block is inserted.  Heres the code:

Code: [Select]

(defun c:workpoint (/ CRDX CRDY CRDXY ADT P)
(setq atd (getvar 'ATTDIA))
(setvar 'ATTDIA 0)
(while (setq p (getpoint "\n Specify point :"))
(setq CRDX (rtos (car p) 4 0))
(setq CRDY (rtos (cadr p) 4 0))
(setq CRDXY (strcat "(" CRDX ", " CRDY ")"))
  (command "_.-insert"
           "SW Coordinates Tag r00"
           "_none"
           p
           ""
           ""
           ""
           CRDXY
           CRDX
           CRDY
  )
)
(setvar 'ATTDIA atd)
)
The variables CRDX and CRDY are correct but the attributes they populate are in a visibility state that is OFF so... it ain't working.

Anyone know how to assign values to attributes in the "non current" visibility state?

Any help is appreciated, as always.

[ronjonp]

Why aren't you using a field for this? Here's some code to get you started .. you'll have to provide the name of the tag you are trying to fill in.

Code - Auto/Visual Lisp: [Select]

1. (defun c:workpoint (/ b blockname p tag)
2.   (vl-load-com)
3.   ;; The name of your block
4.   (setq blockname "SW Coordinates Tag r00")
5.   ;; The name of the tag you want to fill in
6.   (setq tag "COORDS")
7.   (defun _getactivespace (/ ad)
8.     (setq ad (vla-get-activedocument (vlax-get-acad-object)))
9.     (if (= (getvar 'cvport) 1)
10.       (vla-get-paperspace ad)
11.       (vla-get-modelspace ad)
12.     )
13.   )
14.   ;; (_getactivespace)
15.   (defun _insertblock (blockname point scale rotation / b blk e spc)
16.     (if (and blockname
17.              (setq spc (_getactivespace))
18.              (if (wcmatch (strcase blockname) "*.DWG")
19.                (setq b (vl-filename-base blockname))
20.                (setq b blockname)
21.              )
22.              (or (tblobjname "block" b) (findfile (setq b (strcat b ".dwg"))))
23.         )
24.       (setq blk (vla-insertblock spc (vlax-3d-point point) b scale scale scale rotation))
25.     )
26.     blk
27.   )
28.   ;; (_insertblock "foo" (trans (getpoint) 1 0) 5 0)
29.   (defun _putattvalue (block tag value / att flag)
30.     (foreach att (vlax-invoke block 'getattributes)
31.       (if (eq (strcase tag) (strcase (vla-get-tagstring att)))
32.         (progn (vla-put-textstring
33.                  att
34.                  (if (= (type value) 'str)
35.                    value
36.                    (vl-princ-to-string value)
37.                  )
38.                )
39.                (setq flag value)
40.         )
41.       )
42.     )
43.     flag
44.   )
45.   ;; (_putattvalue (car (entsel)) "tagname" "1")
46.   (while (setq p (getpoint "\n Specify point :"))
47.     (if (setq b (_insertblock blockname (trans p 1 0) 1 0))
48.       (_putattvalue b tag (strcat "(" (rtos (car p) 4 0) ", " (rtos (cadr p) 4 0) ")"))
49.     )
50.   )
51.   (princ)
52. )

[jpcadconsulting]

Ah! The crux of the issue.

It seems that using fields will always result in coordinate values in relation to the World Coordinate System, even if a different User Coordiante System is current.

http://knowledge.autodesk.com/support/autocad/troubleshooting/caas/sfdcarticles/sfdcarticles/Object-fields-displaying-coordinate-information-relative-to-the-World-UCS.html

My client needs the blocks to represent the X,Y values in relation to 0,0,in the current User Coordinate System.

[jpcadconsulting]

And thanks for the code ronjonp!!!