Topic: Entity Selection

[DanB]

I'm looking for some assistance with entity selection in LISP.

pseudo code

Code: [Select]


Prompt for Entity Selection
User Selects Entity
Object Modified
Repeat Prompt for Entity Selection
Continue Until User Stops Selecting and hits Enter/Return (OR Escape?)-think this should be part of Error trap?
Exit and return any previous settings


My dilema comes from:

Code: [Select]


(setq ent (entsel "\nSelect something: "))

If user fails to select an entity (meaning the pick box just missed the arc or line, this returns nil) This ends the user selection process and ends the code prematurely. Must I test for nil with..

Code: [Select]


(if (= ent nil)

If so how does one incorporate accepting Enter (isn't Enter seen as nil??)

Hope this is clear enough to get my point across.
Thanks,
Dan

[daron]

How about this:

Code: [Select]

(while
 (not (setq endata (car (entsel "\nSelect Object: "))))
     (prompt "\nNothing selected. ")
     )

[MP]

Perhaps this will suffice ...

Code: [Select]

(while (setq ename (car (entsel)))

    ;;  do good stuff with ename

)

[MP]

Ummm, what Daron said.

[daron]

I'm glad you agree. Wow.

[DanB]

Thanks Daron, this looks like it's going to work.

Code: [Select]


(while
     (not (setq endata (car (entsel "\nSelect Object: "))))
         (prompt "\nNothing selected. ")
     )


[CAB]

Here is another way to process the entsel.
You can have different messages and exit on the Enter key.
Just another way to skin the old cat.

Code: [Select]

(while
  (not
    (progn
      (setvar "errno" 0) ; must pre set the errno to 0
      (setq ename (car (entsel "\nSelect Object: ")))
      (cond
        ((= (getvar "errno") 52)
         (prompt "\nEnter Key Pressed, Good Bye. ")
         T
        )
        ((null ename)
         (prompt "\nNothing selected. ") ; returns nil
        )
        ((= (cdr (assoc 0 (entget ename))) "ARC")
         (prompt "\nObject is an Arc, Try again.")
        )
        ((= (cdr (assoc 0 (entget ename))) "LINE")
         (prompt "\nObject is an Line, Try again.")
        )
        ((vl-string-search "TEXT" (cdr (assoc 0 (entget ename))))
         ;;  text or Mtext or Rtext
         (prompt "\nObject is text, Try again.")
        )
        (T
         ;;   no match
         (prompt "\nYou got an something else, Good Bye. ")
         T ; allow exit from loop
        )
      )
    )
  )
)


[SMadsen]

Very nice, CAB.

Dan's initial request also included detection of Escape. This can be added by using VL-CATCH-ALL-APPLY like below. Just remember to put the test for an error object before any test of ERRNO (Esc will cause a value of 52).

Code: [Select]

(while
  (not
    (progn
      (setvar "errno" 0)                ; must pre set the errno to 0
      (setq ename (vl-catch-all-apply 'entsel '("\nSelect Object: ")))
      (cond
        ((vl-catch-all-error-p ename)
         (prompt "\nEscape was pressed")
         T
        )
        ((= (getvar "errno") 52)
         (prompt "\nEnter Key Pressed, Good Bye. ")
         T
        )
        ((null ename)
         (prompt "\nNothing selected. ") ; returns nil
        )
        ((= (cdr (assoc 0 (entget (car ename)))) "ARC")
         (prompt "\nObject is an Arc, Try again.")
        )
        ((= (cdr (assoc 0 (entget (car ename)))) "LINE")
         (prompt "\nObject is a Line, Try again.")
        )
        ((vl-string-search "TEXT"
                           (cdr (assoc 0 (entget (car ename))))
         )
         ;;  text or Mtext or Rtext
         (prompt "\nObject is text, Try again.")
        )
        (T
         ;;   no match
         (prompt "\nYou got something else, Good Bye. ")
         T                              ; allow exit from loop
        )
      )
    )
  )
)

[CAB]

Well I'll be, learn something every day here.
All this time I thought you couldn't catch the escape key press with lisp.
Thanks so much for that tip.

Good to see you back, you must be busy.