Topic: quoting polyline

[Lupo76]

Hello everyone,
I have to create a function that fits the dimensions along the segments of a polyline.
I have made ​​this function, but is not able to manage the arcs present in a polyline.
In fact to obtain the vertices of the polyline using the following function:

Code: [Select]

(defun vertexpoli (oggreg / coords n p listavertex)
  (vl-load-com)
  (setq coords (vla-get-coordinates (vlax-ename->vla-object oggreg)))
  (setq coords (vlax-safearray->list (vlax-variant-value coords)))
  (setq n 0)
  (setq p (list (nth n coords)  (nth (+ n 1) coords)))
 
  (repeat (/ (length coords) 2)
    (progn
      (if listavertex
        (setq listavertex (append (list p) listavertex))
        (setq listavertex (list p))
      )
      (setq n (+ n 2))
      (setq p (list (nth n coords)  (nth (+ n 1) coords)))
    )
  )
  listavertex
)

Can you give me some advice on how to implement it, add to the list, the data of the arcs?

[efernal]

one way:

see dxf code 42 (bulge)
find out the included angle and  divide by 2.0
find out the distance between start point and end point
use half of this distance and half of included angle to calculate radius, so length will be radius * included angle

[irneb]

If it's just a situation of wanting points on the arc vectors or their arc lengths, then perhaps look into the vlax-curve-* functions.

[ribarm]

Check these posts :

http://forums.augi.com/showthread.php?134324-Polylines-dimensions-export-to-excel/page3&post#24

http://forums.augi.com/showthread.php?134324-Polylines-dimensions-export-to-excel/page3&post#29

M.R.

P.S. You may also want to use this code (c:Rebar) :
http://forums.augi.com/showthread.php?135690-Get-Polyline-segments/page4&post#32

[Lupo76]

What to say .... 
I did not think just find all this code ready! 

Thank you!

[ElpanovEvgeniy]

What to say .... 
I did not think just find all this code ready! 

Thank you!

Code - Auto/Visual Lisp: [Select]

1. (defun test (e)
2.   ;; (test (car(entsel)))
3.   (vl-remove nil
4.              (mapcar (function (lambda (a b)
5.                                  (if (= (car a) 10)
6.                                    (list (cdr a) (cdr b))
7.                                  )
8.                                )
9.                      )
10.                      (entget e)
11.                      (cdddr (entget e))
12.              )
13.   )
14. )

test:

Code: [Select]

(test (car(entsel)))
=>>
'(((1728.94 1778.07) 0.0)
  ((1945.34 1892.39) 0.0)
  ((2269.92 1759.53) 0.0)
  ((2671.7 2161.3) -0.694158)
  ((3098.4 1966.54) 0.0685342)
  ((3135.5 1404.21) -0.538618)
  ((2647.19 915.904) -0.187763)
  ((1973.16 1351.68) -0.851784)
  ((2147.77 1526.3) 1.95618)
  ((2147.77 1635.94) -0.23567)
  ((1715.03 1564.88) 1.02521)
)

[Lee Mac]

Another

Code - Auto/Visual Lisp: [Select]

1. (defun _lwvertices ( e )
2.     (if (setq e (member (assoc 10 e) e))
3.         (cons
4.             (cons
5.                 (cdr (assoc 10 e))
6.                 (cdr (assoc 42 e))
7.             )
8.             (_lwvertices (cdr e))
9.         )
10.     )
11. )

Code: [Select]

(_lwvertices (entget (car (entsel))))
=>>
(
    ((-230.89 -9.2228) . 0.0)
    ((-221.288 16.2617) . -0.495079)
    ((-201.074 22.3174) . 0.553551)
    ((-185.407 28.6254) . 0.0)
    ((-190.208 48.3065) . 0.0)
    ((-206.633 48.3065) . 0.0)
)

[ElpanovEvgeniy]

for test:

Code - Auto/Visual Lisp: [Select]

1. (defun test1 (/ l)
2.   (setq l (test (car (entsel "\n Select LWPOLYLINE:"))))
3.   (entmakex
4.     (append (list '(0 . "LWPOLYLINE")
5.                   '(100 . "AcDbEntity")
6.                   '(67 . 0)
7.                   '(410 . "Model")
8.                   '(8 . "0")
9.                   '(62 . 1)
10.                   '(100 . "AcDbPolyline")
11.                   (cons 90 (length l))
12.                   '(70 . 0)
13.             )
14.             (apply (function append)
15.                    (mapcar (function (lambda (a) (list (cons 10 (car a)) (cons 42 (cadr a))))) l)
16.             )
17.     )
18.   )
19.   (princ)
20. )

[ElpanovEvgeniy]

Hi Lee Mac! 
Great idea to use recursion - got short and clear!

ps. long time no theme challenge...
bored 

[Lee Mac]

Hi Lee Mac! 
Great idea to use recursion - got short and clear!

Thank you! Your method was also very interesting 

Another for Polyline:

Code - Auto/Visual Lisp: [Select]

1. (defun _vertices ( e / l )
2.     (if (eq "VERTEX" (cdr (assoc 0 (setq l (entget e)))))
3.         (cons
4.             (cons
5.                 (cdr (assoc 10 l))
6.                 (cdr (assoc 42 l))
7.             )
8.             (_vertices (entnext e))
9.         )
10.     )
11. )

ps. long time no theme challenge...
bored 

   A challenge is long overdue 

[irneb]

Sorry to chip in, had to have a go at this too 
ActiveX version works on both LWPoly and old Poly:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun ExtractVertices  (ename / obj lst n)
4.   (setq obj (vlax-ename->vla-object ename) n 0)
5.   (vl-remove-if
6.     'null
7.     (mapcar
8.       '(lambda (a b / m)
9.          (setq m n n (1+ n))
10.          (if (= (rem m 2) 0) (cons (cons a b) (vla-GetBulge eo (/ m 2)))))
11.       (setq lst (vlax-get eo 'Coordinates))
12.       (cdr lst))))

[irneb]

That actually gave me an idea ... what about a grouping function to get around that hassle of ActiveX coordinates: http://www.theswamp.org/index.php?topic=41419.0

[ElpanovEvgeniy]

Code - Auto/Visual Lisp: [Select]

1. (defun f (o i)
2.   (if (< i (vlax-curve-getEndParam o))
3.     (cons (cons (vlax-curve-getPointAtParam o i) (vla-getbulge o i)) (f o (1+ i)))
4.   )
5. )

test:

Code - Auto/Visual Lisp: [Select]

1. (f (vlax-ename->vla-object(car(entsel))) 0)