Topic: entmod not modifying

[daron]

I'm trying to throw together a little function that will take the xvalue of a list of selected objects, get the greatest xvalue of all objects and substitute that value into the xvalue of said objects. Here's what I have so far.
ename list should be a list of ename objects

Code: [Select]

(defun lineupText (enamelist / xval puttoval newlist)
     (setq xval    (mapcar '(lambda (x) (car (cdr (assoc 11 (entget x)))))
   enamelist
   )
  puttoval (car (vl-sort xval '>))
     )
     (mapcar '(lambda (x)
  (setq newlist (subst puttoval
(car (cdr (assoc 11 (entget x))))
(entget x)
)
  )
  (entmod newlist)
  (entupd x)
     )
    objs
     )
)
I'm sure this could be made cleaner, but this is just the first go around. Will someone please tell me why entmod isn't updating the list?
Thank you.

[MP]

Perhaps --

Code: [Select]

(defun LineUpText ( enames / x pair data )
     
    ;; get minimum x coordinate for all entities 11 group

    (setq x
        (apply 'min
            (mapcar
               '(lambda (ename) (cadr (assoc 11 (entget ename))))
                enames
            )    
        )
    )
   
    ;;  apply minx to all entities
   
    (foreach ename enames
        (entmod
            (subst
                (cons 11
                    (cons x
                        (cddr
                            (setq pair
                                (assoc 11
                                    (setq data (entget ename))
                                )
                            )    
                        )
                    )
                )
                pair
                data
            )
        )
        (entupd ename)
    )
     
    (princ)
   
)

[daron]

Okay, I see what I was doing wrong. I was adding just the value and needed to add the list. Doh! Nice code.

[MP]

Glad it helped, and thanks for the compliment.