Topic: Changing VLA in a Reactor Lisp

[MSTG007]

I have found some code that does work when I close out a drawing. Its basic. So when I close a drwing it will zoom extents and then pops up a window saying "Command Close was issed." (Press ok) then Save file and exits.

I would like to find the call / command to (uncheck the Display Plot Styles) in the page setup window.

Hopefully that is an easy change... But I do now know.

Code: [Select]

;;=======================================================================
;; CLOSE reactor
;;=======================================================================
(vl-load-com)
(defun smart-command-reactor (commands StartCallback EndCallback / ended)
  (vl-load-reactors)
  (setq ended
    (vlr-command-reactor nil
     '(
        (:vlr-commandEnded . internal-commandEnded)
        (:vlr-commandCancelled . internal-commandEnded)
        (:vlr-commandFailed . internal-commandEnded)
      )
    )
  )
  (vlr-remove ended)
  (vlr-command-reactor
    (list
      ended
      StartCallback
      EndCallback
      (if (listp commands)
        (mapcar 'strcase commands)
        (list (strcase commands))
      )
    )
    '((:vlr-commandWillStart . internal-commandWillStart))
  )
)
;;=======================================================================
(defun internal-commandWillStart (reactor args / data result)
  (setq data (vlr-data reactor))
  (if
    (and
      (member (car args) (last data))
      (setq result (apply (cadr data) (list (car args))))
    )
    (progn
      (vlr-data-set
        (car data)
        (list (caddr data) result)
      )
      (vlr-add (car data))
    )
  )
)
;;=======================================================================
(defun internal-commandEnded (reactor args / data)
  (setq data (vlr-data reactor))
  (vlr-remove reactor)
  (apply
    (car data)
    (list
      reactor
      (vlr-current-reaction-name)
      (car args)
      (cadr data)
    )
  )
)
;;=======================================================================
(if *my-smart-close-reactor* (vlr-remove *my-smart-close-reactor*))
;;=======================================================================
(setq *my-smart-close-reactor*

  (smart-command-reactor

    ;; command(s) as list
    '("CLOSE")

    ;; StartCallback (called when CLOSE starts)
    (function
      (lambda (cmdname)
        ;;;===================================================
        ;;; *** from here
        ;;;===================================================
(vla-ZoomExtents (vlax-get-acad-object))
(alert "Command CLOSE was issued.")
        ;;;===================================================
        ;;; *** to here
        ;;;===================================================
      )
    )

    ;; EndCallback (called when CLOSE ends)
    (function
      (lambda (data)
        (setvars data)
        (sssetfirst nil)
        (setq app nil adoc nil)
      )
    )
  )
)
;;=======================================================================
(defun setvars (data)
  (mapcar
    (function
      (lambda (v / r)
        (setq r (getvar (car v)))
        (setvar (car v) (cdr v))
        (cons (car v) r)
      )
    )
    data
  )
)
;;=======================================================================
(princ "\nCLOSE reactor enabled.")
;;=======================================================================
(princ)
;;=======================================================================

[Jeff_M]

If you add this just above the zoomextents line:
(vla-put-showplotstyles
  (vla-get-activelayout
    (vla-get-activedocument
      (vlax-get-acad-object)))
  :vlax-false)

it should do what you want.

[MSTG007]

Works! Sweet. Ill ask one more thing... What if I wanted to add this to the reactor script as well.

Code: [Select]

(defun c:foo (/ i)
  (if (= (strcase (getenv "username")) "YOU")
    (setq i -1)
    (setq i 0)
  )
  (vlax-for l (vla-get-layouts (vla-get-activedocument (vlax-get-acad-object)))
    (if (zerop (vlax-get l 'modeltype))
      (vlax-put l 'showplotstyles i)
    )
  )
  (princ)
)

[ronjonp]

Maybe this will shed some light

Code: [Select]


(or *commandreactors*
    (setq *commandreactors*
      (vlr-command-reactor
        nil
        '((:vlr-commandwillstart . strtcmd)
          (:vlr-commandended . endcmd)
          (:vlr-commandcancelled . cnclcmd)
          (:vlr-commandfailed . faldcmd)
         )
      )
    )
)
;; Resets all tabs to not show plot styles on close
(defun strtcmd (calling-reactor strtcmdinfo)
  (if (wcmatch (strcase (car strtcmdinfo) t) "close,closeall")
    (vlax-for l   (vla-get-layouts (vla-get-activedocument (vlax-get-acad-object)))
      (if (zerop (vlax-get l 'modeltype))
   (vlax-put l 'showplotstyles 0)
      )
    )
  )
)

[MSTG007]

Guess what... I remembered something you helped me with:

http://www.theswamp.org/index.php?topic=45449.15

Guess what again. It works now. I do not know why it does now, but all that matters is it does.

This will make alot of people (not mad at me). lol

Thanks for all your time and help with me again:)

[ronjonp]

Glad to help out