Topic: LWPOLY to SPLINE

[ribarm]

I am really thin when splines are to be constructed and I really want this to come to reality... I want to convert LWPOLY to SPLINE entity with as less as possible difference to original... As LWPOLY is actually 2nd degree curve, I want that created SPLINE be also 2nd degree curve... I want that straight segments be also straight and arcs segments also arcs but spline segments...

All this is because, I have set of lisps for creating lattice structures by using revsurf command applied to 1st and 2nd layer curve (works with SPLINES - but not with LWPOLYS) and routine will entmake set of lattice lines between these 2 layers upper and lower struts... I'll attach one example (mero-revsurf.lsp) and mero-revsurf.dwg with LWPOLYS as layers... But as they are LWPOLYS, CAD will mess with vertexes when surfaces are exploded and vertices are obtained... As SPLINE objects have parameters equally set along curve from start to end parameter, somehow when CAD constructs surfaces with SPLINES as generic curves, 3dfaces on revolved surfaces are exactly created with correct order of vertices for creating lattice structures...

So I am looking for entmaking SPLINE 2nd degree curve based on LWPOLY data...

For more info there is also youtube video with my routines for those that are interested...
Video - click here

M.R.

[VovKa]

why don't you want to use standard acad commands?

[ribarm]

I can use standard commands, but I don't know how to convert straight LINE entities and ARC entities to SPLINE entities... For ARC I think, I can do it - there is a code I wrote for ELLIPSE and ELLIPTIC ARCS and also there is code I wrote to convert ARC, CIRCLE entities to ELLIPSE entities, so I can use them combined... But I don't know how to convert LINE entities to SPLINE entities... Finally if I solve this for LINES, I can explode LWPOLYLINE and convert all entities (LINES + ARCS) to SPLINE entities and finally use SPLINEDIT -> JOIN...

So my question is actually how to convert LINE to SPLINE... There must be something for such simple task...

[ribarm]

I figured this one...

This is my discovery :

((-1 . <Entity name: 7ef034e0>) (0 . "SPLINE") (330 . <Entity
name: 7ef01cf8>) (5 . "184") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 .
"0") (100 . "AcDbSpline") (210 0.0 0.0 1.0) (70 . 24) (71 . 1) (72 . 4) (73 .
2) (74 . 0) (42 . 1.0e-010) (43 . 1.0e-010) (40 . 0.0) (40 . 0.0) (40 . 10.0)
(40 . 10.0) (10 0.0 0.0 0.0) (10 10.0 0.0 0.0))

SPLINE from vertex (0.0 0.0 0.0) to vertex (10.0 0.0 0.0) - curve of 1st degree...

And for ARCs - I've did that earlier here - ellipse2spline and here - circle+arcs2ellipse

So, can someone help me to automatize this process for LWPOLY and method described above in my previous post...

M.R.
Thanks...

[GP]

This may do the trick:
(ucs = w)
 

Code: [Select]

