Topic: Averaging

[MP]

Hi folks. Long time no see/talk. Been sick, but not wishing to dwell on that. Hope everyone is well.

Anyway ... had need to write a simple average function that could take a list of numbers, or a list of coordinates, and average the result.

Thought it might make a fun simple challenge for the cumpulsive lisp authors that hang their hats here.

Given: (1 2 3 4 5) or ((1 2) (3 4) (5 6)) or ((1) (2 3) (4 5 6))

Return: 3.0 or (3.0 4.0) or (2.33333 2.66667 2.0) respectively.

Code: [Select]

(defun _Avg ( lst )

    (cond
        ((vl-some 'vl-consp lst) (cons (_Avg (mapcar 'car lst)) (_Avg (mapcar 'cdr lst))))
        ((vl-some 'numberp lst) (/ (apply '+ (subst 0 nil lst)) (float (length lst))))
    )

)
Cheers.

[Lee Mac]

Quick hack, but I fail for the last one:

Code - Auto/Visual Lisp: [Select]

1. (defun _avg ( l / n )
2.     (setq n (float (length l)))
3.     (if (vl-some 'listp l)
4.         (mapcar '(lambda ( x ) (/ x n)) (apply 'mapcar (cons '+ l)))
5.         (/ (apply '+ l) n)
6.     )
7. )

Nice to see you again MP 

[Lee Mac]

Another, but not too different to yours:

Code - Auto/Visual Lisp: [Select]

1. (defun _avg ( l / r n )
2.     (setq n (float (length l)))
3.     (cond
4.         (   (listp (car l))
5.             (repeat (apply 'max (mapcar 'length l))
6.                 (setq r (cons (/ (apply '+ (subst 0 nil (mapcar 'car l))) n) r)
7.                       l (mapcar 'cdr l)
8.                 )
9.             )
10.             (reverse r)
11.         )
12.         (   (/ (apply '+ l) n))
13.     )
14. )

This method of transposition would also work if we excluded the last example:

Code - Auto/Visual Lisp: [Select]

1. (defun _avg ( l )
2.     (if (listp (car l))
3.         (mapcar '_avg (apply 'mapcar (cons 'list l)))
4.         (/ (apply '+ l) (float (length l)))
5.     )
6. )

[MP]

Nicely done Lee (like the brevity of the 6 liner) and thanks for the greets.

[adalea03]

MP
Your humility is admirable.

LM
You continue to raise the bar so high (as MP has done so often)
that I can still walk under it without stooping.

I can only imagine what auto/visual Lisp might have been if minds like yours (and others here)
were a part of the developing teams.

Tony

[Kerry]

Hi folks. Long time no see/talk. < ....>

Great to see you posting again Michael.
Best wishes,
Regards,

[Lee Mac]

Nicely done Lee (like the brevity of the 6 liner) and thanks for the greets.

Thanks Michael 

LM
You continue to raise the bar so high (as MP has done so often)
that I can still walk under it without stooping.

I can only imagine what auto/visual Lisp might have been if minds like yours (and others here)
were a part of the developing teams.

Tony

That's very kind of you to say Tony, thanks 

[irneb]

Hope you're feeling well again MP.

Great idea! And great work MP & Lee! I love how novel, brief, succinct, elegant and robust code can be made in Lisp. I'm trying to imagine how many bible sheets I'd have typed to get the same function in C  :ugly:

Here's another to "extend" on the idea. What about obtaining the median instead of the average? Say something like this:

Code: [Select]

(defun _Median (lst / avg closest diff %compare%)
  (setq avg     (_Avg lst)
        closest (car lst)
  )
  (cond
    ((numberp avg)
     (setq diff (abs (- avg closest))
           lstp 0
     )
     (defun %compare% (num / diff1)
       (if (<= (setq diff1 (abs (- num avg))) diff)
         diff1
       )
     )
    )
    ((vl-consp avg)
     (setq diff (distance avg closest)
           lstp 1
     )
     (defun %compare% (pt / diff1)
       (if (<= (setq diff1 (distance num avg)) diff)
         diff1
       )
     )
    )
    (t (defun %compare% (num) nil))
  )
  (car
    (reverse (vl-remove-if-not
               '(lambda (n / d)
                  (if (setq d (%compare% n))
                    (setq closest n
                          diff d
                    )
                  )
                )
               (cdr lst)
             )
    )
  )
)

[CAB]

Good to see you back Michael. 

[MP]

Good to see you back Michael. 

Thank you Charles, good to see your hat still hangs here prominantly.

Hope you're feeling well again MP ... Here's another to "extend" on the idea ...

Thank you sir. I love when code snips spawn other ideas, the very essence of the swamp.

Great to see you posting again Michael.
Best wishes,
Regards

Thank you Kerry, and to you and yours the best.

MP
Your humility is admirable.

I think you have me confused with someone else but I'll steal the kind words from you anyway.

[irneb]

I love when code snips spawn other ideas, the very essence of the swamp.

... So that's what the swamp is all about! At last I get it: It's a spawning pond!

[irneb]

Actually to take my "spawned" idea  and make it a bit "better" ... seeing as it's not truly the correct definition of "Median":

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. ;;; By MP: http://www.theswamp.org/index.php?topic=41352.0
4. (defun _Avg  (lst)
5.   (cond ((vl-some 'vl-consp lst) (cons (_Avg (mapcar 'car lst)) (_Avg (mapcar 'cdr lst))))
6.         ((vl-some 'numberp lst) (/ (apply '+ (subst 0 nil lst)) (float (length lst))))))
7.  
8. ;;; Get closest point or number to another point or number
9. (defun _Closest  (lst val / diff)
10.   (cond ((listp val)
11.          (setq diff (distance (car lst) val))
12.          (last (vl-remove-if-not
13.                  (function (lambda (pt / d)
14.                              (if (<= (setq d (distance pt val)) diff)
15.                                (setq diff d))))
16.                  lst)))
17.         ((numberp val)
18.          (setq diff (abs (- (car lst) val)))
19.          (last (vl-remove-if-not
20.                  (function (lambda (num / d)
21.                              (if (<= (setq d (abs (- num val))) diff)
22.                                (setq diff d))))
23.                  lst)))))
24.  
25. ;;; Get most average point or number
26. (defun _ClosestToAvg (lst /) (_Closest lst (_Avg lst)))

Not to mention ... it's a bit more succinct, and gives the core as a separate usable function _Closest.

Edit: Code altered to reduce the stupid (car (reverse ... )) into (last ... )  :ugly:
And trying out another formatting alternative - more like python format.

[irneb]

And of cource the "true" definition of Median (if you have a sorted list):

Code - Auto/Visual Lisp: [Select]

1. (defun _Median (lst / n)
2.   (setq n (/ (length lst) 2))
3.   (cond
4.     ((vl-consp (car lst))
5.      (if (= (rem n 2) 0)
6.        (mapcar (function (lambda (a b) (/ (+ a b) 2.))) (nth n lst) (nth (1+ n) lst))
7.        (nth n lst)
8.      )
9.     )
10.     ((numberp (car lst))
11.      (if (= (rem n 2) 0)
12.        (/ (+ (nth n lst) (nth (1+ n) lst)) 2.)
13.        (nth n lst)
14.      )
15.     )
16.   )
17. )

Though with a point list there may be several ways to sort it, e.g. X then Y then Z, or distance from origin, or distance from another point, or clockwise, or ccw, etc.