Topic: Is Internet Connection Available?

[AARYAN]

Hi All,

Please help.

Is there a way to check if my computer is connected to internet or not through VisualLisp.
Need a Code to Check and return True if yes and nil if No.

Thanks and Best Regards
Aaryan

[Lee Mac]

Maybe something along the lines of:

Code: [Select]

;; Internet-p  -  Lee Mac
;; Returns T if internet connection is available

(defun LM:internet-p ( / obj rtn url )
    (setq url "http://www.google.com/") ;; url to test
    (if (setq obj (vlax-get-or-create-object "winhttp.winhttprequest.5.1"))
        (progn
            (setq rtn
                (vl-catch-all-apply
                    (function
                        (lambda ( )
                            (vlax-invoke obj 'open "GET" url :vlax-false)
                            (vlax-invoke obj 'send)
                            (command "_.delay" 200) ;; Increase if slow connection
                            (vlax-get obj 'status)
                        )
                    )
                )
            )
            (vlax-release-object obj)
            (if (vl-catch-all-error-p rtn)
                (prompt (vl-catch-all-error-message rtn))
                (= 200 rtn)
            )
        )
    )
)

[AARYAN]

Thanks You Lee Mac.

But it returns nil and my computer's connection is proper.
What would be the reason?

Thanks Again.

[Lee Mac]

But it returns nil and my computer's connection is proper.
What would be the reason?

Any error messages?

[AARYAN]

Yes There is

WinHttp.WinHttpRequest: The data necessary to complete this operation is not yet available.

[Lee Mac]

Yes There is

WinHttp.WinHttpRequest: The data necessary to complete this operation is not yet available.

Try increasing the delay noted in the code.

[Gasty]

Hi,

Try this:

(defun ping (target)
(= 0 (acet-sys-spawn 3 "ping" target))
)

Test: (ping "8.8.8.8")

Gaston Nunez

[AARYAN]

Yes There is

WinHttp.WinHttpRequest: The data necessary to complete this operation is not yet available.

Try increasing the delay noted in the code.

Thats It.. I tried it with 250 and works perfectly.
Thank You So Much Lee Mac.
Is increasing Delay related to the speed of the Internet Connection.

[AARYAN]

Hi,

Try this:

(defun ping (target)
(= 0 (acet-sys-spawn 3 "ping" target))
)

Test: (ping "8.8.8.8")

Gaston Nunez

This works perfectly too.
Thanks You So Much Gaston Nunez.

Regards

[Lee Mac]

Is increasing Delay related to the speed of the Internet Connection.

Yes; Gaston's solution may be better however - very good Gaston.

[ronjonp]

What about this:

Code: [Select]

(defun _ping (address / out ws)
  (if (setq ws (vlax-get-or-create-object "WScript.Shell"))
    (progn (setq out (vlax-invoke ws 'run (strcat "ping.exe -n 1 " address) 0 :vlax-true))
   (and ws (vlax-release-object ws))
   (zerop out)
    )
  )
)
(_ping "google.com")

[AARYAN]

What about this:

Code: [Select]

(defun _ping (address / out ws)
  (if (setq ws (vlax-get-or-create-object "WScript.Shell"))
    (progn (setq out (vlax-invoke ws 'run (strcat "ping.exe -n 1 " address) 0 :vlax-true))
   (and ws (vlax-release-object ws))
   (zerop out)
    )
  )
)
(_ping "google.com")

Thank You So Much!

[AARYAN]

Thanks to ALL OF YOU. Problem Solved!!

[ronjonp]

Thanks to ALL OF YOU. Problem Solved!!

 

[Lee Mac]

Good solution Ron, not reliant on Express Tools
As is evident from my post, I wasn't aware of the 'ping' application