Topic: Osmode question

[hudster]

In the following lisp no matter what I do when I escape the routine I can't get the osmode to revert to what it was originally.

anyone have any Ideas where I'm going wrong?

Code: [Select]


;;;Degrees to Radians function
(defun dtr (a)
   (* pi (/ a 180.0))
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;main circuit routine;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun c:circ ()
  (setq osm (getvar "osmode")
cmd (getvar "cmdecho"))
  (setvar "osmode" 18)
  (setvar "cmdecho" 0)
  (setq pt1 (getpoint "\nSelect First Symbol: ")
pt2 (getpoint "\nSelect next Symbol: ")
ANG (ANGLE PT1 PT2)
PT3 (POLAR PT1 (+ ANG (DTR 45)) 275)
PT4 (POLAR PT2 (+ ANG (DTR 135)) 275)
)
  ;;;DRAW CIRCUIT LINE
  (setvar "osmode" 0)
  (COMMAND "PLINE" PT1 PT3 PT4 PT2 "")
  ;;;move onto next circuit line
  (while
  (setq pt1 pt2)
  (setq pt2 nil)
  (setq pt3 nil)
  (setq pt4 nil)
  (setq ang nil)
  (setvar "osmode" 18)
  (setq pt2 (getpoint "\nSelect Next symbol: ")
ANG (ANGLE PT1 PT2)
PT3 (POLAR PT1 (+ ANG (DTR 45)) 275)
PT4 (POLAR PT2 (+ ANG (DTR 135)) 275)
)
  (setvar "osmode" 0)
  (COMMAND "PLINE" PT1 PT3 PT4 PT2 "")
(SETVAR "OSMODE" OSM)
(SETVAR "CMDECHO" CMD)
  )
  (princ)
  )

[daron]

Code: [Select]

(defun c:circ ()
     (setq osm (getvar "osmode")
  cmd (getvar "cmdecho")
     )
     (setvar "osmode" 18)
     (setvar "cmdecho" 0)
     (setq pt1 (getpoint "\nSelect First Symbol: ")
  pt2 (getpoint "\nSelect next Symbol: ")
  ANG (ANGLE PT1 PT2)
  PT3 (POLAR PT1 (+ ANG (DTR 45)) 275)
  PT4 (POLAR PT2 (+ ANG (DTR 135)) 275)
     )
;;;DRAW CIRCUIT LINE
     (setvar "osmode" 0)
     (COMMAND "PLINE" PT1 PT3 PT4 PT2 "")
;;;move onto next circuit line
     (while
 (setq pt1 pt2)
     (setq pt2 nil
   pt3 nil
   pt4 nil
   ang nil)
     (setvar "osmode" 18)
     (setq pt2 (getpoint "\nSelect Next symbol: ")
   ANG (ANGLE PT1 PT2)
   PT3 (POLAR PT1 (+ ANG (DTR 45)) 275)
   PT4 (POLAR PT2 (+ ANG (DTR 135)) 275)
     )
     (setvar "osmode" 0)
     (COMMAND "PLINE" PT1 PT3 PT4 PT2 "")
     )
     (SETVAR "OSMODE" OSM)
     (SETVAR "CMDECHO" CMD)
     (princ)
)

See if that'll work.

[hudster]

nope, when I hit escape during the routine the osmode stays at 18.

[MP]

I just woke up but ...

Code: [Select]

(defun c:circ ( / *error* osm cmd )
   
    (defun *error* ( msg )
        (setvar "osmode" osm)
        (setvar "cmdecho" osm)
        (princ)
    )
   
    (setq
        osm (getvar "osmode")
        cmd (getvar "cmdecho")
    )
   
    ...
   
)

[hudster]

OK got it, I had tried the error checking/console break routine from afralisp but I fogot to add the lines

Code: [Select]

(initerr) ;intit error
and

Code: [Select]

(reset)                  ;reset variables

Code: [Select]

;;;
;;error checker from www.afralisp.com
;;;
(defun error () ;load function
  (prompt "\nGlobal Error Trap Loaded") ;inform user
  (princ)
) ;defun
;;;*==========================================================
(defun initerr () ;init error
  (setq oldlayer (getvar "clayer")) ;save settings
  (setq oldsnap (getvar "osmode"))
  (setq oldpick (getvar "pickbox"))
  (setq blip (getvar "blipmode"))
  (setq temperr *error*) ;save *error*
  (setq *error* trap) ;reassign *error*
  (princ)
) ;defun
;;;*===========================================================
(defun trap (errmsg) ;define trap
  (command nil nil nil)
  (if (not (member errmsg '("console break" "Function Cancelled"))
      )
    (princ (strcat "\nError: " errmsg)) ;print message
  )
  (command "undo" "b") ;undo back
  (setvar "clayer" oldlayer) ;reset settings
  (setvar "blipmode" blip)
  (setvar "menuecho" 0)
  (setvar "highlight" 1)
  (setvar "osmode" osm)
  (setvar "pickbox" oldpick)
  (princ "\nError Resetting Enviroment ") ;inform user
  (terpri)
  (setq *error* temperr) ;restore *error*
  (princ)
) ;defun
;;;*===========================================================
(defun reset () ;define reset
  (setq *error* temperr) ;restore *error*
  (setvar "clayer" oldlayer) ;reset settings
  (setvar "blipmode" blip)
  (setvar "menuecho" 0)
  (setvar "highlight" 1)
  (setvar "osmode" osm)
  (setvar "pickbox" oldpick)
  (princ)
) ;defun
;;;*======================================================
(princ)
;;;
;;;Degrees to Radians function
(defun dtr (a)
   (* pi (/ a 180.0))
)
;;;
(defun c:circ ()
     (setq osm (getvar "osmode")
      cmd (getvar "cmdecho")
     )
(initerr) ;intit error
(command "undo" "m") ;set undo mark
     (setvar "osmode" 18)
     (setvar "cmdecho" 0)
     (setq pt1 (getpoint "\nSelect First Symbol: ")
      pt2 (getpoint "\nSelect next Symbol: ")
      ANG (ANGLE PT1 PT2)
      PT3 (POLAR PT1 (+ ANG (DTR 45)) 275)
      PT4 (POLAR PT2 (+ ANG (DTR 135)) 275)
     )
;;;DRAW CIRCUIT LINE
     (setvar "osmode" 0)
     (COMMAND "PLINE" PT1 PT3 PT4 PT2 "")
;;;move onto next circuit line
     (while
     (setq pt1 pt2)
         (setq pt2 nil
          pt3 nil
          pt4 nil
          ang nil)
         (setvar "osmode" 18)
         (setq pt2   (getpoint "\nSelect Next symbol: ")
          ANG   (ANGLE PT1 PT2)
          PT3   (POLAR PT1 (+ ANG (DTR 45)) 275)
          PT4   (POLAR PT2 (+ ANG (DTR 135)) 275)
         )
         (setvar "osmode" 0)
         (COMMAND "PLINE" PT1 PT3 PT4 PT2 "")
     )
(reset) ;reset variables
     (princ)
)


[daron]

Of course, you never said anything about "USER ERROR" in your initial post. I found that as I ran your routine, it didn't reset my snaps from exiting the while loop properly. That is why I moved it out.

[Keith™]

FYI, if you ever hit the escape key while in a lisp program, AutoCAD WILL generate an error, to handle that error you should define an error handler for your lisp program. It can be simple or complex ... but you must have one if you are going to ever hit the escape key while in a lisp program.

[daron]

I assume you're telling the Hudster that. I do know what you speak of. It's just that "user error" wasn't the impression I got from the initial post