Author Topic: Help with this code?  (Read 4473 times)

0 Members and 1 Guest are viewing this topic.

josan

  • Mosquito
  • Posts: 15
Help with this code?
« on: September 03, 2013, 03:31:39 PM »
I take this code http://www.theswamp.org/index.php?topic=44185.msg494430#msg494430 and modify.

Results (; error: bad argument type: numberp: nil)

Code: [Select]
(defun ar2 (x y z)
(setq aplic "RT_RJH")
(regapp aplic)
(entmake (list (cons 0 "BLOCK")(cons 2 "LT_LINE")(cons 70 0)(cons 10 (list 0 0 0))))
(entmake (list (cons 0 "CIRCLE")(cons 8 "0")
               (cons 10 (list 0 0 -12))
               (cons 39 24)
               (cons 40 0.25)
               (cons 210 (list 1 0 0))))
(entmake (list (cons 0 "ENDBLK")))
(entmake (list (cons 0 "INSERT")
               (cons 8 "RT_LIGHTS")
               (cons 2 "LT_LINE")
               (cons 10 (list (* x 0.5) y z))
               (cons 41 (/ x 24.))
               (cons 42 (/ x 24.))
               (cons 43 (/ x 24.))
               '(-3 (aplic
                         (1070 . 200) (1000 . "L48")
                         (1070 . 100) (1010 1.0 1.0 1.0)
                         (1070 . 111) (1040 . 1.0)
                         (1070 . 110) (1040 . 100.0)
                         (1070 . 105) (1040 . 0.0)
                         (1070 . 103) (1040 . 0.25)
                         (1070 . 99)  (1070 . 1)
                         (1070 . 101) (1011 0.0 0.0 0.0)))
))
)

Thanks for your time...
« Last Edit: September 05, 2013, 12:00:23 AM by CAB »

David Bethel

  • Swamp Rat
  • Posts: 656
Re: Wath's wrong
« Reply #1 on: September 03, 2013, 04:15:41 PM »
1 thing jumps out :

You cannot evaluate a symbol in a quoted expression

Code: [Select]
  '(-3 (aplic

Code: [Select]
'(-3 ("RT_RJH"

-David


Ahha    Another ACCurender person   :kewl:

« Last Edit: September 03, 2013, 04:19:19 PM by David Bethel »
R12 Dos - A2K

Lee Mac

  • Seagull
  • Posts: 12603
  • London, England
Re: Wath's wrong
« Reply #2 on: September 03, 2013, 05:30:52 PM »
If you wanted to retain the use of a local variable for the application name, you would need to construct the xdata list using the AutoLISP list function, as opposed to quoting it as a literal expression, e.g.:

Code - Auto/Visual Lisp: [Select]
  1. (defun ar2 ( x y z / app )
  2.     (setq app "RT_RJH")
  3.     (regapp app)
  4.     (entmake
  5.        '(
  6.             (000 . "BLOCK")
  7.             (002 . "LT_LINE")
  8.             (070 . 0)
  9.             (010 0.0 0.0 0.0)
  10.         )
  11.     )
  12.     (entmake
  13.        '(
  14.             (000 . "CIRCLE")
  15.             (008 . "0")
  16.             (010 0.0 0.0 -12.0)
  17.             (039 . 24.0)
  18.             (040 . 0.25)
  19.             (210 1.0 0.0 0.0)
  20.         )
  21.     )
  22.     (entmake '((0 . "ENDBLK")))
  23.     (entmake
  24.         (list
  25.            '(0 . "INSERT")
  26.            '(8 . "RT_LIGHTS")
  27.            '(2 . "LT_LINE")
  28.             (list 10 (* x 0.5) y z)
  29.             (cons 41 (/ x 24.0))
  30.             (cons 42 (/ x 24.0))
  31.             (cons 43 (/ x 24.0))
  32.             (list -3
  33.                 (list app
  34.                    '(1070 . 200)'(1000 . "L48")
  35.                    '(1070 . 100)'(1010 1.0 1.0 1.0)
  36.                    '(1070 . 111)'(1040 . 1.0)
  37.                    '(1070 . 110)'(1040 . 100.0)
  38.                    '(1070 . 105)'(1040 . 0.0)
  39.                    '(1070 . 103)'(1040 . 0.25)
  40.                    '(1070 . 099)'(1070 . 1)
  41.                    '(1070 . 101)'(1011 0.0 0.0 0.0)
  42.                 )
  43.             )
  44.         )
  45.     )
  46. )

