Topic: Copy nested object(s) - how to work with XRefs?

[alanjt]

I'm using the vla-copyobjects method to copy a nested object and if it's just a nested object within a block, it works fine, but I can't figure out how to get it to work with an Xref. Any help would be greatly appreciated.

Here's a snippet of code that I'm trying to work with...

Code: [Select]

(defun c:Test (/ doc space ent obj new)

  (setq doc   (vla-get-activedocument (vlax-get-acad-object))
        space (if (eq (getvar 'CVPORT) 1)
                (vla-get-paperspace doc)
                (vla-get-modelspace doc)
              )
  )

  (if (setq ent (nentselp "\nSelect nested object to copy: "))
    (progn (if (eq (cdr (assoc 0 (entget (car ent)))) "VERTEX")
             (setq obj (vlax-ename->vla-object (cdr (assoc 330 (entget (car ent))))))
             (setq obj (vlax-ename->vla-object (car ent)))
           )
           (setq new (car (vlax-invoke doc 'CopyObjects (list obj) space)))
           (vla-transformby new (vlax-tmatrix (caddr ent)))
    )
  )
  (princ)
)
Do I have to use ODBX? I keep getting the following error: Error: AutoCAD.Application: Object not in database

[Matt__W]

I believe there's a LSP for Autodesk's NCOPY command (I can't see my C:\ drive so I can't tell you were to look - I think it's part of the Express Tools).  You could disect that file and see how it works.

[alanjt]

I believe there's a LSP for Autodesk's NCOPY command (I can't see my C:\ drive so I can't tell you were to look - I think it's part of the Express Tools).  You could disect that file and see how it works.

Yeah, I looked there. It uses a series of entmake(x) functions - not what I was hoping for, but if I can't get copyobjects to work, I'll have to go that route. I was just thinking this would be a little less aggravating.

[VovKa]

Code: [Select]

(vlax-invoke doc 'CopyObjects (list obj) space)

i think 'doc' is wrong, it must be XRefDatabase not Document

[Lee Mac]

Why not just:

Code: [Select]

(defun c:test ( / a b )
    (if
        (and
            (setq a (nentselp))
            (= 4 (length a))
            (setq b (entmakex (entget (car a))))
        )
        (vla-transformby (vlax-ename->vla-object b) (vlax-tmatrix (caddr a)))
    )
    (princ)
)
(With the check for the Vertex Entity)

Or did I miss something?

[alanjt]

Code: [Select]

(vlax-invoke doc 'CopyObjects (list obj) space)

i think 'doc' is wrong, it must be XRefDatabase not Document

That make sense. Will have to investigate more.

I'm such a retard. I was thinking it would be heavily convoluted to use entmake, but it's actually pretty simple since I only care about curves.

sample (tested on nested 3dpolyline, arc, line, lwpolyline, ellipse, arc, circle, xline, ray)...

Code: [Select]

(defun _entmakeNestedCurve (ent matrix / e d)
  (if (eq (cdr (assoc 0 (entget ent))) "VERTEX")
    (progn (entmake (entget (setq ent (cdr (assoc 330 (entget ent))))))
           (while (/= (cdr (assoc 0 (setq d (entget (setq ent (entnext ent)))))) "SEQEND")
             (setq e (entmakex d))
           )
           (setq e (cdr (assoc 330 (entget (entmakex '((0 . "SEQEND")))))))
    )
    (setq e (entmakex (entget ent)))
  )
  (vla-transformby (vlax-ename->vla-object e) (vlax-tmatrix matrix))
  e
)



(defun c:Test (/ ent)
  (if (setq ent (nentselp "\nSelect nested curve to copy: "))
    (vla-put-color (vlax-ename->vla-object (_entmakeNestedCurve (car ent) (caddr ent))) 3)
  )
  (princ)
)

[alanjt]

Why not just:

(With the check for the Vertex Entity)

Or did I miss something?

Oops, missed your post.
I was concerned about 3d/2dpolylines, but it was a lot easier than I'd imagined.

[VovKa]

That make sense. Will have to investigate more.

that's the way

Code: [Select]

(setq new
                        (car
                            (vlax-invoke
                                (vla-get-XRefDatabase
                                    (vla-Item
                                        (vla-get-Blocks doc)
                                        (vla-get-Name
                                            (vlax-ename->vla-object (car (last ent))
                                            )
                                        )
                                    )
                                )
                                'CopyObjects
                                (list obj)
                                space
                            )
                        )
               )

[alanjt]

That make sense. Will have to investigate more.

that's the way

Code: [Select]

(setq new
                        (car
                            (vlax-invoke
                                (vla-get-XRefDatabase
                                    (vla-Item
                                        (vla-get-Blocks doc)
                                        (vla-get-Name
                                            (vlax-ename->vla-object (last (last ent))
                                            )
                                        )
                                    )
                                )
                                'CopyObjects
                                (list obj)
                                space
                            )
                        )
               )

Ahhh, that makes total sense. 
Thanks so much Vovka.

[VovKa]

Thanks so much Vovka.

i've edited my post, must be car not last

[alanjt]

Thanks so much Vovka.

i've edited my post, must be car not last

Cool. I hadn't had a chance to test your code, only look at it to see what you were doing. Really, thanks again.

[CAB]

This wont do it?
http://www.theswamp.org/index.php?topic=27354.msg329179#msg329179