Topic: Check if Command is Running

[cmwade77]

Ok, I have looked, but have not found the answer yet, I need to know three things:
1. How do I check if a command is already running?
2. If a command is already running, is it the array command?
3. How do I cancel it if it is?

I am creating a tool palette, so it is possible that a command is already running, but it is also possible that I will need to not cancel the command, but interact with this command while it is running, so I do need to know how to do both things separately.

[Matt__W]

As a starting point, take a look at CMDACTIVE.

[cmwade77]

Ok, that tells me if a command is running....now I need to know if it is the array command or not. And how to cancel the running command via LISP.

[Crank]

If you redefine the ARRAY command, you can set a marker.

[alanjt]

Code: [Select]

(getvar 'CMDNAMES)

[cmwade77]

That will do the trick for that....now for the life of me, I can't seem to figure out how to cancel an active command by using LISP.

[Lee Mac]

Code: [Select]

(command) ... (command)

[cmwade77]

Thank you Lee, I knew it had to be something simple like that.

[cmwade77]

Code: [Select]

(command) ... (command)

Ok, so I am trying to use this to cancel drawing a pline, but it doesn't seem to work, please see my code below:

Code: [Select]

  (setq pt1 (getpoint "\nSelect the first point: "))
  (cond
(pt1
  (vla-StartUndoMark *ACAD_DOC*)
  (command "._pline" pt1)
  (setq ct 0)
  (princ "\n")
  (while pt1
(setq pt1 (getpoint pt1 "Select the next point (press enter to close):"))
(cond
  (pt1
(command pt1)
(setq ct (+ ct1))
  )
  (T
(cond
  ((= ct 0)
(princ "\nCommand Canceled.\n")
(command)(command)
  )
  ((= ct 1)
(princ "\nObject invalid.")
(command)(command)
(vla-EndUndoMark *ACAD_DOC*)
(command "._undo")
  )
  (T
(command "_C")
  )
)
  )
)
  )Any ideas?

[Lee Mac]

Why not:

Code: [Select]

(command "_.pline")
(while (= 1 (logand 1 (getvar 'CMDACTIVE))) (command pause))

[chlh_jd]

Hi all , just for fun

Code: [Select]

(defun c:tar (/ pt1 pt2 len str en) 
  (and
    (setq pt1 (getpoint "first point: "))
    (setq pt2 (getpoint pt1 ">Second point: "))
    (progn
      (setq len (distance pt1 pt2))
      (command "pline" pt1 "w" 0 (* 1.8 len) pt2)
      (command "w" (* 0.4 len) (* 1.3 len) "a")
      (command pause)
      (princ "\nNextpoint<Print Enter for end>: ")
    )
  )   
  (princ)
)
and following ...

Code: [Select]

(defun c:tar (/ pt1 pt2 len str en) 
  (and
    (setq pt1 (getpoint "first point: "))
    (setq pt2 (getpoint pt1 ">Second point: "))
    (progn
      (setq len (distance pt1 pt2))
      (command "pline" pt1 "w" 0 (* 1.8 len) pt2)
      (command "w" (* 0.4 len) (* 1.3 len) "a")
      (command pause)
      (princ "\nendpoint: ")
    )
  ) 
 (command "") 
  (princ)
)


[cmwade77]

Why not:

Code: [Select]

(command "_.pline")
(while (= 1 (logand 1 (getvar 'CMDACTIVE))) (command pause))

Grr...I hate when I over think the problem, that helps a lot, thank you.

[Lee Mac]

Grr...I hate when I over think the problem, that helps a lot, thank you.

We've all been there    You're welcome.

[efernal]

Code: [Select]

(DEFUN c:test (/ cn p1 p2)
  (IF (SETQ p1 (GETPOINT "\n-> Initial point : "))
    (IF (SETQ p2 (GETPOINT p1 "\n-> Second point : "))
      (PROGN (SETQ cn 2)
             (COMMAND "_.PLINE")
             (COMMAND "_NON" p1 "_NON" p2)
             (WHILE (SETQ p1 (GETPOINT p2 "\r-> Another point or ENTER for finish : "))
               (COMMAND "_NON" p1)
               (SETQ p2 p1
                     cn (1+ cn)
               )
             )
             (IF (> cn 2)
               (COMMAND "_CLOSE")
               (COMMAND nil)
             )
      )
      (PRINC "\n-> No second point...")
    )
    (PRINC "\n-> First point not given...")
  )
  (PRINC)
)


[cmwade77]

Why not:

Code: [Select]

(command "_.pline")
(while (= 1 (logand 1 (getvar 'CMDACTIVE))) (command pause))

This is working great, but I need to get the last point picked, any ideas?