Topic: Attribute height change routine

[TJAM51]

How can the following routine be changed to do crossing, window, or single selevction sets? Thanks

Code: [Select]


;;;Attribute height change
(defun c:ahc ()
(setq atth(getreal "\nEnter new attribute height: "))
(command "attedit" "y" "*" "*" "*" "c" pause pause)
(while
(= 1 (logand (getvar "cmdactive") 1))
(command "h" atth "n")
);;; end while
);;; end lisp


[MP]

A real quick spin on a different approach ...

Code: [Select]

(defun c:ahc ( / ss i height insert )
    (cond
        (   (setq ss (ssget '((0 . "insert")(66 . 1))))
            (initget (+ 1 2 4))
            (setq height (getreal "\nNew attribute height: "))
            (repeat (setq i (sslength ss))
                (foreach attribute
                    (vlax-invoke
                        (setq insert    
                            (vlax-ename->vla-object
                                (ssname ss (setq i (1- i)))
                            )
                        )
                        'GetAttributes
                    )
                    (vla-put-height
                        attribute
                        height
                    )    
                )
                (vla-update insert)                
            )
        )    
    )
    (princ)    
)
Also, see this.

[TJAM51]

  OUTSTANDING...THANKS

[MP]

My pleasure.