Topic: Offset polyline from coordinates - Lisp

[venkat241]

Dear All,

I want to draw offset polyline to a reference polyline from offset widths LHS or RHS to reference polyline.

I want to draw offset lines w.r.t coordinates of reference line instead of Station, beacause my reference line is not straight one but combination of lines and arc.


To understand my problem, iam attaching herewith the data for ready reference.

Regards

Venkat

[ronjonp]

Maybe this will get you started  .

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ _addlwpolyline _angleatpoint _readfile _parse a data e file l l1 l2 pt)
2.   (defun _readfile (filename / handle result stream)
3.     (cond ((and (eq 'str (type filename)) (setq handle (open filename "r")))
4.            (while (setq stream (read-line handle)) (setq result (cons stream result)))
5.            (close handle)
6.            (reverse result)
7.           )
8.     )
9.   )
10.   (defun _addlwpolyline (layer width ptlst 0or1)
11.     (entmakex (apply 'append
12.                      (list (list '(0 . "LWPOLYLINE")
13.                                  (cons 100 "AcDbEntity")
14.                                  (cons 8 layer)
15.                                  (cons 100 "AcDbPolyline")
16.                                  (cons 90 (length ptlst))
17.                                  (cons 43 width)
18.                                  (cons 38 (caddr (trans '(0 0 0) 1 (trans '(0. 0. 1.) 1 0))))
19.                                  (cons 70 0or1)
20.                            )
21.                            (mapcar '(lambda (x) (list 10 (car x) (cadr x))) ptlst)
22.                            (list (cons 210 (trans '(0. 0. 1.) 1 0)))
23.                      )
24.               )
25.     )
26.   )
27.   (defun _angleatpoint (ename pt / ang clpt e param)
28.     (if (and (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-curve-getendparam (list ename))))
29.              (setq clpt (vlax-curve-getclosestpointto ename pt))
30.              (setq param (vlax-curve-getparamatpoint ename clpt))
31.              (setq ang (angle '(0 0) (vlax-curve-getfirstderiv ename param)))
32.         )
33.       ang
34.     )
35.   )
36.   (defun _parse (del str / p result)
37.     (if (vl-string-search del str)
38.       (progn (while str
39.                (setq p (vl-string-search del str))
40.                (setq result (cons (substr str 1 p) result))
41.                (if p
42.                  (setq str (substr str (+ 1 p (strlen del))))
43.                  (setq str nil)
44.                )
45.              )
46.              (vl-remove "" (reverse result))
47.       )
48.       str
49.     )
50.   )
51.   (if (and (setq e (car (entsel "\nPick center line: ")))
52.            (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-curve-getendparam (list e))))
53.            (setq file (getfiled "Pick CSV !<--must be CSV! File" (getvar 'dwgprefix) "csv" 0))
54.            (setq data (_readfile file))
55.       )
56.     (progn (foreach line data
57.              (setq l (_parse "," line))
58.              ;; If the line has 7 items and they are all numbers rock and roll
59.              (if (and (= (length l) 7) (vl-every '(lambda (x) (numberp (read x))) l))
60.                (progn (setq pt (list (read (nth 2 l)) (read (nth 3 l))))
61.                       (setq a (+ (/ pi 2.) (_angleatpoint e pt)))
62.                       (setq l1 (cons (list pt (polar pt a (read (nth 5 l)))) l1))
63.                       (setq l2 (cons (list pt (polar pt a (read (last l)))) l2))
64.                )
65.              )
66.            )
67.            (_addlwpolyline "LHS" 0 (mapcar 'cadr l1) 0)
68.            (foreach p l1
69.              (entmakex (list '(0 . "LINE")
70.                              '(100 . "AcDbEntity")
71.                              '(8 . "LHS")
72.                              '(100 . "AcDbLine")
73.                              (cons 10 (car p))
74.                              (cons 11 (cadr p))
75.                        )
76.              )
77.            )
78.            (_addlwpolyline "RHS" 0 (mapcar 'cadr l2) 0)
79.            (foreach p l2
80.              (entmakex (list '(0 . "LINE")
81.                              '(100 . "AcDbEntity")
82.                              '(8 . "RHS")
83.                              '(100 . "AcDbLine")
84.                              (cons 10 (car p))
85.                              (cons 11 (cadr p))
86.                        )
87.              )
88.            )
89.     )
90.   )
91.   (princ)
92. )

[venkat241]

Dear ronjonp,

Thank You very much.

Rgds

Venkat

[ronjonp]

Dear ronjonp,

Thank You very much.

Rgds

Venkat

You're welcome 

[Q1241274614]

(setq a (+ (/ pi 2.) (_angleatpoint e pt)))
A is not the angle bisector

[ronjonp]

(setq a (+ (/ pi 2.) (_angleatpoint e pt)))
A is not the angle bisector

It is a perpendicular offset which I thought the OP wanted? How would you suggest fixing the code?

[Konstantin Kil]

(setq a (+ (/ pi 2.) (_angleatpoint e pt)))
A is not the angle bisector

It is a perpendicular offset which I thought the OP wanted? How would you suggest fixing the code?

Dear Ronjonp! Please tell me if I can use this Lisp without entering the East and North coordinates in .csv format. if I have a polyline in AutoCAD, from which will be will  built :Chainage, LHS, RHS?   P.S. sorry for my english)

[DEVITG]

Hi Konstantin Kil .

For better understanding, and to get further help,  please upload such sample.dwg  and sample.csv

[d2010]

(setq a (+ (/ pi 2.) (_angleatpoint e pt)))
A is not the angle bisector
I lock your program.Lisp. You cannot run without (isInside18_jsldatinDwg) .
You program now -you see a new-version.

[Konstantin Kil]

Hi Konstantin Kil .

For better understanding, and to get further help,  please upload such sample.dwg  and sample.csv

Good day DEVITG! having 2 files available: axis and data.  I want to get something similar to the result.

[sanju2323]

Hi ronjonp,
  Konstantin Kil has shared the file wouldn't it be possible by Lisp? It is also very useful for me.

[BIGAL]

Have a look at this https://www.cadtutor.net/forum/topic/70992-how-to-write-lisp-to-following-problem/

Using parse csv make a list (Ch off1 off2)(Ch off1 off2)(Ch off1 off2)
just run twice getpointatdist, get-1st-derivative polar to work out new point for off1 add to list make pline all off1's then do again for off2.

Add dims etc as you go, look at any of the Chainage.lsp for a code starting point.

[sanju2323]

Thank you BIGAL for the reply, but I am not an expert in lisp code, can you give me the complete code?

[BIGAL]

Posted at Cadtutor now. Note needs a dim style set.