Topic: Request - align object.lsp

[Fabricio28]

Hi guys,
I'm trying  to find out a lisp that align object to a polyline.

Can anybody help me out, please?

My file attached can explain better my task.

Thank in advance

[Lee Mac]

No need for a custom program, just use the in-built ALIGN command:

[Fabricio28]

Thanks for replay Lee,
I was using rotate reference command to align objects, I didn't know align command.
I was wondering if you had some command faster than align, because I have thousand of objects to align in my drawing.

I've tried to create a dinamic block with align parameter, but no success.

Thanks anyway.
Regards

[irneb]

Thanks for replay Lee,
I was using rotate reference command to align objects, I didn't know align command.
I was wondering if you had some command faster than align, because I have thousand of objects to align in my drawing.

I've tried to create a dinamic block with align parameter, but no success.

Thanks anyway.
Regards

Are these objects blocks? Is it extremely important that they're placed on the exact endpoint?

[Fabricio28]

Are these objects blocks? Is it extremely important that they're placed on the exact endpoint?

Yes, they are blocks. These blocks are placed in each endpoints of the polyline and aligned.

Regards.
 

[irneb]

Are they already placed there or would you like the lisp to place them on those points? I.e. are they on each and every endpoint, or only those where the user physically inserts them?

[Fabricio28]

Hi, irneb
I'd like the lisp place the block in each endpoints.

thank you

[Lee Mac]

Very quickly written code:

Code - Auto/Visual Lisp: [Select]

1. (defun c:alignblocks ( / _block _ang b e i j p s )    
2.     (if
3.         (and
4.             (setq b (LM:ssget "\nSelect Block to Align: " '("_+.:E:S" ((0 . "INSERT")))))
5.             (setq s (LM:ssget "\nSelect LWPolylines: "    '(((0 . "LWPOLYLINE")))))
6.         )
7.         (progn
8.             (eval
9.                 (list 'defun '_block '( p r )
10.                     (list 'entmake
11.                         (list 'list
12.                           ''(0 . "INSERT")
13.                            '(cons 10 p)
14.                            '(cons 50 r)
15.                             (list 'quote (assoc 2 (entget (ssname b 0))))
16.                         )
17.                     )
18.                 )
19.             )
20.             (defun _ang ( e p )
21.                 (apply 'atan (cdr (reverse (vlax-curve-getfirstderiv e p))))
22.             )
23.             (repeat (setq i (sslength s))
24.                 (setq e (ssname s (setq i (1- i))))
25.                 (_block (vlax-curve-getstartpoint e) (_ang e 0))
26.                 (_block (vlax-curve-getendpoint   e) (+ pi (_ang e (vlax-curve-getendparam e))))
27.                 (repeat (fix (setq j (1- (vlax-curve-getendparam e))))
28.                     (_block (setq p (vlax-curve-getpointatparam e j)) (_ang e j))
29.                     (_block p (+ pi (_ang e (setq j (1- j)))))
30.                 )
31.             )
32.         )
33.     )
34.     (princ)
35. )
36.  
37. ;; ssget  -  Lee Mac
38. ;; A wrapper for the ssget function to permit the use of a custom selection prompt
39. ;;
40. ;; Arguments:
41. ;; msg    - selection prompt
42. ;; params - list of ssget arguments
43.  
44. (defun LM:ssget ( msg params / sel )
45.     (princ msg)
46.     (setvar 'nomutt 1)
47.     (setq sel (vl-catch-all-apply 'ssget params))
48.     (setvar 'nomutt 0)
49.     (if (not (vl-catch-all-error-p sel)) sel)
50. )
51.  
52. (vl-load-com)
53. (princ)

Example:

[Fabricio28]

Hi Lee,
I'm really impressed with your code. It's just amazing!
Worked like a charm, I'll save a lot of time.

Many Thanks

May I ask you just one more thing.
Is there any way to remove the line bellow the blocks?

I really appreciate your help.

Kind Regards
 

[Lee Mac]

Hi Lee,
I'm really impressed with your code. It's just amazing!
Worked like a charm, I'll save a lot of time.

Many Thanks

You're welcome, it was only a quick draft 

May I ask you just one more thing.
Is there any way to remove the line bellow the blocks?

Add (entdel e) on a new line between line 30 & 31.

[Fabricio28]

Sorry Lee,
My english is terrible. :ugly:
I mean, I'd like to trim the line on the blocks.

Regards

[Lee Mac]

I mean, I'd like to trim the line on the blocks.

Ah, this is a little more difficult and would depend on the block dimensions & geometry.

[Fabricio28]

Ah, this is a little more difficult and would depend on the block dimensions & geometry.

I see, Lee
But thanks for your wonderful job!

You helped me a lot.

Kind Regards

[Fabricio28]

Ah, this is a little more difficult and would depend on the block dimensions & geometry.

Hi Lee
I want to clean my drawings to remove excess overlapping of lines, etc but it takes time to delete 1 by 1.
I tried overkill command but it doesnt work the way I wanted it. Please help...

My block dimensions & geometry is default.

Kind Regards