Topic: help list

[Q1241274614]

((“nr” “X” “Y” “Z”) (1.0 -55687.7 35585.1 0.0) (2.0 -54769.5 35230.2 0.0) (3.0 -54532.6 35023.2 0.0) (4.0 -55184.2 34283.8 0.0) (5.0 -55983.9 35230.2 0.0))

result： ((“nr” “X” “Y” “Z”) (“1.0”  “-55687.7”  “35585.1”  “0.0”) (“2.0”  “-54769.5”  “35230.2”  “0.0”) (“3.0”  “-54532.6”  “35023.2” “0.0" ) ("4.0"  "-55184.2" "34283.8"  "0.0") ("5.0" "-55983.9" "35230.2" "0.0"))

[Stefan]

Code - Auto/Visual Lisp: [Select]

1. (mapcar
2.   (function
3.     (lambda (a)
4.       (mapcar
5.         (function
6.           (lambda (b)
7.             (vl-princ-to-string b)
8.             )
9.           )
10.         a
11.         )
12.       )
13.     )
14.  '(("nr" "X" "Y" "Z") (1.0 -55687.7 35585.1 0.0) (2.0 -54769.5 35230.2 0.0) (3.0 -54532.6 35023.2 0.0) (4.0 -55184.2 34283.8 0.0) (5.0 -55983.9 35230.2 0.0))
15.   )

[Q1241274614]

thank!

[irneb]

Code - Auto/Visual Lisp: [Select]

1. (mapcar
2.   (function
3.     (lambda (a)
4.       (mapcar
5.         (function
6.           (lambda (b)
7.             (vl-princ-to-string b)
8.             )
9.           )
10.         a
11.         )
12.       )
13.     )
14.  '(("nr" "X" "Y" "Z") (1.0 -55687.7 35585.1 0.0) (2.0 -54769.5 35230.2 0.0) (3.0 -54532.6 35023.2 0.0) (4.0 -55184.2 34283.8 0.0) (5.0 -55983.9 35230.2 0.0))
15.   )

You don't need the 2nd lambda, you could simply directly call vl-princ-to-string from the mapcar.

Code - Auto/Visual Lisp: [Select]

1. (mapcar (function (lambda (a) (mapcar 'vl-princ-to-string a)))
2.         '(("nr" "X" "Y" "Z")
3.           (1.0 -55687.7 35585.1 0.0)
4.           (2.0 -54769.5 35230.2 0.0)
5.           (3.0 -54532.6 35023.2 0.0)
6.           (4.0 -55184.2 34283.8 0.0)
7.           (5.0 -55983.9 35230.2 0.0)))

[irneb]

Or a more generalized version allowing for multiple levels of sub-lists:

Code - Auto/Visual Lisp: [Select]

1. (defun princ-list (source /)
2.   (cond ((listp source) (mapcar 'princ-list source))
3.         (t (vl-princ-to-string source))))

E.g.

Code: [Select]

_$ (princ-list
        '(("nr" "X" "Y" "Z")
          (1.0 -55687.7 35585.1 0.0)
          (2.0 -54769.5 35230.2 0.0)
          (3.0 -54532.6 35023.2 0.0)
          (4.0 -55184.2 34283.8 0.0)
          (5.0 -55983.9 35230.2 0.0)
          (6.0 (1 "test" 7))))
(("nr" "X" "Y" "Z") (1.0 -55687.7 35585.1 0.0) (2.0 -54769.5 35230.2 0.0) (3.0 -54532.6 35023.2 0.0) (4.0 -55184.2 34283.8 0.0) (5.0 -55983.9 35230.2 0.0) (6.0 (1 "test" 7)))


[ribarm]

Code - Auto/Visual Lisp: [Select]

1. (defun foo ( l / a b c )
2.   (while (setq a (car l))
3.     (setq l (cdr l))
4.     (if (eq (type a) 'str)
5.         (setq b (cons a b))
6.         (cond ((eq (type a) 'int)
7.                (setq b (cons (itoa a) b))
8.               )
9.               ((eq (type a) 'real)
10.                (setq b (cons (rtos a 2 1) b))
11.               )
12.               ((eq (type a) 'list)
13.                (setq b (foo a))
14.               )
15.         )
16.     )
17.     (if (eq (length b) 1) (setq c (cons (car b) c)) (setq c (cons b c)))
18.     (setq b nil)
19.   )
20.   (reverse c)
21. )
22.  

M.R.

[irneb]

Or my version not using vl functions:

Code - Auto/Visual Lisp: [Select]

1. (defun princ-list (source /)
2.   (cond ((listp source) (mapcar 'princ-list source))
3.         ((= (type source) 'Int) (itoa source))
4.         ((= (type source) 'Real) (rtos source))
5.         (t source)))

The reason mine is so much shorter than yours (ribarm) is due to recursion. This is usually where recursion makes coding a lot simpler than the usual iteration with state variables.

[Lee Mac]

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (if (atom l)
3.         (vl-princ-to-string l)
4.         (cons (f (car l)) (if (cdr l) (f (cdr l))))
5.     )
6. )

Code: [Select]

_$ (f '((1 . 2) (1 2 3)))
(("1" . "2") ("1" "2" "3"))

[Q1241274614]

(apply 'max (mapcar  'strlen (mapcar 'car lst)))
(apply 'max (mapcar  'strlen (mapcar 'cadr lst)))
(apply 'max (mapcar  'strlen (mapcar 'caddr lst)))
。。。。。。。。
If there are N, how should solve。

[ElpanovEvgeniy]

Code - Auto/Visual Lisp: [Select]

1. (defun f (l)
2.   (cond ((not l) nil)
3.         ((atom l) (vl-princ-to-string l))
4.         ((cons (f (car l)) (f (cdr l))))
5.   )
6. )
7. (f '((1 . 2) (1 2 3) ("1" "2" "3")))

Code - Auto/Visual Lisp: [Select]

1. (defun f1 (l)
2.   (if (listp l)
3.     (mapcar 'f1 l)
4.     (vl-princ-to-string l)
5.   )
6. )
7. (f1 '((1 2 3) ("1" "2" "3")))

[Lee Mac]

(apply 'max (mapcar  'strlen (mapcar 'car lst)))
(apply 'max (mapcar  'strlen (mapcar 'cadr lst)))
(apply 'max (mapcar  'strlen (mapcar 'caddr lst)))
。。。。。。。。
If there are N, how should solve。

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (mapcar '(lambda ( x ) (apply 'max (mapcar 'strlen x))) (apply 'mapcar (cons 'list l)))
3. )

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (if (car l)
3.         (cons
4.             (apply 'max (mapcar 'strlen (mapcar 'car l)))
5.             (f (mapcar 'cdr l))
6.         )
7.     )
8. )

Recursive, for entire list:

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l )
2.     (if (= 'str (type l))
3.         (strlen l)
4.         (max (f (car l)) (if (cdr l) (f (cdr l)) 0))
5.     )
6. )

Code - Auto/Visual Lisp: [Select]

1. _$ (f '(("a" "abc" ("b" . "def") ("ef" "ghij" ("klmn" . "o")))))
2. 4

[Q1241274614]

thank！

[ribarm]

If you have lists within list, like Irneb thought, for entire list max strlen of string :

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l / ff b )
2.   (defun ff ( l / a )
3.     (while (setq a (car l))
4.       (setq l (cdr l))
5.       (cond ((and (eq (type a) 'str))
6.              (setq b (append (list (strlen a)) b))
7.             )
8.             ((eq (type a) 'list)
9.              (ff a)
10.             )
11.       )
12.       (if (not l)
13.         (setq b (list (apply 'max b)))
14.       )
15.     )
16.     (car b)
17.   )
18.   (ff l)
19. )
20.  

Code: [Select]

(f (foo '(("nr" "X" "Y" "Z") (1.0 -55687.7 35585.1 0.0) (2.0 -54769.5 35230.2 0.0) (3.0 -54532.6 35023.2 0.0) (4.0 -55184.2 34283.8 0.0) (5.0 -55983.9 35230.2 0.0)) ))

foo is my above posted code...

[Lee Mac]

If you have lists within list, like Irneb thought, for entire list max strlen of string :

Code - Auto/Visual Lisp: [Select]

1. (defun f ( l / a )...

Careful... 

Code: [Select]

_$ (f '("a" "bc" ("def")))
3
_$ (f '("a" "b"))
3
Also:

Code: [Select]

_$ (f '("a" "b "))
1

[ribarm]

I've corrected - I don't need (snvalid), so I removed it both from (foo) and (f)...

Code: [Select]

(snvalid "a ")
nil

M.R.