Topic: Fasted way to find a closed polyline by point inside

[Marc'Antonio Alessi]

maybe the solution is very simple...
As in subject: fasted way to find a closed polyline.
 known data:
 - internal point
 - polyline layer

[ChrisCarlson]

Code - Auto/Visual Lisp: [Select]

1. (sssetfirst nil (setq a (ssget "_X" '((8 . "LAYER")(0 . "LWPOLYLINE") (70 . 1)) )))
2.  

Not sure what you mean by internal point? What if you have a polyline within a polyline?

[Marc'Antonio Alessi]

Not sure what you mean by internal point? What if you have a polyline within a polyline?

Normally there is not this possibility,  if there could be also the first polyline found can be good.

[RC]

do you mean something similar to the BOUNDARY command???

[gile]

Hi

Just a thought:

Code - Auto/Visual Lisp: [Select]

1. (if (setq ss
2.            (ssget
3.              "_F"
4.              (list internalPoint (getvar 'extmin))
5.              (list '(0 . "lwpolyline") (cons 8 layerName) '(-4 . "&") '(70 . 1))
6.            )
7.     )
8.   (ssname ss 0)
9. )

[ribarm]

Here, try this...

Code - Auto/Visual Lisp: [Select]

1. (defun selcllwbypt+lay (pt         layer      /          rlw
2.                         member-fuzz           2nd        ss
3.                         lw         lwr        lwdxf10dxf42
4.                         lwdxf10dxf42g         lwrdxf10dxf42
5.                         lwrdxf10dxf42g        i          lwe
6.                         lwd        lwdg       e          el
7.                        )
8.  
9.   (defun rlw (lw / e x1 x2 x3 x4 x5 x6)
10.     ;; by ElpanovEvgeniy
11.     ;; reverse lwpolyline
12.     (if (= (cdr (assoc 0 (setq e (entget lw)))) "LWPOLYLINE")
13.       (progn
14.         (foreach a1 e
15.           (cond ((= (car a1) 10) (setq x2 (cons a1 x2)))
16.                 ((= (car a1) 40) (setq x4 (cons (cons 41 (cdr a1)) x4)))
17.                 ((= (car a1) 41) (setq x3 (cons (cons 40 (cdr a1)) x3)))
18.                 ((= (car a1) 42)
19.                  (setq x5 (cons (cons 42 (- (cdr a1))) x5))
20.                 )
21.                 ((= (car a1) 210) (setq x6 (cons a1 x6)))
22.                 (t (setq x1 (cons a1 x1)))
23.           )
24.         )
25.         (entmod
26.           (append
27.             (reverse x1)
28.             (append
29.               (apply
30.                 (function append)
31.                 (apply
32.                   (function mapcar)
33.                   (cons
34.                     'list
35.                     (list x2
36.                           (cdr (reverse (cons (car x3) (reverse x3))))
37.                           (cdr (reverse (cons (car x4) (reverse x4))))
38.                           (cdr (reverse (cons (car x5) (reverse x5))))
39.                     )
40.                   )
41.                 )
42.               )
43.               x6
44.             )
45.           )
46.         )
47.         (entupd lw)
48.       )
49.     )
50.   )
51.  
52.   (defun member-fuzz (e l f)
53.     (vl-member-if
54.       (function
55.         (lambda (x)
56.           (and (equal (car x) (car e) f) (equal (cadr x) (cadr e) f))
57.         )
58.       )
59.       l
60.     )
61.   )
62.  
63.   (defun 2nd (lst)
64.     (if lst (cons (car lst) (2nd (cddr lst))))
65.   )
66.  
67.   (setq el (entlast))
68.   (setq ss (ssget "_A"
69.                   (list '(0 . "LWPOLYLINE")
70.                         (cons 8 layer)
71.                         '(-4 . "&=")
72.                         '(70 . 1)
73.                         (cons 410 (if (= 1 (getvar 'cvport)) (getvar 'ctab) "Model"))
74.                   )
75.            )
76.   )
77.   (command "_.SELECT" ss "")
78.   (command "_.-BOUNDARY"     "_A"     "_B"     "_N"     "_P"
79.            ""       "_I"     "_Y"     "_O"     "_P"     "_X"
80.            pt       ""
81.           )
82.   (if (not (eq el (entlast)))
83.     (progn
84.       (setq lw (entget (entlast)))
85.       (setq lwr (entget (rlw (entlast))))
86.       (setq lwdxf10dxf42
87.              (vl-remove-if-not
88.                (function (lambda (x) (or (eq (car x) 10) (eq (car x) 42))))
89.                lw
90.              )
91.       )
92.       (setq lwdxf10dxf42g
93.              (mapcar (function (lambda (a b) (list a b)))
94.                      (2nd lwdxf10dxf42)
95.                      (2nd (cdr lwdxf10dxf42))
96.              )
97.       )
98.       (setq lwrdxf10dxf42
99.              (vl-remove-if-not
100.                (function (lambda (x) (or (eq (car x) 10) (eq (car x) 42))))
101.                lwr
102.              )
103.       )
104.       (setq lwrdxf10dxf42g
105.              (mapcar (function (lambda (a b) (list a b)))
106.                      (2nd lwrdxf10dxf42)
107.                      (2nd (cdr lwrdxf10dxf42))
108.              )
109.       )
110.       (setq i -1)
111.       (while (and (not e) (setq lwe (ssname ss (setq i (1+ i)))))
112.         (setq lwd
113.                (vl-remove-if-not
114.                  (function (lambda (x) (or (eq (car x) 10) (eq (car x) 42))))
115.                  (entget lwe)
116.                )
117.         )
118.         (setq
119.           lwdg (mapcar (function (lambda (a b) (list a b)))
120.                        (2nd lwd)
121.                        (2nd (cdr lwd))
122.                )
123.         )
124.         (if
125.           (or
126.             (vl-every
127.               (function (lambda (x) (member-fuzz x lwdxf10dxf42g 1e-4)))
128.               lwdg
129.             )
130.             (vl-every
131.               (function (lambda (x) (member-fuzz x lwrdxf10dxf42g 1e-4)))
132.               lwdg
133.             )
134.           )
135.            (setq e lwe)
136.         )
137.       )
138.       (entdel (entlast))
139.       (if e (sssetfirst nil (ssadd e)))
140.     )
141.   )
142.   (princ)
143. )
144.  

[Lee Mac]

Here's a quickly written ray-casting method, compatible with straight-segmented polylines only:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / e p )
2.     (if (setq p (getpoint "\nSpecify point: "))
3.         (if (setq e (polyfrominsidepoint p))
4.             (sssetfirst nil (ssadd e))
5.             (princ "\nNo polyline found.")
6.         )
7.     )
8.     (princ)
9. )
10. (defun polyfrominsidepoint ( p / e i r s )
11.     (if
12.         (setq i -1 s
13.             (ssget "_X"
14.                 (list '(0 . "LWPOLYLINE") '(-4 . "&=") '(70 . 1)
15.                     (if (= 1 (getvar 'cvport))
16.                         (cons 410 (getvar 'ctab))
17.                        '(410 . "Model")
18.                     )
19.                 )
20.             )
21.         )
22.         (while (and (null r) (setq e (ssname s (setq i (1+ i)))))
23.             (if (raycast p (mapcar 'cdr (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) (entget e))))
24.                 (setq r e)
25.             )
26.         )
27.     )
28.     r
29. )
30. (defun raycast ( p l )
31.     (= 1
32.         (logand 1
33.             (length
34.                 (vl-remove 'nil
35.                     (mapcar
36.                        '(lambda ( a b ) (inters p (mapcar '+ p '(1e8 0.0)) a b))
37.                         (cons (last l) l)
38.                         l
39.                     )
40.                 )
41.             )
42.         )
43.     )
44. )
45. (princ)

[roy_043]

The raycasting method has a fundamental flaw:
http://ww3.cad.de/foren/ubb/Forum145/HTML/000602.shtml#000008

Try KGA_Geom_PointInsidePointList_P instead:

Code - Auto/Visual Lisp: [Select]

1. ; 20140220
2. ; See: http://paulbourke.net/geometry/polygonmesh/
3. (defun KGA_Geom_PointInsidePointList_P (pt ptLst)
4.   (<
5.     pi
6.     ;; The absolute value of the total angle is 2pi for an inside point.
7.     (abs
8.       (apply
9.         '+
10.         (mapcar
11.           '(lambda (pt1 pt2)
12.             (KGA_Geom_Angle pt1 pt pt2)
13.           )
14.           ptLst
15.           (append (cdr ptLst) (list (car ptLst)))
16.         )
17.       )
18.     )
19.   )
20. )
21.  
22. ; 20140220
23. ; Return value: -pi <= angle <= pi
24. (defun KGA_Geom_Angle (pt1 pt2 pt3 / ang)
25.   (cond
26.     ((<= (- pi) (setq ang (- (angle pt2 pt3) (angle pt2 pt1))) pi)
27.       ang
28.     )
29.     ((minusp ang)
30.       (+ ang pi pi)
31.     )
32.     (T
33.       (- ang pi pi)
34.     )
35.   )
36. )

[Marc'Antonio Alessi]

First of all thank you all for the answers:

@gile: this is good for another case that I have to solve, but in this case it select too many objects
using: (getvar 'extmin).

roy_043: I do not have the point list to use your function I only have a point

I try Lee Mac or ribarm (more complex) suggestion.
I'll see if I have problems.

Grazie ancora.

[Stefan]

The initial selection set can be reduced using a filter on coordinates

Code - Auto/Visual Lisp: [Select]

1. (defun c:test (/ p)
2.   (if
3.     (setq p (getpoint "\nSelect point: "))
4.     (sssetfirst nil
5.       (ssget "X"
6.              (list '(0 . "LWPOLYLINE")
7.                    '(8 . "Layer");<----
8.                    '(70 . 1)
9.                    '(-4 . ">=,>=,*") (cons 10 p)
10.                    '(-4 . "<=,<=,*") (cons 10 p)
11.              )
12.       )
13.     )
14.   )
15.   (princ)
16. )

If, by any chance, there are only rectangles in WCS, this is all you need. Complex objects requires a checking routine.

[GP]

@gile: this is good for another case that I have to solve, but in this case it select too many objects
using: (getvar 'extmin).

(ssname ss 0)
You select only the first object (crossed by "fence")

Ciao

[roy_043]

roy_043: I do not have the point list to use your function I only have a point

My KGA_Geom_PointInsidePointList_P function is an alternative for Lee's raycast function. Both functions take a point and a point list as arguments.

[ribarm]

@gile: this is good for another case that I have to solve, but in this case it select too many objects
using: (getvar 'extmin).

(ssname ss 0)
You select only the first object (crossed by "fence")

Ciao

And you have to be in visible screen while running lisp... With my function that's not important...

Ciao

[Marc'Antonio Alessi]

roy_043: I do not have the point list to use your function I only have a point

My KGA_Geom_PointInsidePointList_P function is an alternative for Lee's raycast function. Both functions take a point and a point list as arguments.

Ok I understand, sorry for the misinterpretation and thanks again.
Ciao.

[Marc'Antonio Alessi]

I think I have many options to choose from, I'll try in a real drawing to find the faster and I will tell you my opinion.
Thank you all.

[Marc'Antonio Alessi]

I have edited many functions to work also with "non closed" LWPOLYLINE see "(70 . 1)",
these are the results, all comments are well accepted, attach files and test DWG:

test_Stefan     > 1 error
selcllwbypt+lay > 4 errors

Code: [Select]

    (GILE_TEST INTERNALPOINT LAYERNAME)...........1186 / 12.27 <fastest>
    (TEST_STEFAN INTERNALPOINT LAYERNAME).........1373 / 10.6
    (POLYFROMINSIDEPOINT_KGA INTERNALPOINT).......5273 / 2.76
    (POLYFROMINSIDEPOINT INTERNALPOINT)...........5632 / 2.58
    (SELCLLWBYPT+LAY INTERNALPOINT LAYER...).....14555 / 1 <slowest>

    (TEST_STEFAN INTERNALPOINT LAYERNAME)........1810 / 5.83 <fastest>
    (GILE_TEST INTERNALPOINT LAYERNAME)..........2137 / 4.93
    (POLYFROMINSIDEPOINT_KGA INTERNALPOINT)......6568 / 1.61
    (POLYFROMINSIDEPOINT INTERNALPOINT).........10545 / 1 <slowest>

    (GILE_TEST INTERNALPOINT LAYERNAME).........1185 / 5.45 <fastest>
    (TEST_STEFAN INTERNALPOINT LAYERNAME).......1373 / 4.7
    (POLYFROMINSIDEPOINT_KGA INTERNALPOINT).....6240 / 1.03
    (POLYFROMINSIDEPOINT INTERNALPOINT).........6458 / 1 <slowest>


[roy_043]

I don't know the context you want to use the code in, but I would not focus on speed just yet. All code examples have one or more issues:
- Bulges are not taken into account.
- Polylines may not be bisected by other polylines.
- The polyline must have an edge between the point and extmin.
- The polyline must be rectangular.
...

[ribarm]

I don't know the context you want to use the code in, but I would not focus on speed just yet. All code examples have one or more issues:
- Bulges are not taken into account.
- Polylines may not be bisected by other polylines.
- The polyline must have an edge between the point and extmin.
- The polyline must be rectangular.
...

All these issues are taken into consideration with my code... Maybe that's why it's the slowest... Or I missed something in OP's request?

[Marc'Antonio Alessi]

I don't know the context you want to use the code in, but I would not focus on speed just yet. All code examples have one or more issues:
- Bulges are not taken into account.
- Polylines may not be bisected by other polylines.
- The polyline must have an edge between the point and extmin.
- The polyline must be rectangular.
...

All these issues are taken into consideration with my code... Maybe that's why it's the slowest... Or I missed something in OP's request?

Marko did you seen my dwg?  There are 4 errors (selcllwbypt+lay > 4 errors)...

[ribarm]

Marko did you seen my dwg?  There are 4 errors (selcllwbypt+lay > 4 errors)...

Yes, the problem is fuzz factor... Change 1e-10 to 1e-4 and it'll work...

[EDIT] : I've updated code in my post... Test it now... [/EDIT]

[roy_043]

All these issues are taken into consideration with my code... Maybe that's why it's the slowest... Or I missed something in OP's request?

I find that your code does not work if a polyline is bisected by another and if I click a point that is internal to the first and external to the second. Note: I use BricsCAD.

[Marc'Antonio Alessi]

Marko did you seen my dwg?  There are 4 errors (selcllwbypt+lay > 4 errors)...

Yes, the problem is fuzz factor... Change 1e-10 to 1e-4 and it'll work...

[EDIT] : I've updated code in my post... Test it now... [/EDIT]

Ok, now is ok.

[Marc'Antonio Alessi]

All these issues are taken into consideration with my code... Maybe that's why it's the slowest... Or I missed something in OP's request?

I find that your code does not work if a polyline is bisected by another and if I click a point that is internal to the first and external to the second. Note: I use BricsCAD.

For this i think Lee Mac and your KGA... are OK.

[Marc'Antonio Alessi]

I don't know the context you want to use the code in, but I would not focus on speed just yet. All code examples have one or more issues:
- Bulges are not taken into account.
- Polylines may not be bisected by other polylines.
- The polyline must have an edge between the point and extmin.
- The polyline must be rectangular.
...

Sorry for the delay but I do not see my reply (about 5 hours ago) so I rewrite it:

The contest is my sample DWG:
ok - Bulges are not taken into account.
ok - Polylines may not be bisected by other polylines.
ok - The polyline must have an edge between the point and extmin.

No - The polyline must be rectangular.
Not true but many functions works in this situation.      If there is a function that satisfies all it is better...

Thanks

[Lee Mac]

The raycasting method has a fundamental flaw:
http://ww3.cad.de/foren/ubb/Forum145/HTML/000602.shtml#000008

A messy attempt to avoid such issues:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / e p )
2.     (if (setq p (getpoint "\nSpecify point: "))
3.         (if (setq e (polyfrominsidepoint p))
4.             (sssetfirst nil (ssadd e))
5.             (princ "\nNo polyline found.")
6.         )
7.     )
8.     (princ)
9. )
10. (defun polyfrominsidepoint ( p / e i r s )
11.     (if
12.         (setq i -1 s
13.             (ssget "_X"
14.                 (list '(0 . "LWPOLYLINE") '(-4 . "&=") '(70 . 1)
15.                     (if (= 1 (getvar 'cvport))
16.                         (cons 410 (getvar 'ctab))
17.                        '(410 . "Model")
18.                     )
19.                 )
20.             )
21.         )
22.         (while (and (null r) (setq e (ssname s (setq i (1+ i)))))
23.             (if (pointinsidepoly-p p (vlax-ename->vla-object e))
24.                 (setq r e)
25.             )
26.         )
27.     )
28.     r
29. )
30. (defun pointinsidepoly-p ( pnt obj )
31.     (raycast
32.         (vla-addray
33.             (vla-objectidtoobject (vla-get-document obj) (vla-get-ownerid obj))
34.             (vlax-3D-point pnt)
35.             (vlax-3D-point (mapcar '+ pnt '(1.0 0.0 0.0)))
36.         )
37.         pnt obj (groupn (vlax-get obj 'coordinates) 2)
38.     )
39. )
40. (defun raycast ( ray pnt obj vtx / lst )
41.     (if (and (setq lst (groupn (vlax-invoke ray 'intersectwith obj acextendnone) 3))
42.             (vl-some
43.                '(lambda ( x )
44.                     (or (vl-some '(lambda ( y ) (equal 0.0 (distance x y) 1e-8)) vtx)
45.                         (equal 0.0
46.                             (distance '(0.0 0.0 0.0)
47.                                 (v^v (vlax-curve-getfirstderiv obj (vlax-curve-getparamatpoint obj x))
48.                                      (mapcar '- x pnt)
49.                                 )
50.                             )
51.                             1e-8
52.                         )
53.                     )
54.                 )
55.                 lst
56.             )
57.             (< (angle '(0.0 0.0 0.0) (vlax-get ray 'directionvector)) 6)
58.         )
59.         (progn
60.             (vlax-invoke ray 'rotate pnt 0.17)
61.             (raycast ray pnt obj vtx)
62.         )
63.         (progn
64.             (vla-delete ray)
65.             (= 1 (logand 1 (length lst)))
66.         )
67.     )      
68. )
69. (defun groupn ( l n / x r )
70.     (repeat (/ (length l) n)
71.         (repeat n
72.             (setq x (cons (car l) x)
73.                   l (cdr l)
74.             )
75.         )
76.         (setq r (cons (reverse x) r)
77.               x nil
78.         )
79.     )
80.     (reverse r)
81. )
82. (defun v^v ( u v )
83.     (list
84.         (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
85.         (- (* (car  v) (caddr u)) (* (car  u) (caddr v)))
86.         (- (* (car  u) (cadr  v)) (* (car  v) (cadr  u)))
87.     )
88. )
89. (vl-load-com) (princ)

Don't expect it to be fast though!

[ribarm]

Here is my newest version... It's much more simple than previous, and it satisfies all previously mentioned issues... And it's fast enough - for my standards...

Code - Auto/Visual Lisp: [Select]

1. (defun selcllwbypt+lay-2 (pt         layer      /          insidep
2.                           el         ss         lw         i
3.                           lwe        e
4.                          )
5.  
6.   (vl-load-com)
7.  
8.   ;;======================================================================;;
9.   ;;    DETERMINING IF A POINT LIES ON THE INTERIOR OF A CLOSED ENTITY      ;;
10.   ;;======================================================================;;
11.  
12.   ;;  Idea was stoled from Eugeny Kalney
13.   ;;  http://www.k-prof.com.ru/
14.   ;;  written by Fatty The Old Horse
15.   ;;  9/29/05 edited: 9/30/05
16.  
17.   (defun insidep (pt entn / big flag obj1 obj2 obj3 p1 p2 small)
18.     (if (and pt entn)
19.       (progn
20.         (setq obj1 (vlax-ename->vla-object entn))
21.         (setq obj2 (car (vlax-invoke obj1 'Offset 0.001))
22.               obj3 (car (vlax-invoke obj1 'Offset -0.001))
23.         )
24.         (if (> (vla-get-area obj2) (vla-get-area obj3))
25.           (progn
26.             (set 'big obj2)
27.             (set 'small obj3)
28.           )
29.           (progn
30.             (set 'big obj3)
31.             (set 'small obj2)
32.           )
33.         )
34.         (setq p1 (vlax-curve-getClosestPointTo big pt)
35.               p2 (vlax-curve-getClosestPointTo small pt)
36.         )
37.         (if (> (distance pt p1) (distance pt p2))
38.           (setq flag T)
39.           (setq flag nil)
40.         )
41.         (mapcar (function (lambda (x)
42.                             (progn
43.                               (vla-delete x)
44.                               (vlax-release-object x)
45.                             )
46.                           )
47.                 )
48.                 (list big small)
49.         )
50.       )
51.     )
52.     flag
53.   )
54.  
55.   (setq el (entlast))
56.   (setq ss (ssget "_A"
57.                   (list '(0 . "LWPOLYLINE")
58.                         (cons 8 layer)
59.                         '(-4 . "&=")
60.                         '(70 . 1)
61.                         (cons 410 (if (= 1 (getvar 'cvport)) (getvar 'ctab) "Model"))
62.                   )
63.            )
64.   )
65.   (command "_.SELECT" ss "")
66.   (command "_.-BOUNDARY"     "_A"     "_B"     "_N"     "_P"
67.            ""       "_I"     "_N"     ""       "_O"     "_P"
68.            "_X"     pt       ""
69.           )
70.   (if (not (eq el (entlast)))
71.     (progn
72.       (setq lw (entlast))
73.       (setq i -1)
74.       (while (and (not e) (setq lwe (ssname ss (setq i (1+ i)))))
75.         (if
76.           (and
77.             (vlax-invoke (vlax-ename->vla-object lw) 'intersectwith (vlax-ename->vla-object lwe) acextendnone)
78.             (insidep pt lwe)
79.           )
80.           (setq e lwe)
81.         )
82.       )
83.       (entdel (entlast))
84.       (if e (sssetfirst nil (ssadd e)))
85.     )
86.   )
87.   (princ)
88. )
89.  

Regards, M.R.

[roy_043]

@ ribarm:
Your new function insidep creates two offset copies for every entity in ss. This must slow things down for large selection sets. Two other problems with this function are that the offset distance is hard-coded and that offset can create more than one new entity.

Another case to consider:
Two nested polylines without intersections and a point inside the biggest poyline only...

[Marc'Antonio Alessi]

Here is my newest version... It's much more simple than previous, and it satisfies all previously mentioned issues... And it's fast enough - for my standards...
...
Regards, M.R.

Tested on Bricscad V14: do not works. Later I will tet on AutoCAD.

[Marc'Antonio Alessi]

A messy attempt to avoid such issues:
...
Don't expect it to be fast though!

Tested on Bricscad V15:
> test_Stefan do not works (?)

Code: [Select]

Elapsed milliseconds / relative speed for 2048 iteration(s):
    (GILE_TEST INTERNALPOINT LAYERNAME)...........1638 / 19.75 <fastest>
    (POLYFROMINSIDEPOINT INTERNALPOINT)...........6926 / 4.67
    (POLYFROMINSIDEPOINT_KGA INTERNALPOINT).......8580 / 3.77
    (POLYFROMINSIDEPOINT2 INTERNALPOINT).........13494 / 2.4
    (SELCLLWBYPT+LAY INTERNALPOINT LAYER...).....32355 / 1 <slowest>

Elapsed milliseconds / relative speed for 1024 iteration(s):
    (GILE_TEST INTERNALPOINT LAYERNAME).........1451 / 6.81 <fastest>
    (POLYFROMINSIDEPOINT INTERNALPOINT).........5382 / 1.83
    (POLYFROMINSIDEPOINT_KGA INTERNALPOINT).....7488 / 1.32
    (POLYFROMINSIDEPOINT2 INTERNALPOINT)........9875 / 1 <slowest>

Elapsed milliseconds / relative speed for 2048 iteration(s):
    (GILE_TEST INTERNALPOINT LAYERNAME)..........1825 / 11.39 <fastest>
    (POLYFROMINSIDEPOINT INTERNALPOINT).........12137 / 1.71
    (POLYFROMINSIDEPOINT_KGA INTERNALPOINT).....19641 / 1.06
    (POLYFROMINSIDEPOINT2 INTERNALPOINT)........20779 / 1 <slowest>
a little bit slower.

[ribarm]

@ ribarm:
Your new function insidep creates two offset copies for every entity in ss. This must slow things down for large selection sets. Two other problems with this function are that the offset distance is hard-coded and that offset can create more than one new entity.

Another case to consider:
Two nested polylines without intersections and a point inside the biggest poyline only...

Yes, it must slow things on large sel. set, but hard-coded offset value is small, so I don't think it may create more than 2 new lwpolylines... Look into OP's posted example *.dwg...

I've considered that case - updated code... Changed island detection to "_N" and chosen default ray casting method (+X)... Thanks for your remarks, Roy - they are wise...

M.R.

[Lee Mac]

A messy attempt to avoid such issues:
...
Don't expect it to be fast though!

Tested on Bricscad V15:

I'm not sure that the performance comparison between my later posted function and that posted earlier is meaningful since the first function I posted will return incorrect results under some conditions (arc-segmented polylines / ray tangent to edge etc.), and hence we are not comparing apples with apples.

[Marc'Antonio Alessi]

A messy attempt to avoid such issues:
...
Don't expect it to be fast though!

Tested on Bricscad V15:

I'm not sure that the performance comparison between my later posted function and that posted earlier is meaningful since the first function I posted will return incorrect results under some conditions (arc-segmented polylines / ray tangent to edge etc.), and hence we are not comparing apples with apples.

I agree with you, I did a new test with Briscad and thought it was interesting the comparision in the case not need the condition: "arc-segmented polylines / ray tangent to edge etc." (in my case).
Thanks again.

[ribarm]

I have one remark ab this Gile's function :

Code: [Select]

(defun gile ( internalPoint layerName )
    (if (setq ss
          (ssget
            "_F"
            (list internalPoint (getvar 'extmin))
            (list '(0 . "lwpolyline") (cons 8 layerName) '(-4 . "&") '(70 . 1))
          )
        )
        (sssetfirst nil (ssadd (ssname ss 0)))
    )
    (princ)
)

Please, test it on posted DWG, and look into picture... So it's the fastest, but it's wrong...

Regards...

[roy_043]

@ ribarm:
You are correct. But Gile's (or similar) code can be useful if you want the reduce the number of polylines to process.

[Marc'Antonio Alessi]

I have one remark ab this Gile's function :
..
Please, test it on posted DWG, and look into picture... So it's the fastest, but it's wrong...
Regards...

@ribarm "posted DWG" is it my DWG? Does not exist overlapping polylines in that drawing, only
   adjacent. Anyway thanks again for your suggestions and tests!

Marco