Topic: Load block definition from file

[GUIDO ROOMS]

Does anyone know a method to load a block definition into the blocks table from a file?
Thanks in advance, as ever.

[Lee Mac]

Two ways:

Code - Auto/Visual Lisp: [Select]

1. (command "_.-insert" <full-filename-of-block> nil)

Code - Auto/Visual Lisp: [Select]

1. (vla-delete
2.     (vla-insertblock
3.         (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
4.         (vlax-3D-point 0.0 0.0 0.0)
5.         <full-filename-of-block>
6.         1.0
7.         1.0
8.         1.0
9.         0.0
10.     )
11. )

By using the full filename when inserting the block, the block definition will be reloaded into the drawing.

[irneb]

Of course you may also want to erase the insert/reference after the command. You can also make a new blank block definition and then use the CopyFrom method through ObjectDBX, but that would be a whole lot of extra code simply to avoid an erase.

[Lee Mac]

Of course you may also want to erase the insert/reference after the command.

This is not required in my example since the Insert command is cancelled (by the presence of the nil) before the reference is inserted but after the definition is loaded into the drawing.

[GUIDO ROOMS]

Thank you Lee for the reply.

In fact, that's what I've been doing so far.
One can also do it using the .net api, but I was looking for a lisp function to add a block definition directly to the table without inserting and then erasing it (maybe I should have been more clear about that in my first post).

Perhaps Irneb's reply is what I was looking for: the answer is "no", at least there's no straightforward & simple way to do it in lisp.

Thanks to both of you.
Greetings.

[GUIDO ROOMS]

This is not required in my example since the Insert command is cancelled (by the presence of the nil) before the reference is inserted but after the definition is loaded into the drawing.

True! I'd overlooked that one...

[Lee Mac]

I was looking for a lisp function to add a block definition directly to the table without inserting and then erasing it (maybe I should have been more clear about that in my first post).

This is also possible, consider the following example:

Code - Auto/Visual Lisp: [Select]

1. (defun c:makeblock ( / bnm doc ins lst sel )
2.     (while
3.         (and (/= "" (setq bnm (getstring t "\nSpecify Block Name: ")))
4.             (or
5.                 (not (snvalid bnm))
6.                 (tblsearch "BLOCK" bnm)
7.             )
8.         )
9.         (princ "\nBlock name invalid or already exists.")
10.     )
11.     (if
12.         (and
13.             (/= "" bnm)
14.             (ssget '((410 . "Model")))
15.             (setq ins (getpoint "\nSpecify Base Point: "))
16.         )
17.         (progn
18.             (setq doc (vla-get-activedocument (vlax-get-acad-object)))
19.             (vlax-for obj (setq sel (vla-get-activeselectionset doc))
20.                 (setq lst (cons obj lst))
21.             )
22.             (vla-delete sel)
23.             (vlax-invoke doc 'copyobjects (reverse lst)
24.                 (vla-add
25.                     (vla-get-blocks doc)
26.                     (vlax-3D-point (trans ins 1 0))
27.                     bnm
28.                 )
29.             )
30.         )
31.     )
32.     (princ)
33. )
34. (vl-load-com) (princ)
35.  

Or, if you wish to create the block definition from scratch:

Code - Auto/Visual Lisp: [Select]

1. (defun c:makeblock ( / bnm )
2.     (while
3.         (and (/= "" (setq bnm (getstring t "\nSpecify Block Name: ")))
4.             (or
5.                 (not (snvalid bnm))
6.                 (tblsearch "BLOCK" bnm)
7.             )
8.         )
9.         (princ "\nBlock name invalid or already exists.")
10.     )
11.     (if (/= "" bnm)
12.         (vla-addcircle
13.             (vla-add
14.                 (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
15.                 (vlax-3D-point 0 0 0)
16.                 bnm
17.             )
18.             (vlax-3D-point 0 0 0)
19.             10.0
20.         )
21.     )
22.     (princ)
23. )
24. (vl-load-com) (princ)

Otherwise, you could also use ObjectDBX and the copyobjects method with an external drawing file.

[irneb]

This is not required in my example since the Insert command is cancelled (by the presence of the nil) before the reference is inserted but after the definition is loaded into the drawing.

Ah! Sorry ... yes missed that  :-[

[Lee Mac]

This is not required in my example since the Insert command is cancelled (by the presence of the nil) before the reference is inserted but after the definition is loaded into the drawing.

Ah! Sorry ... yes missed that  :-[

No problem! 

[Lee Mac]

Otherwise, you could also use ObjectDBX and the copyobjects method with an external drawing file.

Here is a general example of this method:

http://lee-mac.com/steal.html

[GUIDO ROOMS]

Good man, Lee!
Thanks a ton.

[Lee Mac]

Good man, Lee!
Thanks a ton.

You're very welcome