Topic: Need help with DCL File

[Dave M]

I have been using this routine to put xrefs on a specific layer for years.  It has a problem though, the dialogue box doesn't work as expected.  I don't have the skill set to fix it.  There's not many lines of code, so I was hoping one of you "brainiacs" out there would be willing to fix it for me.
 
Thanks for looking!

[Matt__W]

Try the attached...

[snownut2]

Really not the place for this thread....

[Matt__W]

Really not the place for this thread....

[snownut2]

On a side note, I could never get the mnemonic option to work in DCL

[Dave M]

Really not the place for this thread....

Can you tell me where the appropriate place is so I know for next time?

[Matt__W]

Really not the place for this thread....

I see now.  The OP posted in "SHOW YOUR STUFF" when it should've been in AutoLISP (Vanilla / Visual).

[CAB]

Modified version with No DCL

Code - Auto/Visual Lisp: [Select]

1. ;;;written by  Michael P. Fowler
2. ;;;09/16/98
3. ;;;written for Rainer Will
4. ;;;written in R14
5. ;;;put xrefs on layers that are equal to the xref name
6.  
7. ;;;  Modified by CAB 02/18/2014
8.  
9. (defun c:xlayer (/ lname ent elist blist xass xcat xlname xlay)
10.   (alert (strcat "This will change the layer of the selected XREF"
11.                  "\nto a layer named 0_xx \nwhere xx is the name of the xref" )
12.   )
13.  
14.   (if (and
15.         (setq ent (car (entsel "Pick xref to change layer name to match xref name: ")))
16.         (setq xass (cdr (assoc 2 (setq elist (entget ent)))))
17.         (setq blist (entget (tblobjname "BLOCK" xass)))
18.         (= 4 (logand (cdr (assoc 70 blist)) 4))
19.   )
20.     (progn
21.       (setq lname (getvar "clayer")
22.             xlay  (cdr (assoc 8 elist))
23.             xcat  (strcat "0_" xass)
24.       )
25.       (command ".layer" "m" xcat "")
26.       (setq xlname (getvar "clayer"))
27.       (command ".layer" "u" xlay "")
28.       (command "change" ent "" "P" "la" xlname "")
29.       (command ".layer" "lo" xcat "")
30.       (setvar "clayer" lname)
31.       (princ (strcat "\nThe xref---" xass "---is now on the---" xcat "---layer")
32.       )
33.  
34.     )
35.     (princ "\nUser Quit or picked non-Xref object....")
36.   )
37.   (princ)
38. )
39.  
40. (princ)

[Dave M]

Thanks M@yhem for fixing the DCL, it works great.  Thanks Charles for the no-DCL version.  I think I like it best!

[Lee Mac]

Some icing for the selection:

Code - Auto/Visual Lisp: [Select]

1. (defun c:xlay ( / xl xn xr )
2.     (while
3.         (progn (setvar 'errno 0) (setq xr (car (entsel "\nSelect xref: ")))
4.             (cond
5.                 (   (= 7 (getvar 'errno))
6.                     (princ "\nMissed, try again.")
7.                 )
8.                 (   (null xr) nil)
9.                 (   (or (/= "INSERT" (cdr (assoc 0 (setq xr (entget xr)))))
10.                         (zerop (logand 4 (cdr (assoc 70 (tblsearch "block" (cdr (assoc 2 xr)))))))
11.                     )
12.                     (princ "\nSelected object is not an xref.")
13.                 )
14.                 (   t
15.                     (lock-unlock-layer (cdr (setq xl (assoc 8 xr))) nil)
16.                     (entmod (subst (cons 8 (setq xn (strcat "0_" (cdr (assoc 2 xr))))) xl xr))
17.                     (lock-unlock-layer xn t)
18.                     nil
19.                 )
20.             )
21.         )
22.     )
23.     (princ)
24. )
25. (defun lock-unlock-layer ( lay lck / dxf enx )
26.     (if (setq enx (tblobjname "layer" lay))
27.         (progn
28.             (setq enx (entget enx)
29.                   dxf (assoc 70 enx)
30.             )
31.             (entmod (subst (cons 70 (boole (if lck 7 4) 4 (cdr dxf))) dxf enx))
32.         )
33.     )
34. )
35. (princ)

[Dave M]

Thanks Lee! I always appreciate your input!
Dave

[Bhull1985]

Some icing for the selection:

Code - Auto/Visual Lisp: [Select]

1. (defun c:xlay ( / xl xn xr )
2.     (while
3.         (progn (setvar 'errno 0) (setq xr (car (entsel "\nSelect xref: ")))
4.             (cond
5.                 (   (= 7 (getvar 'errno))
6.                     (princ "\nMissed, try again.")
7.                 )
8.                 (   (null xr) nil)
9.                 (   (or (/= "INSERT" (cdr (assoc 0 (setq xr (entget xr)))))
10.                         (zerop (logand 4 (cdr (assoc 70 (tblsearch "block" (cdr (assoc 2 xr)))))))
11.                     )
12.                     (princ "\nSelected object is not an xref.")
13.                 )
14.                 (   t
15.                     (lock-unlock-layer (cdr (setq xl (assoc 8 xr))) nil)
16.                     (entmod (subst (cons 8 (setq xn (strcat "0_" (cdr (assoc 2 xr))))) xl xr))
17.                     (lock-unlock-layer xn t)
18.                     nil
19.                 )
20.             )
21.         )
22.     )
23.     (princ)
24. )
25. (defun lock-unlock-layer ( lay lck / dxf enx )
26.     (if (setq enx (tblobjname "layer" lay))
27.         (progn
28.             (setq enx (entget enx)
29.                   dxf (assoc 70 enx)
30.             )
31.             (entmod (subst (cons 70 (boole (if lck 7 4) 4 (cdr dxf))) dxf enx))
32.         )
33.     )
34. )
35. (princ)

Found another one just like the previous Lee
                (   (null xr) nil)

I see how you're using it, with your description and the alternate routine, interesting! I think I may have to incorporate this as well because it seems as if it'd be the proper way to handle a user right clicking through a routine.

[Lee Mac]

Thanks Lee! I always appreciate your input!
Dave

You're welcome Dave! 

I think I may have to incorporate this as well because it seems as if it'd be the proper way to handle a user right clicking through a routine.

There are many ways to skin a cat in AutoLISP