Author Topic: ==={Challenge}===Find the ridge lines of sloped roof (Read 106836 times)

ribarm · « **Reply #225 on:** August 10, 2023, 02:47:02 AM »

Still not good, but logic is correct, so it should work now better...

Code - Auto/Visual Lisp: [Select]

(defun c:roof-new-new-new ( / *error* mid _offset unit rlw offd inside-p collinear-p unique chkcircinside mc preprocess1 preprocess2 rem-vllvlli subprocess process done lw lwi lwx lwo ent enti lil lix lwnl ch el p1 p2 pp ppp ipp ippl vll vlli tll iplst lst ) ;;; cad, doc, spc, lay, vlll, vllli, tlll, f - global variables ;;;
 
  (vl-load-com)
 
  (defun *error* ( m )
    (if (and lwi (not (vlax-erased-p lwi)))
      (entdel lwi)
    )
    (if (and enti (not (vlax-erased-p enti)))
      (entdel enti)
    )
    (if (setq ppp (unique ppp))
      (foreach pp ppp
        (if (not (vl-some '(lambda ( x ) (and (not (equal (car x) pp 1e-6)) (not (equal (cadr x) pp 1e-6)) (not (equal (car x) (cadr x) 1e-6)) (collinear-p (car x) pp (cadr x)))) lil))
          (entmake (list (cons 0 "POINT") (cons 10 pp) (cons 62 1)))
        )
      )
    )
    (if (= ch "No")
      (while (setq el (entnext el))
        (if (and el (not (vlax-erased-p el)))
          (entdel el)
        )
      )
    )
    (if lil
      (foreach li lil
        (if (vl-some '(lambda ( x ) (and (not (equal (car li) x 1e-6)) (not (equal (cadr li) x 1e-6)) (not (equal (car li) (cadr li) 1e-6)) (collinear-p (car li) x (cadr li)))) ppp)
          (setq lil (vl-remove li lil))
          (if (vl-some '(lambda ( x ) (equal x (car li) 1e-6)) ppp)
            (entmake (list (cons 0 "LINE") (cons 10 (car li)) (cons 11 (cadr li)) (cons 62 3)))
          )
        )
      )
    )
    (command-s "_.-OVERKILL" "_ALL" "_T" "_Y" "" "")
    (if (= 8 (logand 8 (getvar 'undoctl)))
      (vla-endundomark doc)
    )
    (prompt "\nIf you want to start again on different sample, make sure you nil flag f : (setq f nil vlll nil vllli nil tlll nil) ...")
    (if m
      (prompt m)
    )
    (princ)
  )
 
  (defun mid ( p1 p2 )
    (mapcar '(lambda ( a b ) (/ (+ a b) 2.0)) p1 p2)
  )
 
  (defun _offset ( lw dist / lill lww vl lwx tl tln iplst lws )
    (setq vl (mapcar 'cdr (vl-remove-if '(lambda ( x ) (/= (car x) 10)) (setq lwx (entget lw)))))
    (setq tl (mapcar '(lambda ( a b ) (list a b)) vl (append (cdr vl) (list (car vl)))))
    (setq tln (mapcar '(lambda ( x ) (list (polar (car x) (+ (* 0.5 pi) (angle (car x) (cadr x))) (- dist)) (polar (cadr x) (+ (* 0.5 pi) (angle (car x) (cadr x))) (- dist)))) tl))
    (setq iplst (mapcar '(lambda ( a b ) (inters (car a) (cadr a) (car b) (cadr b) nil)) tln (append (cdr tln) (list (car tln)))))
    (setq lill (mapcar '(lambda ( a b ) (list a b)) iplst (append (cdr iplst) (list (car iplst)))))
    (setq lill (vl-remove-if '(lambda ( x ) (or (null (car x)) (null (cadr x)))) lill))
    (setq lws
      (cons
        (setq lww
          (entmakex
            (append
              (list
                (cons 0 "LWPOLYLINE")
                (cons 100 "AcDbEntity")
                (cons 100 "AcDbPolyline")
                (cons 90 (length iplst))
                (cons 70 (1+ (* 128 (getvar 'plinegen))))
                (cons 38 0.0)
              )
              (mapcar '(lambda ( p ) (cons 10 p)) iplst)
              (list (list 210 0.0 0.0 1.0))
            )
          )
        )
        lws
      )
    )
  )
 
  (defun unit ( v / d )
    (if (not (equal (setq d (distance '(0.0 0.0 0.0) v)) 0.0 1e-6))
      (mapcar '(lambda ( x ) (/ x d)) v)
    )
  )
 
  (defun rlw ( lw / e x1 x2 x3 x4 x5 x6 )
    ;; by ElpanovEvgeniy
    (if (= (cdr (assoc 0 (setq e (entget lw)))) "LWPOLYLINE")
      (progn
        (foreach a1 e
          (cond ((= (car a1) 10) (setq x2 (cons a1 x2)))
                ((= (car a1) 40) (setq x4 (cons (cons 41 (cdr a1)) x4)))
                ((= (car a1) 41) (setq x3 (cons (cons 40 (cdr a1)) x3)))
                ((= (car a1) 42) (setq x5 (cons (cons 42 (- (cdr a1))) x5)))
                ((= (car a1) 210) (setq x6 (cons a1 x6)))
                (t (setq x1 (cons a1 x1)))
          )
        )
        (entmod (append (reverse x1)
                  (append (apply 'append
                            (apply 'mapcar
                              (cons 'list
                                (list x2
                                  (cdr (reverse (cons (car x3) (reverse x3))))
                                  (cdr (reverse (cons (car x4) (reverse x4))))
                                  (cdr (reverse (cons (car x5) (reverse x5))))
                                )
                              )
                            )
                          )
                          x6
                  )
                )
        )
        (entupd lw)
      )
    )
  )
 
  (defun offd ( sign ip tl / dl )
    (setq dl (mapcar '(lambda ( x )
                        (distance ip
                          (inters
                            ip
                            (polar ip (+ (* 0.5 pi) (angle (car x) (cadr x))) 1.0)
                            (car x)
                            (polar (car x) (angle (car x) (cadr x)) 1.0)
                            nil
                          )
                        )
                      ) tl
              )
    )
    (vl-some '(lambda ( x )
               (if
                 (>
                   (-
                     (length dl)
                     (length (vl-remove-if '(lambda ( y ) (equal x y 0.05)) dl))
                   ) 2
                 )
                 x
               )
             ) (vl-sort dl sign)
    )
  )
 
  (defun inside-p ( p lw lwi )
    (< (distance p (vlax-curve-getclosestpointto lwi p)) (distance p (vlax-curve-getclosestpointto lw p)))
  )
 
  (defun collinear-p ( p1 p p2 )
    (equal (distance p1 p2) (+ (distance p1 p) (distance p p2)) 1e-6)
  )
 
  (defun unique ( pl )
    (if pl
      (cons (car pl)
            (unique
              (vl-remove-if
                '(lambda ( x )
                   (equal x (car pl) 1e-6)
                 )
                (cdr pl)
              )
            )
      )
    )
  )
 
  (defun chkcircinside ( pp tll / d ci ipp ippl tst )
    (if (and pp tll)
      (progn
        (setq ci (entmakex (list (cons 0 "CIRCLE") (cons 10 pp) (cons 40 (offd (function <) pp tll)))))
        (if (setq ipp (vlax-invoke (vlax-ename->vla-object ci) 'intersectwith (vlax-ename->vla-object ent) acextendnone))
          (progn
            (while ipp
              (setq ippl (cons (list (car ipp) (cadr ipp) (caddr ipp)) ippl))
              (setq ipp (cdddr ipp))
            )
            (if (or (not ippl) (vl-every '(lambda ( x ) (inside-p x ent enti)) (apply 'append (mapcar '(lambda ( x ) (list (vlax-curve-getpointatparam ci (- x 0.1)) (vlax-curve-getpointatparam ci (+ x 0.1)))) (mapcar '(lambda ( x ) (vlax-curve-getparamatpoint ci x)) ippl)))))
              (setq tst t)
            )
          )
          (setq tst t)
        )
        (if (and ci (not (vlax-erased-p ci)))
          (entdel ci)
        )
      )
    )
    tst
  )
 
  (defun mc ( p lw / ci pl mp p1 p2 p3 p4 )
    (setq ci (entmakex (list (cons 0 "CIRCLE") (cons 10 p) (cons 40 2.0))))
    (setq pl (vlax-invoke (vlax-ename->vla-object ci) 'intersectwith (vlax-ename->vla-object lw) acextendnone))
    (if (and ci (not (vlax-erased-p ci)))
      (entdel ci)
    )
    (cond
      ( (= (length pl) 12)
        (setq p1 (list (car pl) (cadr pl)))
        (setq p2 (list (nth 3 pl) (nth 4 pl)))
        (setq p3 (list (nth 6 pl) (nth 7 pl)))
        (setq p4 (list (nth 9 pl) (nth 10 pl)))
        (cond
          ( (vl-some '(lambda ( li ) (or (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- (mid p1 p2) p)) 1e-3) (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- p (mid p2 p1))) 1e-3))) lil)
            (setq mp (mid p3 p4))
          )
          ( (vl-some '(lambda ( li ) (or (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- (mid p2 p3) p)) 1e-3) (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- p (mid p3 p2))) 1e-3))) lil)
            (setq mp (mid p4 p1))
          )
          ( (vl-some '(lambda ( li ) (or (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- (mid p3 p4) p)) 1e-3) (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- p (mid p4 p3))) 1e-3))) lil)
            (setq mp (mid p1 p2))
          )
          ( (vl-some '(lambda ( li ) (or (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- (mid p4 p1) p)) 1e-3) (equal (unit (mapcar '- (car li) (cadr li))) (unit (mapcar '- p (mid p1 p4))) 1e-3))) lil)
            (setq mp (mid p2 p3))
          )
        )
      )
      ( (= (length pl) 6)
        (setq p1 (list (car pl) (cadr pl)))
        (setq p2 (list (nth 3 pl) (nth 4 pl)))
        (setq mp (mid p1 p2))
      )
    )
    (list p mp)
  )
 
  (defun preprocess1 ( vl vli / ip ) ;;; iplst - lexical global variable
    (setq iplst (mapcar '(lambda ( p1 p2 p3 p4 / ip )
                          (if
                            (and
                              (setq ip (inters p1 p2 p3 p4 nil))
                              (inside-p ip ent enti)
                              (equal (unit (mapcar '- ip p1)) (unit (mapcar '- p2 p1)) 1e-6)
                              (equal (unit (mapcar '- ip p3)) (unit (mapcar '- p4 p3)) 1e-6)
                              (inside-p (mapcar '+ p1 (mapcar '* (unit (mapcar '- ip p1)) (list 1e-2 1e-2))) ent enti)
                              (inside-p (mapcar '+ p3 (mapcar '* (unit (mapcar '- ip p3)) (list 1e-2 1e-2))) ent enti)
                            )
                            (list ip (list p1 p3))
                            (list nil nil)
                          )
                        )
                        vl
                        vli
                        (append (cdr vl) (list (car vl)))
                        (append (cdr vli) (list (car vli)))
                )
    )
    iplst
  )
 
  (defun preprocess2 ( vl vli / ip ) ;;; iplst - lexical global variable
    (setq iplst (mapcar '(lambda ( p1 p2 p3 p4 / ip )
                          (if
                            (and
                              (setq ip (inters p1 p2 p3 p4 nil))
                              (inside-p ip ent enti)
                              (equal (unit (mapcar '- ip p1)) (unit (mapcar '- p2 p1)) 1e-6)
                              (equal (unit (mapcar '- ip p3)) (unit (mapcar '- p4 p3)) 1e-6)
                              (inside-p (mapcar '+ p1 (mapcar '* (unit (mapcar '- ip p1)) (list 1e-2 1e-2))) ent enti)
                              (inside-p (mapcar '+ p3 (mapcar '* (unit (mapcar '- ip p3)) (list 1e-2 1e-2))) ent enti)
                            )
                            (list ip (list p1 p3))
                            (list nil nil)
                          )
                        )
                        vl
                        vli
                        (mapcar '(lambda ( x ) (car (mc (caar lil) (cond ( (ssname (ssget "_C" (caar lil) (caar lil) '((0 . "LWPOLYLINE"))) 0) ) ( entlast ))))) vl)
                        (mapcar '(lambda ( x ) (cadr (mc (caar lil) (cond ( (ssname (ssget "_C" (caar lil) (caar lil) '((0 . "LWPOLYLINE"))) 0) ) ( entlast ))))) vli)
                )
    )
    iplst
  )
 
  (defun rem-vllvlli ( lil )
    (if (vl-some '(lambda ( x ) (equal x (cadr (car lil)) 1e-2)) vll)
      (progn
        (setq vll (vl-remove-if '(lambda ( x ) (equal (cadr (car lil)) x 1e-2)) vll))
        (setq vlli (vl-remove-if '(lambda ( x ) (equal (cadr (car lil)) x 1e-2)) vlli))
      )
    )
    (if (vl-some '(lambda ( x ) (equal x (cadr (cadr lil)) 1e-2)) vll)
      (progn
        (setq vll (vl-remove-if '(lambda ( x ) (equal (cadr (cadr lil)) x 1e-2)) vll))
        (setq vlli (vl-remove-if '(lambda ( x ) (equal (cadr (cadr lil)) x 1e-2)) vlli))
      )
    )
  )
 
  (defun subprocess ( iplst flag / p1 p2 pp1 pp2 )
    (setq iplst (vl-remove-if '(lambda ( x ) (or (null (car x)) (null (cadr x)))) iplst))
    (setq iplstoffd (mapcar '(lambda ( x ) (if (and (car x) (cadr x))
                                             (list
                                               (mapcar '+ '(0.0 0.0) (car x))
                                               (mapcar '(lambda ( y ) (mapcar '+ '(0.0 0.0) y)) (cadr x))
                                               (offd (function <) (mapcar '+ '(0.0 0.0) (car x)) tlll)
                                             )
                                             (list nil nil nil)
                                           )
                             ) iplst
                    )
    )
    (setq iplstoffd (vl-remove-if '(lambda ( x ) (null (caddr x))) iplstoffd))
    (if (not flag)
      (setq iplstoffd (vl-sort iplstoffd '(lambda ( a b ) (< (caddr a) (caddr b)))))
      (setq iplstoffd (vl-sort iplstoffd '(lambda ( a b ) (if (equal (caddr a) (caddr b) 1e-6) (< (distance (car a) (caar lst)) (distance (car b) (caar lst))) (< (caddr a) (caddr b))))))
    )
    (if (not (vl-position (car iplstoffd) lst))
      (setq ipd (car iplstoffd) lst (cons ipd lst))
      (progn
        (setq iplstoffd (cdr (member (car lst) iplstoffd)))
        (setq ipd (car iplstoffd) lst (cons ipd lst))
      )
    )
    (if (and ipd (chkcircinside (car ipd) tlll))
      (progn
        (setq ppp (cons (car ipd) ppp))
        (if
          (and
            (setq p1
              (vl-some '(lambda ( x )
                (if
                  (equal
                    (unit (mapcar '- (car ipd) x))
                    (unit (mapcar '- (car ipd) (caadr ipd)))
                    1e-6
                  )
                  x
                )
              ) vll
              )
            )
            (setq pp1
              (vl-some '(lambda ( x )
                (if
                  (equal
                    (unit (mapcar '- (car ipd) x))
                    (unit (mapcar '- (car ipd) p1))
                    1e-6
                  )
                  x
                )
              ) vlll
              )
            )
          )
          (setq lil (cons (list (car ipd) pp1) lil))
          (if p1
            (setq lil (cons (list (car ipd) p1) lil))
            (setq lil (cons (list (car ipd) (caadr ipd)) lil))
          )
        )
        (if
          (and
            (setq p2
              (vl-some '(lambda ( x )
                (if
                  (equal
                    (unit (mapcar '- (car ipd) x))
                    (unit (mapcar '- (car ipd) (cadadr ipd)))
                    1e-6
                  )
                  x
                )
              ) vll
              )
            )
            (setq pp2
              (vl-some '(lambda ( x )
                (if
                  (equal
                    (unit (mapcar '- (car ipd) x))
                    (unit (mapcar '- (car ipd) p2))
                    1e-6
                  )
                  x
                )
              ) vlll
              )
            )
          )
          (setq lil (cons (list (car ipd) pp2) lil))
          (if p2
            (setq lil (cons (list (car ipd) p2) lil))
            (setq lil (cons (list (car ipd) (cadadr ipd)) lil))
          )
        )
        (if
          (and
            (caddr ipd)
            (setq lwnl (vl-catch-all-apply '_offset (list ent (- (caddr ipd)))))
          )
          (if (and lwnl (vl-catch-all-error-p lwnl))
            (setq done t)
          )
        )
        (cond
          ( (and lwnl (not (vl-catch-all-error-p lwnl)) (= (length lwnl) 1))
            (rem-vllvlli lil)
          )
          ( (and lwnl (not (vl-catch-all-error-p lwnl)) (> (length lwnl) 1))
            (setq lwnl (vl-sort lwnl '(lambda ( a b ) (< (distance (car ipd) (vlax-curve-getclosestpointto a (car ipd))) (distance (car ipd) (vlax-curve-getclosestpointto b (car ipd)))))))
            (rem-vllvlli lil)
          )
        )
      )
    )
    lwnl
  )
 
  (defun process ( lw / lwi lwx vl vli iplst tl lwnl ) ;;; vll, vlli, tll, lwnl, ppp, done, flag - lexical global variables ;;;
    (if lw
      (progn
        (setq vl (mapcar 'cdr (vl-remove-if '(lambda ( x ) (/= (car x) 10)) (setq lwx (entget lw)))))
        (if (not vll)
          (setq vll vl)
        )
        (setq lwi (vlax-vla-object->ename (car (vlax-invoke (vlax-ename->vla-object lw) 'offset -1e-3))))
        (setq vli (mapcar 'cdr (vl-remove-if '(lambda ( x ) (/= (car x) 10)) (entget lwi))))
        (if (not vlli)
          (setq vlli vli)
        )
        (setq tl (mapcar '(lambda ( a b ) (list a b)) vl (append (cdr vl) (list (car vl)))))
        (if (not tll)
          (setq tll tl)
        )
        (setq iplst nil)
        (setq iplst (preprocess1 vll vlli))
        (subprocess iplst nil)
        (repeat (length vll)
          (setq iplst nil)
          (setq iplst (preprocess2 vll vlli))
          (subprocess iplst t)
        )
        (if (and lwi (not (vlax-erased-p lwi)))
          (entdel lwi)
        )
        lwnl
      )
    )
  )
 
  (or cad (progn (vl-load-com) (setq cad (vlax-get-acad-object))))
  (or doc (setq doc (vla-get-activedocument cad)))
  (or spc (setq spc (vla-get-block (setq lay (vla-get-activelayout doc)))))
 
  (if (= 8 (logand 8 (getvar 'undoctl)))
    (vla-endundomark doc)
  )
  (vla-startundomark doc)
  (if
    (and
      (setq lw (car (entsel "\nPick boundary closed polygonal LWPOLYLINE with only straight segments...")))
      (= (cdr (assoc 0 (setq lwx (entget lw)))) "LWPOLYLINE")
      (= 1 (logand 1 (cdr (assoc 70 lwx))))
      (vl-every '(lambda ( x ) (= 0.0 (cdr x))) (vl-remove-if '(lambda ( x ) (/= (car x) 42)) lwx))
      (setq el (entlast) ent lw)
    )
    (progn
      (setq lwi (vlax-vla-object->ename (car (vlax-invoke (vlax-ename->vla-object lw) 'offset -1e-3))))
      (if (> (vlax-curve-getarea lwi) (vlax-curve-getarea lw))
        (setq lw (rlw lw)) ;;; force main lwpolyline CCW - counter clockwise ;;;
      )
      (setq enti (vlax-vla-object->ename (car (vlax-invoke (vlax-ename->vla-object ent) 'offset -1e-3))))
      (if (and lwi (not (vlax-erased-p lwi)))
        (entdel lwi)
      )
      (if (not f)
        (progn
          (setq vlll (mapcar 'cdr (vl-remove-if '(lambda ( x ) (/= (car x) 10)) (entget ent))))
          (setq vllli (mapcar 'cdr (vl-remove-if '(lambda ( x ) (/= (car x) 10)) (entget enti))))
          (setq tlll (mapcar '(lambda ( a b ) (list a b)) vlll (append (cdr vlll) (list (car vlll)))))
          (setq f t)
        )
      )
      (initget "Yes No")
      (setq ch (cond ( (getkword "\nDo you want points-offsets-lines or just lines [Yes / No] <No> : ") ) ( "No" )))
      (while (not done)
        (if
          (and
            (not (vl-catch-all-error-p (setq lwnl (vl-catch-all-apply 'process (list lw)))))
            lwnl
          )
          (while (and (not done) (setq lww (car (vl-sort lwnl '(lambda ( a b ) (> (vlax-curve-getarea a) (vlax-curve-getarea b)))))))
            (setq lwnl (vl-remove lww lwnl))
            (setq lwo lww)
            (setq lwnl (vl-catch-all-apply 'process (list lww)))
            (if (vl-catch-all-error-p lwnl)
              (setq done t)
              (if (eq (car lwnl) lwo)
                (setq done t)
              )
            )
          )
          (setq done t)
        )
      ) ;;; main engine ;;;
    )
  )
  (*error* nil)
)
 

Regards, M.R.

ribarm · « **Reply #226 on:** August 11, 2023, 03:26:14 AM »

Who is interested in this over custom _offset sub function version, I've made few improvements, but still it doesn't solve but there is attempt which is pretty good for a start for experienced member that wants to continue... Also I've implemented *.lsp in archive at www.cadtutor.net download section...
If nothing, I've played with this challenge one more time...

Thanks for following, but I see there are no too much interest for roofs - hipped ones...

ribarm · « **Reply #227 on:** August 14, 2023, 02:49:38 AM »

Quote from: ribarm on August 11, 2023, 03:26:14 AM

Who is interested in this over custom _offset sub function version, I've made few improvements, but still it doesn't solve but there is attempt which is pretty good for a start for experienced member that wants to continue... Also I've implemented *.lsp in archive at www.cadtutor.net download section...
If nothing, I've played with this challenge one more time...

Thanks for following, but I see there are no too much interest for roofs - hipped ones...

Anyone?
You can download attachment from previous post and continue on that basis... We need fast and good code still... And I wanted to be used offset relations as this is correct path for correct solution...

It's Alive! · « **Reply #228 on:** August 14, 2023, 05:05:03 AM »

Cool stuff, never had the need to draw sloped roofs. back when I was drafting, I was in New Mexico, most of the houses were Adobe, with flat roofs.
That, and I mostly did submittals for commercial casework

ribarm · « **Reply #229 on:** August 14, 2023, 05:15:54 AM »

Quote from: It's Alive! on August 14, 2023, 05:05:03 AM

Cool stuff, never had the need to draw sloped roofs. back when I was drafting, I was in New Mexico, most of the houses were Adobe, with flat roofs.
That, and I mostly did submittals for commercial casework

Daniel, if it was you downloaded my post, I must say that solution exist in archieve on www.cadtutor.net - download section... This was for fun and for me to see if it would behave correct with offsettings... But sadly I was wrong, so here is the link at cadtutor with all neccessary routines you may find for correct construct 2d+3d solutions and there are even hatches... Main one is : 2droof-final.lsp and others based on it... But I'd check firstly : hr.lsp and if it fails, then 2droof-final.lsp... There is also good command version : roof-command-new.lsp and my versions for finding random solutions based on input correct one (2droof-final.lsp)... Those are just possibilities and solution version works very slow, so if you want improvements for speed, this could be the task for challenging *.arx, or *.dll, or ...

Link : https://www.cadtutor.net/forum/files/file/36-hipped-roof-routines/

ribarm · « **Reply #230 on:** August 14, 2023, 05:18:51 PM »

I've changed (mc) sub function... Also I've changed the code all around where I founded it's necessity...

HTH., M.R.

ribarm · « **Reply #231 on:** August 18, 2023, 10:14:42 AM »

I have no feedback...

Could someone have a look into my attachment in previous post and give opinion, or better implement something I forgot...
It seems that this all looks like joke, but I've spent a lot of time to collect and compose and this version... So please, help by download and look, or give opinion ab things implemented or more yet to be implemented next...
C'mon show some courage...

ronjonp · « **Reply #232 on:** August 18, 2023, 12:13:26 PM »

Quote from: ribarm on August 18, 2023, 10:14:42 AM

I have no feedback...

Could someone have a look into my attachment in previous post and give opinion, or better implement something I forgot...
It seems that this all looks like joke, but I've spent a lot of time to collect and compose and this version... So please, help by download and look, or give opinion ab things implemented or more yet to be implemented next...
C'mon show some courage...

I just tried it and it does nothing ?

ribarm · « **Reply #233 on:** August 18, 2023, 11:46:22 PM »

Quote from: ronjonp on August 18, 2023, 12:13:26 PM

Quote from: ribarm on August 18, 2023, 10:14:42 AM
I have no feedback...

Could someone have a look into my attachment in previous post and give opinion, or better implement something I forgot...
It seems that this all looks like joke, but I've spent a lot of time to collect and compose and this version... So please, help by download and look, or give opinion ab things implemented or more yet to be implemented next...
C'mon show some courage...
I just tried it and it does nothing ?

It's because you probably tested routine on othogonal polygonal LWPOLYLINE... Try this mod. attached here - should throw triangles on porches...
But when it's needed to continue from there to build complete solution it stops around first continuation points all around, or make not correct connections... With ultimate roof, that's the case, it makes triangles, at few places correct continuation and then not correct connections over whole area from one side to opposite side of roof... So it's doing something, but wrong...

ribarm · « **Reply #234 on:** August 22, 2023, 05:21:00 AM »

@Ron

I can not say for sure that attached version will solve at least something as I am facing the same thing on some examples - throws nothing!!! But I've sorted some things as you can see if you download file from previous post... I will try some more fixing if I find spare time, but I doubt it'll be revolutionary fixing... Now I and anyone can see that this is challenge topic... But I tried on some different basis to approach things - by using custom (_offset) function... Anyway thanks for looking into this and feedbacking...

M.R.

ribarm · « **Reply #235 on:** August 24, 2023, 08:43:41 AM »

Hi, me again... I think I've connected what was the problem... I've removed 2 vvl and vvli upon sucessful connecting 2 lines, but also added vvl and vvli to apex of triangle (if it's somewhere in the beggining of calculations)... That with vvl and vvli should iterate all until there are no vvl and vvli... And there is the problem : (prout) sub catched error in it's operations... So routine either crashes before error handler output, or (while) loops into endless time... Either way I finished what should be working, but it's not... So I'll chill out for now until someone figures out and finish it all correctly...
Thanks for attention, M.R.

ribarm · « **Reply #236 on:** August 28, 2023, 09:43:28 AM »

I am stuck here with posted *.lsp in previous reply... Can someone see and solve it, or give opinion, suggestion, advice in right direction...
I've put also previous versions - last one is : roof-newest.lsp... Some new gurus, reply, please...

P.S. I doubt that someone will fix it as it has many lacks, but nevertheless, this was only for experimental purposes... Hope dies lastly, so we are waiting for valuable input...

ribarm · « **Reply #237 on:** September 02, 2023, 05:46:38 AM »

I didn't know that only @Ron came and commented what I posted... @Daniel is busy, but what ab @Cab, @Lee Mac, @Highflyingbird, @Evgeniy-@VovKa (if they are available for conflict situation in their countries)...
My latest intervention is roof-newest.lsp from pre-previous post... IMHO, it should bite and finish and somewhere that's the case, but there are examples where it throws forest of lines that don't have any relation to the code...
My sincerily best wishes to anyone reading and willing to help...
M.R.

BIGAL · « **Reply #238 on:** September 02, 2023, 07:49:06 PM »

I have been following your comments as years ago did a house package that included roofs it was 3D based so roof pitch was included. We just used a method of making each section of roof using pface. had a number of options Hip, Gable, Straight, Flat etc Unfortunately the package never took off. It was overtaken by Autocad Architecture.

ribarm · « **Reply #239 on:** September 08, 2023, 04:14:54 PM »

Can someone have a look at my (mc) sub function and complete routine for lacks... I believe that (mc) function is the key for solving as much as possible... I am out of fuel for coding, but no one want to even download "roof-newest.lsp" and look - 4 eyes are more than 2... I believe that I am close, but routine gives forest of lines in no relation to what's written in routine, but i may be wrong... So basically I am looking for help for this particular versions with custom (_offset) sub...

Thanks for reading,
Maybe at the end someone will relight my candles of hope...

News:

Author Topic: ==={Challenge}===Find the ridge lines of sloped roof (Read 106836 times)

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

It's Alive!

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ronjonp

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof

BIGAL

Re: ==={Challenge}===Find the ridge lines of sloped roof

ribarm

Re: ==={Challenge}===Find the ridge lines of sloped roof