Topic: Trivial question - variable paper space / model

[Lupo76]

Hello everyone,
how do I know if the pointer is:
- In paper space
- In a paper space viewport (model space so)

I tried with CTAB, but it always returns the name of the layout even if the pointer is in window.
Even TILEMODE not good.

[irneb]

Several ways, but for me the easiest is to check TileMode. If 0 then on a PS tab. Then if CVport > 1 you know you're inside a viewport, since VP# 1 is the paper space itself.

[Lee Mac]

I just use CVPORT 

[irneb]

The problem with only CVport is it equals 2 while on the Model tab (i.e. when TileMode=1), don't know why - I'd have imagined 0 would be more useful. Though if you have tiled viewports on the model tab I could possibly understand. But a CVPort=2 thus might mean you're inside the 1st viewport on paper space, or it might mean you're on the Model tab.

Edit: Actually, I understand what you're saying Lee. If all you really need to know is which space is active, then CVPort>1 means Model Space is active, CVPort=1 means Paper Space.

[Lee Mac]

Edit: Actually, I understand what you're saying Lee. If all you really need to know is which space is active, then CVPort>1 means Model Space is active, CVPort=1 means Paper Space.

Exactly - when creating objects, for most cases this is all you need to know 

[alanjt]

Precisely how we get away with the following...

Code: [Select]

(vlax-get (vla-get-activedocument (vlax-get-acad-object))
          (if (eq (getvar 'CVPORT) 1)
            'Paperspace
            'Modelspace
          )
)

[irneb]

Exactly. It's just that from the OP I understood that he wanted to know if he was inside a viewport or on paperspace. Perhaps for something like applying VP overrides or such. In such case you need to compare TileMode as well.

Anyhow, now all is shown 

[BlackBox]

Anyhow, now all is shown 

Irneb's rocking out with his CVPORT out 

[Lupo76]

I can not leave you alone for 5 minutes 

Thanks to all!

[irneb]

Irneb's rocking out with his CVPORT out 

[hermanm]

Code - Auto/Visual Lisp: [Select]

1. ;;--------------------- tktn_getscl--------------------------------------
2. ;;      Purpose: calculate scale factor
3. ;;      Uses:    nothing
4. ;;      Returns: sf
5. ;;      Method due to Ian Bryant
6. ;;-----------------------------------------------------------------
7. (defun tktn_getscl( )
8.   (cond ((= 1 (getvar "TILEMODE")) (getvar "DIMSCALE"));tiled space
9.         ((= 1 (getvar "CVPORT")) 1.0);in paper space
10.      ;; in a viewport
11.         (T
12.           (last (trans '(0 0 1.0) 3 2));calc scale factor
13.         )
14.   );cond
15. )
16.  

[nivuahc]

I've been using the following, by Jeff Mishler (as part of the routine found here), with great success for some time now.

Code - Auto/Visual Lisp: [Select]

1. (defun get_space ()
2.     (if (= 1 (vla-get-activespace *doc*))
3.       (vla-get-modelspace *doc*)        ;we're in modelspace
4.       (if (= (vla-get-mspace *doc*) :vlax-true)
5.         (vla-get-modelspace *doc*)      ;we're in modelspace
6.                                         ;thru paperspace VPort
7.         (vla-get-paperspace *doc*)      ;we're in paperspace
8.       )
9.     )
10.   )

[CAB]

The one I use:

Code: [Select]

(defun activespace (doc)
  (if (or (= acmodelspace (vla-get-activespace doc))
          (= :vlax-true (vla-get-mspace doc)))
      (vla-get-modelspace doc)
      (vla-get-paperspace doc)
  )
)