(defun c:test ( / el ss obj p1 sp e1 e2)
    ;Gian Paolo Cattaneo - 31.05.2013
    (if (> (atof (getvar 'acadver)) 18.0)
        (if
            (and
                (setq el (entlast))
                (setq ss (ssadd))
                (setq obj (vlax-ename->vla-object (car (entsel "\nSelect object: "))))
                (setq p1 (vlax-curve-getStartPoint obj))
                (vl-position
                    (vlax-get obj 'ObjectName)
                    '("AcDbPolyline" "AcDb2dPolyline" "AcDb3dPolyline" "AcDbArc" "AcDbLine")
                )
                (not (vlax-curve-isClosed obj))
                (setq sp
                     (entmakex
                         (list
                             '(0 . "SPLINE")
                             '(100 . "AcDbEntity")
                             '(100 . "AcDbSpline")
                             '(70 . 
                             '(71 . 3)
                             '(74 . 2)
                             '(11 0.0 0.0 0.0)
                             (cons 11 p1)
                         )
                     )
                )
                (vl-cmdf "_join" sp (vlax-vla-object->ename obj) "")
             )
             (progn
                 (vl-cmdf "_break" "_L" "_non" p1 "_non" p1)
                 (while el
                    (if (setq el (entnext el)) (ssadd el ss))     
                 )
                 (setq e1 (ssname ss 0)
                       e2 (ssname ss 1))
                 (if (equal
                         (vlax-curve-getDistAtParam (vlax-ename->vla-object e1)
                             (vlax-curve-getEndParam (vlax-ename->vla-object e1)))
                         (distance '(0.0 0.0 0.0) p1) 1e-5
                     )
                     (entdel e1)
                     (entdel e2)
                 )
            )
        )
        (alert "This tool requires AutoCAD 2011 or higher")
    )
    (princ)
)


[ribarm]

Thanks GP, I solved it with help of Stefan's code for ARCs...

It works fine...

Code - Auto/Visual Lisp: [Select]

1. (defun c:lwpoly2spl ( / *error* arc2spl line2spl loop pl e s ss )
2.  
3.   (vl-load-com)
4.  
5.   (defun *error* ( msg )
6.     (vla-endundomark (vla-get-activedocument (vlax-get-acad-object)))
7.   )
8.  
9.   (defun arc2spl ( e / make_spline points q1 q2 a pc f pe ps w )
10.  
11.            (setq q1 (vlax-curve-GetStartParam e)
12.                  q2 (vlax-curve-GetEndParam e)
13.                  a  (/ (- (vlax-curve-GetEndParam e) (vlax-curve-GetStartParam e)) 3.0) ; a - parameter interval... and angle
14.                  pc (mapcar                              ; pc - points on contur
15.                       (function
16.                         (lambda (p)
17.                          (vlax-curve-GetPointAtParam e p)
18.                           )
19.                         )
20.                       (list q1 (+ q1 a) (- q2 a) q2)
21.                     )
22.                  f  (mapcar                               ; f - first deriv on pc
23.                       (function
24.                         (lambda (p)
25.                           (vlax-curve-GetFirstDeriv e p)
26.                           )
27.                         )
28.                       (list q1 (+ q1 a) (- q2 a) q2)
29.                     )
30.                  pe (mapcar                              ; pe - extra control points for spline construction
31.                       (function
32.                         (lambda (p1 p2 d1 d2)
33.                           (inters p1 (mapcar '+ p1 d1)
34.                                   p2 (mapcar '+ p2 d2)
35.                                   nil
36.                                   )
37.                         )
38.                       )
39.                      pc (cdr pc) f (cdr f)
40.                     )
41.                  ps  (list (car pc) (car pe) (cadr pc) (cadr pe) (caddr pc) (caddr pe) (cadddr pc)) ; ps - control points for spline
42.                  w   (list 1.0 (cos (/ a 2)) 1.0 (cos (/ a 2)) 1.0 (cos (/ a 2)) 1.0)  ; weights for spline
43.            )
44.  
45.     (defun make_spline ( pts )
46.       (entmakex
47.         (append
48.            '((0 . "SPLINE") (100 . "AcDbEntity") (100 . "AcDbSpline")
49.               (70 . 4) (71 . 2) (72 . 10) (73 . 7) (74 . 0)
50.               (42 . 1.0e-010) (43 . 1.0e-010)
51.               (40 . 0.0) (40 . 0.0) (40 . 0.0) (40 . 1.0) (40 . 1.0)
52.               (40 . 2.0) (40 . 2.0) (40 . 3.0) (40 . 3.0) (40 . 3.0))
53.            pts
54.         )
55.       )
56.     )
57.    
58.     (defun points ( p w )
59.       (apply 'append (mapcar '(lambda (a b) (list (cons 10 a) (cons 41 b))) p w))
60.     )
61.    
62.     (entdel e)
63.     (make_spline (points ps w))
64.    
65.   )
66.  
67.   (defun line2spl ( e / sp ep d )
68.    
69.     (setq sp (cdr (assoc 10 (entget e)))
70.           ep (cdr (assoc 11 (entget e)))
71.           d (distance sp ep)
72.     )
73.    
74.     (entdel e)
75.    
76.     (entmakex
77.       (list
78.         '(0 . "SPLINE") '(100 . "AcDbEntity") '(100 . "AcDbSpline") '(210 0.0 0.0 1.0) '(71 . 1) '(73 . 2)
79.         '(42 . 1.0e-010) '(43 . 1.0e-010) '(40 . 0.0) '(40 . 0.0) (cons 40 d) (cons 40 d) (cons 10 sp) (cons 10 ep)
80.       )
81.     )
82.    
83.   )
84.  
85.   (vla-startundomark (vla-get-activedocument (vlax-get-acad-object)))  
86.   (setq loop T)
87.   (while loop
88.     (setq pl (car (entsel "\nPick LWPOLYLINE to convert it to SPLINE")))
89.     (if (eq (cdr (assoc 0 (entget pl))) "LWPOLYLINE") (setq loop nil))
90.   )
91.   (setq e (entlast))
92.   (command "_.explode" pl "")
93.   (setq ss (ssadd))
94.   (while (setq e (entnext e))
95.     (if (eq (cdr (assoc 0 (entget e))) "LINE")
96.       (progn
97.         (setq s (line2spl e))
98.         (ssadd s ss)
99.       )
100.     )
101.     (if (eq (cdr (assoc 0 (entget e))) "ARC")
102.       (progn
103.         (setq s (arc2spl e))
104.         (ssadd s ss)
105.       )
106.     )
107.   )
108.   (command "_.splinedit" (ssname ss 0) "j" ss "" "")
109.   (*error* nil)
110.   (princ)
111. )
112.  

I had to sleep - it was late yesterday, so now is all OK.

M.R.