Topic: How to get Web Page Text line into LISP Variable ?

[snownut2]

I am sure this can & has been done, however I find little when I search.  I would like to get the only string of test from a web query into a LISP variable with no user input.

Is this possible in LISP ?

Example of code to call web result;

 http://geocoder.us/service/csv/geocode?address=181+gould+rd+weare+nh

Text returned from the above HTTP example = 43.037423,-71.692220,181 Gould Rd,Weare,NH,03281

Other than this text line the page is completely blank.

This is the lat-long coordinates derived from a physical street address.

Any assistance would be helpful.

Thanks,

Bruce

[Lee Mac]

Try the following function:

Code: [Select]

;; Get URL Text  -  Lee Mac
;; Retrieves all text data for the given URL

(defun LM:geturltext ( url / obj rtn )
    (if (setq obj (vlax-create-object "winhttp.winhttprequest.5.1"))
        (progn
            (setq rtn
                (vl-catch-all-apply
                   '(lambda nil
                        (vlax-invoke-method obj 'open "GET" url :vlax-false)
                        (vlax-invoke-method obj 'send)
                        (vlax-get-property  obj 'responsebody)
                    )
                )
            )
            (vlax-release-object obj)
            (if (vl-catch-all-error-p rtn)
                (prompt (vl-catch-all-error-message rtn))
                (vl-list->string
                    (mapcar '(lambda ( x ) (lsh (lsh x 24) -24))
                        (vlax-safearray->list (vlax-variant-value rtn))
                    )
                )
            )
        )
    )
)

Code: [Select]

_$ (LM:geturltext "http://geocoder.us/service/csv/geocode?address=181+gould+rd+weare+nh")
"43.037423,-71.692220,181 Gould Rd,Weare,NH,03281\n"

[snownut2]

Lee,

Works great thanks,

Bruce

[Lee Mac]

Excellent 

If you prefer,

Code: [Select]

(lsh (lsh x 24) -24)
Could be equivalently replaced with:

Code: [Select]

(logand x 255)

[hozc]

Lee,

How about getting a txt file from a web page and save it to a specified folder in your computer. This can be used for automatic updating of lisp routines remotely.

Thanks and regards.

Haluk

[snownut2]

Lee,

How about getting a txt file from a web page and save it to a specified folder in your computer. This can be used for automatic updating of lisp routines remotely.

Thanks and regards.

Haluk

Do a bit of searching, that has been posted here somewhere.

Bruce

[hozc]

vla-GetRemoteFile  is the answer. Anyway thank you all.

Haluk

[Lee Mac]

Another, from VovKa:

http://www.theswamp.org/index.php?topic=33750.0

[hozc]

Lee,

This is much better.

Thank you

Haluk

[Lee Mac]

You're welcome - all credit to VovKa