Topic: Looking for a Qselect routine...

[AVCAD]

So I have become in need for a Qselect routine...I use Qselect to select COGO points (Civil) by Raw Description so that I can move the selected to a certain layer. I know when you set up the point styles and what not you can have this automated...the company i work for did not set it up this way and I dont want to remake the template file, they are really iffy about me doing that stuff so I just work around it...i know its dumb but we all deal with it I am sure.

Anyways...i do this same routine over and over again which is really time consuming...does anyone know of a routine that is available or how to make one?

Thanks in advance.

[ronjonp]

Are you talking about filter?

[AVCAD]

if it works sure...but I currently use Qselect

[Jeff_M]

This should work for you:

Code - Auto/Visual Lisp: [Select]

1. (defun c:qselpts (/ *ACAD* *AECCAPP* *AECCDOC* APPSTR DESC GRPS POINT POINT#S POINTS QBLDR TMPGRP VRSN)
2.     (vl-load-com)
3.   (setq vrsn (vlax-product-key))
4.   (cond ((vl-string-search "R16.2" vrsn)(setq appstr "3.0"));;2006
5.         ((vl-string-search "R17.0" vrsn)(setq appstr "4.0"));;2007
6.         ((vl-string-search "R17.1" vrsn)(setq appstr "5.0"));;2008
7.         ((vl-string-search "R17.2" vrsn)(setq appstr "6.0"));;2009
8.         ((vl-string-search "R18.0" vrsn)(setq appstr "7.0"));;2010
9.         ((vl-string-search "R18.1" vrsn)(setq appstr "8.0"));;2011
10.         ((vl-string-search "R18.2" vrsn)(setq appstr "9.0"));;2012
11.         ((vl-string-search "R19.0" vrsn)(setq appstr "10.0"));;2013
12.         ((vl-string-search "R19.1" vrsn)(setq appstr "10.3"));;2014
13.         (t (alert "This version of C3D not supported!"))
14.         )
15.   (if (and appstr
16.            (or *acad*
17.                (setq *acad* (vlax-get-acad-object))
18.                )
19.            (or *AeccApp*
20.                (setq *AeccApp* (vla-getinterfaceobject *acad*
21.                                  (strcat "AeccXUiLand.AeccApplication." appstr)))
22.                )
23.            (or *AeccDoc*
24.                (setq *AeccDoc* (vlax-get *AeccApp* 'ActiveDocument))
25.                )
26.            (setq ss (ssadd))
27.            )
28.     (progn
29.       (setq desc (getstring "\nPlease enter the Raw Description to filter on: " t)
30.             grps (vlax-get *AeccDoc* 'PointGroups)
31.             tmpgrp (vlax-invoke grps 'Add "__TEMP__")
32.             )
33.       (setq qbldr (vlax-get tmpgrp 'querybuilder))
34.       (vlax-put qbldr 'IncludeRawDescriptions desc)
35.       (if (> (length (setq point#s (vlax-get tmpgrp 'Points))) 0)
36.         (progn
37.           (setq points (vlax-get *AeccDoc* 'Points))
38.           (foreach pt# point#s
39.             (setq point (vlax-invoke points 'Find pt#))
40.             (ssadd (vlax-vla-object->ename point) ss)
41.             )
42.           )
43.         )
44.       (vlax-invoke qbldr 'clear)
45.       (vlax-invoke grps 'remove "__TEMP__")
46.       )
47.     )
48.   (sssetfirst ss ss)
49.   (princ)
50.   )

[alanjt]

I use this:

Code: [Select]

(defun c:SP (/ flt ss add i e o)
  ;; Select AECC (Civil 3D) points
  ;; Alan J. Thompson, 09.08.10 / 05.03.11 (rewrite)

  (if (and (/= (setq flt (strcase (getstring T "\nAecc Point Description Selection Filter: "))) "")
           (setq ss (ssget "_A" '((0 . "AECC_COGO_POINT"))))
      )
    (progn
      (setq add (ssadd))
      (repeat (setq i (sslength ss))
        (setq e (ssname ss (setq i (1- i)))
              o (vlax-ename->vla-object e)
        )
        (if (vl-some '(lambda (prop / c)
                        (and (not (vl-catch-all-error-p
                                    (setq c (vl-catch-all-apply 'vlax-get-property (list o prop)))
                                  )
                             )
                             (wcmatch (strcase c) flt)
                        )
                      )
                     '(Description FullDescription RawDescription)
            )
          (ssadd e add)
        )
      )
      (sssetfirst nil add)
      (ssget "_I")
    )
  )
  (princ)
)
(vl-load-com)
(princ)