Topic: delete Path..

[Andrea]

Hi,

i'm trying to remove some empty PATH..
i know there is (vl-mkdir "c:\allo\its me")

but how can i remove this path after ?

ther is no vl-remdir !!?

also, Doslib can help me with it...but don't want to load another arx just for getting a new function...

any idea ?

[Jeff_M]

Using Apropos in the VLIDE I see that Express Tools for 2002 has ACET-FILE-RMDIR

[MP]

Well ... if you modify the code I wrote for you in this thread (you're welcome) you get this (first draft) --

Code: [Select]

(defun FindItemInFile ( PredicateFunction filename / handle item )

    ;;  © 2005 Michael Puckett

    (if
        (and
            (eq 'str (type filename))
            (setq handle (open filename "r"))
        )
        (vl-catch-all-apply
           '(lambda ( / stream )
                (while (setq stream (read-line handle))
                    (cond
                        (   (PredicateFunction stream)
                            (close handle)
                            (setq item stream)
                            (exit)
                        )
                    )
                )
                (close handle)
            )
        )
    )
    item
)


(defun HiddenShellInPgpFile ( / filepath filebackup handle )

    ;;  © 2005 Michael Puckett

    (or
        (FindItemInFile
            (lambda (stream)
                (wcmatch
                    (strcase (vl-string-trim " \t\n" stream))
                    "HIDDENSHELL`,`,4`,`*OS COMMAND:`,"
                )
            )
            (setq filepath (findfile "acad.pgp"))
        )
        (and
            filepath
            (setq filebackup (vl-filename-mktemp filepath))
            (vl-file-copy filepath filebackup)
            (setq handle (open filepath "a"))
            (princ "\nHiddenShell,,4,*OS Command:,\n" handle)
            (null (close handle))
            (setvar "re-init" 16)
        )
    )
)


(defun HiddenShell ( statement / cmdecho )

    ;;  © 2005 Michael Puckett

    (cond
        (
            (HiddenShellInPgpFile)
            (setq cmdecho (getvar "cmdecho"))
            (setvar "cmdecho" 0)
            (command "HiddenShell" statement)
            (setvar "cmdecho" cmdecho)
            t
        )
    )
)


(defun DeleteFolder ( foldername )

    ;;  © 2005 Michael Puckett

    (and
        (vl-file-directory-p foldername)
        ;;  use rmdir / s if you want to kill
        ;;  the entire tree but be careful!
        (HiddenShell (strcat "rmdir " foldername))
        (null (vl-file-directory-p foldername))
    )    
   
)

[nivuahc]

Moved to the appropriate forum.

[Andrea]

Well ... if you modify the code I wrote for you in this thread (you're welcome) you get this (first draft) --

Code: [Select]

(defun FindItemInFile ( PredicateFunction filename / handle item )

    ;;  © 2005 Michael Puckett

    (if
        (and
            (eq 'str (type filename))
            (setq handle (open filename "r"))
        )
        (vl-.......
   
)

wow !!  only for removing a folder ?
there is no thing...alittle shorter ?

[Mark]

there is no thing...alittle shorter ?

C:\Temp>help rmdir
Removes (deletes) a directory.

RMDIR [/S] [/Q] [drive:]path
RD [/S] [/Q] [drive:]path


    /S      Removes all directories and files in the specified directory
            in addition to the directory itself.  Used to remove a directory
            tree.

    /Q      Quiet mode, do not ask if ok to remove a directory tree with /S

[Jeff_M]

Here's another method that is pretty darn quick......and potentially dangerous, as it doesn't care if there are files in the folder or not...it will be deleted regardless.

Code: [Select]


(defun vl-rmdir (path / fso)
  (setq fso (vla-getinterfaceobject (vlax-get-acad-object) "Scripting.FileSystemObject"))
  (vlax-invoke fso 'deletefolder path 0)
  (vlax-release-object fso)
  )


edited to localize the fso symbol

[MP]

Jeff that's sweet. I thought going that route would throw a security alert but it doesn't. Very nicely done.

<TippingHat.mpg>