Topic: Dimassoc Value

[MeasureUp]

On my drawing the "dimassoc" is pre-set to "1".
I am confused by this:

Code: [Select]

(defun c:test (/ DimAssocValue)
(initget "0 1 2")
(setq DimAssocValue (getkword "\n0, <1>, or 2: "))
(if (or (= DimAssocValue 0)
(= DimAssocValue 1)
(= DimAssocValue 2)
)
(setvar "dimassoc" (atoi DimAssocValue))
)
(prompt (strcat "\n" "DimAssoc Value = " (itoa (getvar "dimassoc"))))
(setvar "dimassoc" 1) [color=red]; <= I want "dimassoc" reset to "1" after executing.[/color]
[color=green](princ)[/color]
)

The line of "prompt" is expected to return a "2" if the user enters "2".
But in fact this is what I got after entering "2":

Command:
TEST
0, <1>, or 2: 2

DimAssoc Value = 11

What is wrong?

[alanjt]

Add a closing (princ) to your code. The first 1 is your returned value and the second 1 is returned from you resetting the system variable.

[MeasureUp]

Add a closing (princ) to your code. The first 1 is your returned value and the second 1 is returned from you resetting the system variable.

Sorry for the rough sketch.
(princ) does the job.

But as I said the "dimassoc" is pre-set to "1" on my drawing.
At the "prompt" line in the code, it should return "2".
Now it returns "1".
Did I miss something?

[CAB]

Try this:

Code: [Select]

(defun c:test (/ DimAssocValue)
  (initget "0 1 2")
  (setq DimAssocValue (getkword "\n0, <1>, or 2: "))
  (if (member DimAssocValue '("0" "1" "2"))
    (setvar "dimassoc" (atoi DimAssocValue))
  )
  (prompt (strcat "\n" "DimAssoc Value = " (itoa (getvar "dimassoc"))))
  (setvar "dimassoc" 1)
  (princ)
)

[MeasureUp]

Big THANKS to CAB.  
It is great.

But why my "or" statement is wrong?

I also upated the code:

Code: [Select]

(defun c:test (/ ass DimAssocValue)
(setq ass (getvar "dimassoc"))
(initget "0 1 2")
(setq DimAssocValue (getkword "\n0, <1>, or 2: "))
(if (member DimAssocValue '("0" "1" "2"))
(setvar "dimassoc" (atoi DimAssocValue))
)
(prompt (strcat "\n" "DimAssoc Value = " (itoa (getvar "dimassoc"))))
(command "dimlinear")
(setvar "dimassoc" ass)
(princ)
)

The dimension drawn is not associative when the "dimassoc" is set to "2".
What is wrong?

[CAB]

getkword returns string value and you were comparing the result to integers.

[MeasureUp]

getkword returns string value and you were comparing the result to integers.

Yes, it's the trick. Thanks again. 
Another one is what is wrong with the updated code on Reply#4?

[MeasureUp]

The Problem has been solved.
- End of the Thread.

[CAB]

Glad you conquered the problem.

[MeasureUp]

Glad you conquered the problem.

Thanks again. 

[MeasureUp]

I think I have to open this thread again for another question. 

This is what I have and the red is the trick for my last problem:

Code: [Select]

(defun c:test (/ ass DimAssocValue)
(setq ass (getvar "dimassoc"))
(initget "0 1 2")
(setq DimAssocValue (getkword "\n0, <1>, or 2: "))
(if (member DimAssocValue '("0" "1" "2"))
(setvar "dimassoc" (atoi DimAssocValue))
)
(prompt (strcat "\n" "DimAssoc Value = " (itoa (getvar "dimassoc"))))
(command "dimlinear" [color=red]pause pause pasue[/color])
(setvar "dimassoc" ass)
(princ)
)

How to do if I want have a loop (while) function for "dimlinear"?
Thanks.

[Lee Mac]

Your last 'pause' is spelt wrong 

Consider perhaps something along these lines:

Code: [Select]

(defun c:test ( / ass elast )

  (setq ass (getvar 'DIMASSOC))
  (initget "0 1 2")
  (setvar 'DIMASSOC (atoi (cond ( (getkword "\nSpecify DIMASSOC Value [0/1/2] <1>: ") ) ( "1" ))))

  (prompt (strcat "\nDIMASSOC Value = " (itoa (getvar 'DIMASSOC))))

  (setq elast t)
  (while (not (equal elast (setq elast (entlast))))
    (command "_.dimlinear" pause pause pause)
  )
  (setvar 'DIMASSOC ass)
  (princ)
)
Don't worry about the capitalised System Variables, that's just a habit of mine...

[MeasureUp]

Thanks Lee.

Your last 'pause' is spelt wrong

I will check if my keys were labelled wrong. 

A question to ask before giving your revision a try.
I notice that in your version you change all "dimassoc" to 'dimassoc.
Could you kindly explain what is the advantage(s) by doing this?
Thanks again.

[Lee Mac]

No advantage, both are equally valid - I just have my habits...  :ugly:

[MeasureUp]

Ok, I tried it.
When I stop the while function the code doesn't continue and reset the dimassoc to 1.
I preset the dimassoc to 1 before run the code.