Finally, remember to declare your local variables - see this tutorial to understand why this is a good practice to follow.

josan

  • Mosquito
  • Posts: 15
Re: Wath's wrong
« Reply #3 on: September 04, 2013, 02:03:25 PM »
Problem solved ...

Thanks for the links and I'm reading ....

Lee Mac

  • Seagull
  • Posts: 12603
  • London, England
Re: Help with this code?
« Reply #4 on: September 05, 2013, 06:03:47 AM »
You're welcome josan  :-)

AIberto

  • Newt
  • Posts: 127
Re: Help with this code?
« Reply #5 on: September 08, 2015, 12:01:22 AM »
You're welcome josan  :-)

Hi ,Lee

Where can query the significance of these DFX ?

(list -3
   (list app
      '(1070 . 200)'(1000 . "L48")
      '(1070 . 100)'(1010 1.0 1.0 1.0)
      '(1070 . 111)'(1040 . 1.0)
      '(1070 . 110)'(1040 . 100.0)
      '(1070 . 105)'(1040 . 0.0)
      '(1070 . 103)'(1040 . 0.25)
      '(1070 . 099)'(1070 . 1)
      '(1070 . 101)'(1011 0.0 0.0 0.0)
   )
)
AutoCad2012 ,Windows XP 32bit

Kerry

  • Mesozoic relic
  • Seagull
  • Posts: 11654
  • class keyThumper<T>:ILazy<T>
Re: Help with this code?
« Reply #6 on: September 08, 2015, 12:15:35 AM »
« Last Edit: September 08, 2015, 12:25:33 AM by Kerry »
Perfection is not optional.
Everything will work just as you expect it to, unless your expectations are incorrect.
Discipline: None at all.

--> Donate to theSwamp<--

AIberto

  • Newt
  • Posts: 127
Re: Help with this code?
« Reply #7 on: September 08, 2015, 04:03:28 AM »
Have a look at the latter half of this page

http://help.autodesk.com/view/ACD/2016/ENU/?guid=GUID-A2A628B0-3699-4740-A215-C560E7242F63

Thanks kerry

How change the arrow type ? I use this ,But unsuccessful
Code - Auto/Visual Lisp: [Select]
  1. (list -3
  2.         (list "ACAD"
  3.                 '(1000 . "DSTYLE")
  4.                 '(1002 . "{")
  5.                 '(1070 . 41)
  6.                 (cons 1040 1.5)
  7.                 '(1070 . 341)
  8.                 ;(cons 1005 "_DOTSMALL")
  9.                 '(1002 . "}")
  10.         )
  11. )
  12.  

I want use this ,
(setvar "dimldrblk" "_DOTSMALL")
but , does not work for entmake


Now, I use ActiveX Method.
Code: [Select]
(setq ldobj (vlax-ename->vla-object (entlast)))
(vla-put-ArrowheadType ldobj acArrowDotSmall)
(vla-Update ldobj)


@Lee Mac @roy_043  @Kerry @ronjonp
« Last Edit: September 08, 2015, 07:38:43 AM by AIberto »
AutoCad2012 ,Windows XP 32bit

roy_043

  • Water Moccasin
  • Posts: 1888
  • BricsCAD 18
Re: Help with this code?
« Reply #8 on: September 08, 2015, 08:51:05 AM »
Have you tried?:
Code: [Select]
(setvar 'dimldrblk "DOTSMALL") ; Blockname without '_'.
If you want to accomplish this by supplying extended entity data you will have to use the handle of the block definition for gc 1005 (and not the blockname):
Code - Auto/Visual Lisp: [Select]
  1. (defun c:test ( / ename old)
  2.   (setq old (getvar 'dimldrblk))
  3.   (setvar 'dimldrblk "DOTSMALL") ; Make sure the block "_DOTSMALL" is present.
  4.   (setvar 'dimldrblk old)
  5.   (setq ename (car (entsel)))
  6.   (entmod
  7.     (list
  8.       (cons -1 ename)
  9.       (list -3
  10.         (list
  11.           "ACAD"
  12.           '(1000 . "DSTYLE")
  13.           '(1002 . "{")
  14.           '(1070 . 41)
  15.           (cons 1040 1.5)
  16.           '(1070 . 341)
  17.           (cons
  18.             1005
  19.             (cdr
  20.               (assoc
  21.                 5
  22.                 (entget
  23.                   (cdr (assoc 330 (entget (tblobjname "block" "_DOTSMALL"))))
  24.                 )
  25.               )
  26.             )
  27.           )
  28.           '(1002 . "}")
  29.         )
  30.       )
  31.     )
  32.   )
  33. )

But if I were you I would create a special dimension style for these leaders and *not* use overrides.

AIberto

  • Newt
  • Posts: 127
Re: Help with this code?
« Reply #9 on: September 08, 2015, 11:44:45 AM »
Have you tried?:
Code: [Select]
(setvar 'dimldrblk "DOTSMALL") ; Blockname without '_'.
If you want to accomplish this by supplying extended entity data you will have to use the handle of the block definition for gc 1005 (and not the blockname):
Code - Auto/Visual Lisp: [Select]
  1. (defun c:test ( / ename old)
  2.   (setq old (getvar 'dimldrblk))
  3.   (setvar 'dimldrblk "DOTSMALL") ; Make sure the block "_DOTSMALL" is present.
  4.   (setvar 'dimldrblk old)
  5.   (setq ename (car (entsel)))
  6.   (entmod
  7.     (list
  8.       (cons -1 ename)
  9.       (list -3
  10.         (list
  11.           "ACAD"
  12.           '(1000 . "DSTYLE")
  13.           '(1002 . "{")
  14.           '(1070 . 41)
  15.           (cons 1040 1.5)
  16.           '(1070 . 341)
  17.           (cons
  18.             1005
  19.             (cdr
  20.               (assoc
  21.                 5
  22.                 (entget
  23.                   (cdr (assoc 330 (entget (tblobjname "block" "_DOTSMALL"))))
  24.                 )
  25.               )
  26.             )
  27.           )
  28.           '(1002 . "}")
  29.         )
  30.       )
  31.     )
  32.   )
  33. )

But if I were you I would create a special dimension style for these leaders and *not* use overrides.



Dear roy
Thank you!

Use (setvar 'dimldrblk "DOTSMALL"), ;;Set the variable is rejected
(setvar 'dimldrblk "_DOTSMALL") ;; is ok!

Code - Auto/Visual Lisp: [Select]
  1. (cdr (assoc 5(entget (cdr(assoc 330 (entget (tblobjname "block" blkname)))))))
is reasonable.

But I test you code with AutoCAD Mechanical 2013 , unsuccessful !

can only change arrow size. can't change arrow type.





AutoCad2012 ,Windows XP 32bit

roy_043

  • Water Moccasin
  • Posts: 1888
  • BricsCAD 18
Re: Help with this code?
« Reply #10 on: September 08, 2015, 01:25:47 PM »
What you can try:
Make sure that the block "_DOTSMALL" is present in the dwg and comment out lines 2-4 of the code.

Note: I use BricsCAD.

Lee Mac

  • Seagull
  • Posts: 12603
  • London, England
Re: Help with this code?
« Reply #11 on: September 08, 2015, 01:38:44 PM »
FWIW, below is a reference & accompanying information surrounding the Dimension Style Override DXF groups - I think I saved it from here a few years ago.

Code: [Select]
Art Cooney (artc@autodesk.com)
There's a description of the codes in the ObjectARX documentation (I've included
it below).  I don't think the DXF documentation explains the overrides.

Here's the description from the ObjectARX docs:

Dimension style overrides can be applied to any of the AcDbEntity types that
reference an AcDbDimStyleTableRecord.  These are:

 AcDbAlignedDimension
 AcDbRotatedDimension
 AcDbDiametricDimension
 AcDbRadialDimension
 AcDb2LineAngularDimension
 AcDb3PointAngularDimension
 AcDbOrdinateDimension

 AcDbLeader
 AcDbFcf

Dimension overrides applied to an object of any of these classes are stored as
xdata under the "ACAD" appId in a special subsection. The subsection starts with
a group code 1000 (AcDb::kDxfXdAsciiString) with the string "DSTYLE", followed
by all the dimension override data bracketed inside a pair of group code 1002's
(AcDb::kDxfXdControlString) (the first being a "{" and the other a "}").
Dimension variables in general are called dimvars, and this data is commonly
called "per-entity dimvar overrides" or just dimvar overrides.

Within the group code 1002 brackets is a chain of dimvar group-code/data-value
resbuf pairs, one pair for each dimvar being overridden.
The first resbuf in each pair is the DXF group code for the dimvar, as found in
the Table below.  Since the group code is an integer it has a restype of
AcDb::kDxfXdInteger16 (group code 1070).
The second resbuf in each pair is the value for that dimvar.  Data values for
dimvars may be strings, integers, reals, or objectIds.  As with resbufs in
general, the value of the resbuf’s restype indicates how to read the data in the
resval.  Please refer to the Table below.

As an example, here is a dimension style override list that will override the
DIMTAD and DIMGAP variables. The list is shown in AutoLISP format with indenting
for clarity.

 ("ACAD"
    (1000 . "DSTYLE")
    (1002 . "{")
    (1070 . 77) (1070 . 1)
    (1070 . 147) (1000 .  0.2)
    (1002 . "}")

 )

In this example the group code 77 is DIMTAD, which is overridden to be 1. Then
DIMGAP (group code 147) is set to 0.2.
The following code sample uses acutBuildList() to create this resbuf chain and
to set overrides for DIMTAD and DIMGAP on the entity pointed to by pEnt,
assuming pEnt points to an AcDbEntity of one of the types listed above and is
open for writing:

resbuf* pRb = acutBuildList(
        AcDb::kDxfRegAppName,      "ACAD",
        AcDb::kDxfXdAsciiString,   "DSTYLE",
        AcDb::kDxfXdControlString, "{",
        AcDb::kDxfXdInteger16,  77, AcDb::kDxfXdInteger16, 1,
        AcDb::kDxfXdInteger16, 147, AcDb::kDxfXdReal,      0.2,
        AcDb::kDxfXdControlString, "}",
        RTNONE);
Acad::ErrorStatus es = pEnt->setXdata(pRb);

acutRelRb(pRb);

It is very important the xdata you set onto an object have the proper sequence
of resbufs.  Each override must have both the DXF group code resbuf and the
associated value resbuf. In addition, the value must be the correct data type
(string, real, or int) and must be within the allowable range for that dimvar.
If any of these conditions are not met, AutoCAD may terminate. Also, the 1000
"DSTYLE" and the following 1002 "{" "}" set must be present, and there must only
be one set of all of these.

Remember that xdata is obtained and replaced on a per-appId basis. To modify any
dimension overrides, work with the complete list of xdata for the "ACAD" appId,
which may have other data, including other dimension overrides. So, be sure to
obtain whatever xdata may already be present for the "ACAD" appId (use the
object's xData() method with the string "ACAD"). Add or remove only the
dimension override information you need, making sure that if dimension override
information already exists you don't duplicate any of the xdata that's already
there (including the "DSTYLE" string and the 1002 "{" "}" bracket pairs). Place
new overrides in between the existing 1002 bracket pair, and put the complete
modified list back into the object via the object's setXData() method. If not
done correctly, AutoCAD may terminate.

Here is a table of all the DimStyleTableRecord dimvars, with their DXF group
codes, data types, and value ranges:

Group code  Dimension variable     Data type     Value range
3           DIMPOST                string        any
4           DIMAPOST               string        any
40          DIMSCALE               real          >= 0.0
41          DIMASZ                 real          >= 0.0
42          DIMEXO                 real          >= 0.0
43          DIMDLI                 real          >= 0.0
44          DIMEXE                 real          >= 0.0
45          DIMRND                 real          >= 0.0
46          DIMDLE                 real          >= 0.0
47          DIMTP                  real          >= 0.0
48          DIMTM                  real          >= 0.0
71          DIMTOL                 int           0 = off,  1 = on
72          DIMLIM                 int           0 = off,  1 = on
73          DIMTIH                 int           0 = off,  1 = on
74          DIMTOH                 int           0 = off,  1 = on
75          DIMSE1                 int           0 = off,  1 = on
76          DIMSE2                 int           0 = off,  1 = on
77          DIMTAD                 int           0 - 3
78          DIMZIN                 int           0 - 15
79          DIMAZIN                int           0 - 15            new
140         DIMTXT                 real          >= 0.0
141         DIMCEN                 real          any value
142         DIMTSZ                 real          >= 0.0
143         DIMALTF                real          >= 0.0
144         DIMLFAC                real          >= 0.0
145         DIMTVP                 real          >= 0.0
146         DIMTFAC                real          >= 0.0
147         DIMGAP                 real          any value
148         DIMALTRND              real          >= 0.0           new
170         DIMALT                 int           0 = off,  1 = on
171         DIMALTD                int           >= 0
172         DIMTOFL                int           0 = off,  1 = on
173         DIMSAH                 int           0 = off,  1 = on
174         DIMTIX                 int           0 = off,  1 = on
175         DIMSOXD                int           0 = off,  1 = on
176         DIMCLRD                int           0 - 256
177         DIMCLRE                int           0 - 256
178         DIMCLRT                int           0 - 256
179         DIMADEC                int           0 - 8            new
271         DIMDEC                 int           0 - 8
272         DIMTDEC                int           0 - 8
273         DIMALTU                int           1 - 8
274         DIMALTTD               int           0 - 8
275         DIMAUNIT               int           0 - 4
276         DIMFRAC                int           0 - 2            new
277         DIMLUNIT               int           0 - 4            new
278         DIMDSEP                int           (char) any char  new
279         DIMATMOVE              int           0 - 2            new
280         DIMJUST                int           0 - 4
281         DIMSD1                 int           0 = off,  1 = on
282         DIMSD2                 int           0 = off,  1 = on
283         DIMTOLJ                int           0 - 2
284         DIMTZIN                int           0 - 15
285         DIMALTZ                int           0 - 15
286         DIMALTTZ               int           0 - 15
288         DIMUPT                 int           0 = off,  1 = on
289         DIMATFIT               int           0 - 3            new
340         DIMTXSTY               objectId                       new
341         DIMLDRBLK              objectId                       new
342         DIMBLK                 objectId                       new
343         DIMBLK1                objectId                       new
344         DIMBLK2                objectId                       new
371         DIMLWD                 int           lineweights      new
372         DIMLWE                 int           lineweights      new



roy_043

  • Water Moccasin
  • Posts: 1888
  • BricsCAD 18
Re: Help with this code?
« Reply #12 on: September 08, 2015, 03:35:43 PM »
Some time ago I have updated that reference:
Code: [Select]
Source: http://www.theswamp.org/index.php?topic=3313.msg40725#msg40725
Source: http://www.theswamp.org/index.php?topic=33507

2 improvements and several additions by RKG.
Additional variables based on: http://www.hyperpics.com/system_variables/

Art Cooney (artc@autodesk.com)
There's a description of the codes in the ObjectARX documentation (I've included
it below).  I don't think the DXF documentation explains the overrides.

Here's the description from the ObjectARX docs:

Dimension style overrides can be applied to any of the AcDbEntity types that
reference an AcDbDimStyleTableRecord.  These are:

 AcDbAlignedDimension
 AcDbRotatedDimension
 AcDbDiametricDimension
 AcDbRadialDimension
 AcDb2LineAngularDimension
 AcDb3PointAngularDimension
 AcDbOrdinateDimension

 AcDbLeader
 AcDbFcf

Dimension overrides applied to an object of any of these classes are stored as
xdata under the "ACAD" appId in a special subsection. The subsection starts with
a group code 1000 (AcDb::kDxfXdAsciiString) with the string "DSTYLE", followed
by all the dimension override data bracketed inside a pair of group code 1002's
(AcDb::kDxfXdControlString) (the first being a "{" and the other a "}").
Dimension variables in general are called dimvars, and this data is commonly
called "per-entity dimvar overrides" or just dimvar overrides.

Within the group code 1002 brackets is a chain of dimvar group-code/data-value
resbuf pairs, one pair for each dimvar being overridden.
The first resbuf in each pair is the DXF group code for the dimvar, as found in
the Table below.  Since the group code is an integer it has a restype of
AcDb::kDxfXdInteger16 (group code 1070).
The second resbuf in each pair is the value for that dimvar.  Data values for
dimvars may be strings, integers, reals, or objectIds.  As with resbufs in
general, the value of the resbuf’s restype indicates how to read the data in the
resval.  Please refer to the Table below.

As an example, here is a dimension style override list that will override the
DIMTAD and DIMGAP variables. The list is shown in AutoLISP format with indenting
for clarity.

 ("ACAD"
    (1000 . "DSTYLE")
    (1002 . "{")
    (1070 . 77) (1070 . 1)
    (1070 . 147) (1040 .  0.2)
    (1002 . "}")
 )

In this example the group code 77 is DIMTAD, which is overridden to be 1. Then
DIMGAP (group code 147) is set to 0.2.
The following code sample uses acutBuildList() to create this resbuf chain and
to set overrides for DIMTAD and DIMGAP on the entity pointed to by pEnt,
assuming pEnt points to an AcDbEntity of one of the types listed above and is
open for writing:

resbuf* pRb = acutBuildList(
        AcDb::kDxfRegAppName,      "ACAD",
        AcDb::kDxfXdAsciiString,   "DSTYLE",
        AcDb::kDxfXdControlString, "{",
        AcDb::kDxfXdInteger16,  77, AcDb::kDxfXdInteger16, 1,
        AcDb::kDxfXdInteger16, 147, AcDb::kDxfXdReal,      0.2,
        AcDb::kDxfXdControlString, "}",
        RTNONE);
Acad::ErrorStatus es = pEnt->setXdata(pRb);

acutRelRb(pRb);

It is very important the xdata you set onto an object have the proper sequence
of resbufs.  Each override must have both the DXF group code resbuf and the
associated value resbuf. In addition, the value must be the correct data type
(string, real, or int) and must be within the allowable range for that dimvar.
If any of these conditions are not met, AutoCAD may terminate. Also, the 1000
"DSTYLE" and the following 1002 "{" "}" set must be present, and there must only
be one set of all of these.

Remember that xdata is obtained and replaced on a per-appId basis. To modify any
dimension overrides, work with the complete list of xdata for the "ACAD" appId,
which may have other data, including other dimension overrides. So, be sure to
obtain whatever xdata may already be present for the "ACAD" appId (use the
object's xData() method with the string "ACAD"). Add or remove only the
dimension override information you need, making sure that if dimension override
information already exists you don't duplicate any of the xdata that's already
there (including the "DSTYLE" string and the 1002 "{" "}" bracket pairs). Place
new overrides in between the existing 1002 bracket pair, and put the complete
modified list back into the object via the object's setXData() method. If not
done correctly, AutoCAD may terminate.

Here is a table of all the DimStyleTableRecord dimvars, with their DXF group
codes, data types, and value ranges:

Group code  Dimension variable     Data type     Value range
  3         DIMPOST                string        any
  4         DIMAPOST               string        any
 40         DIMSCALE               real          >= 0.0
 41         DIMASZ                 real          >= 0.0
 42         DIMEXO                 real          >= 0.0
 43         DIMDLI                 real          >= 0.0
 44         DIMEXE                 real          >= 0.0
 45         DIMRND                 real          >= 0.0
 46         DIMDLE                 real          >= 0.0
 47         DIMTP                  real          >= 0.0
 48         DIMTM                  real          >= 0.0
 49         DIMFXL                 real          any value         new 2007
 50         DIMJOGANG              real          0.08727 - 1.5708  new 2007  (5 - 90 degrees)
 69         DIMTFILL               int           0 - 2             new 2007
 70         DIMTFILLCLR            int           0 - 256           new 2007
 71         DIMTOL                 int           0 = off,  1 = on
 72         DIMLIM                 int           0 = off,  1 = on
 73         DIMTIH                 int           0 = off,  1 = on
 74         DIMTOH                 int           0 = off,  1 = on
 75         DIMSE1                 int           0 = off,  1 = on
 76         DIMSE2                 int           0 = off,  1 = on
 77         DIMTAD                 int           0 - 3
 78         DIMZIN                 int           0 - 15
 79         DIMAZIN                int           0 - 15            new
 90         DIMARCSYM              int           0 - 2             new 2007
140         DIMTXT                 real          >= 0.0
141         DIMCEN                 real          any value
142         DIMTSZ                 real          >= 0.0
143         DIMALTF                real          >= 0.0
144         DIMLFAC                real          >= 0.0
145         DIMTVP                 real          >= 0.0
146         DIMTFAC                real          >= 0.0
147         DIMGAP                 real          any value
148         DIMALTRND              real          >= 0.0            new
170         DIMALT                 int           0 = off,  1 = on
171         DIMALTD                int           >= 0
172         DIMTOFL                int           0 = off,  1 = on
173         DIMSAH                 int           0 = off,  1 = on
174         DIMTIX                 int           0 = off,  1 = on
175         DIMSOXD                int           0 = off,  1 = on
176         DIMCLRD                int           0 - 256
177         DIMCLRE                int           0 - 256
178         DIMCLRT                int           0 - 256
179         DIMADEC                int           0 - 8             new
271         DIMDEC                 int           0 - 8
272         DIMTDEC                int           0 - 8
273         DIMALTU                int           1 - 8
274         DIMALTTD               int           0 - 8
275         DIMAUNIT               int           0 - 4
276         DIMFRAC                int           0 - 2             new
277         DIMLUNIT               int           0 - 4             new
278         DIMDSEP                int           (char) any char   new
279         DIMTMOVE               int           0 - 2             new
280         DIMJUST                int           0 - 4
281         DIMSD1                 int           0 = off,  1 = on
282         DIMSD2                 int           0 = off,  1 = on
283         DIMTOLJ                int           0 - 2
284         DIMTZIN                int           0 - 15
285         DIMALTZ                int           0 - 15
286         DIMALTTZ               int           0 - 15
288         DIMUPT                 int           0 = off,  1 = on
289         DIMATFIT               int           0 - 3             new
290         DIMFXLON               int           0 = off,  1 = on  new 2007
294         DIMTXTDIRECTION        int           0 = off,  1 = on  new 2007
340         DIMTXSTY               objectId                        new
341         DIMLDRBLK              objectId                        new
342         DIMBLK                 objectId                        new
343         DIMBLK1                objectId                        new
344         DIMBLK2                objectId                        new
345         DIMLTYPE               objectId                        new 2007
346         DIMLTEX1               objectId                        new 2007
347         DIMLTEX2               objectId                        new 2007
371         DIMLWD                 int           lineweights       new
372         DIMLWE                 int           lineweights       new
« Last Edit: September 08, 2015, 03:48:13 PM by roy_043 »

AIberto

  • Newt
  • Posts: 127
Re: Help with this code?
« Reply #13 on: September 08, 2015, 08:53:54 PM »
What you can try:
Make sure that the block "_DOTSMALL" is present in the dwg and comment out lines 2-4 of the code.

Note: I use BricsCAD.

Dear Roy
Block "_DOTSMALL" is present in the dwg ! I'm sure. I found the arrow type has changed. just not updated.
How make it update ? 


AutoCad2012 ,Windows XP 32bit

roy_043

  • Water Moccasin
  • Posts: 1888
  • BricsCAD 18
Re: Help with this code?
« Reply #14 on: September 09, 2015, 03:42:34 AM »