Topic: -={ Challenge }=- Incircle & Circumcircle of a Triangle

[Lee Mac]

There's a superfuous statement in the code I posted: as p1 lies on the plane, its 'caddr' will always be equal to 0. :loco:

Not necessarily, since the points will be transformed relative to the plane through the origin, you'll still need to use the Z-value of a point in the plane to get the correct elevation.

[Lee Mac]

Another, to practice the method, finding the point in the plane closest to the supplied point:

Code: [Select]

(defun ClosestPointonPlane ( pt p1 p2 p3 )
  (
    (lambda ( n )
      (setq pt (trans pt 0 n)) (trans (list (car pt) (cadr pt) (caddr (trans p1 0 n))) n 0)
    )
    (v^v (mapcar '- p2 p1) (mapcar '- p3 p1))
  )
)

(defun v^v ( u v )
  (list
    (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
    (- (* (car  v) (caddr u)) (* (car  u) (caddr v)))
    (- (* (car  u) (cadr  v)) (* (car  v) (cadr  u)))
  )
)

[gile]

There's a superfuous statement in the code I you posted: as p1 lies on the plane, its 'caddr' will always be equal to 0. :loco:

EDIT: wrong code de below...

Code: [Select]

(defun ClosestPointonPlane ( pt p1 p2 p3 )
  (
    (lambda ( n )
      (setq pt (trans pt 0 n)) (trans (list (car pt) (cadr pt) [color=red]0.[/color]) n 0)
    )
    (v^v (mapcar '- p2 p1) (mapcar '- p3 p1))
  )
)

[Lee Mac]

There's a superfuous statement in the code I you posted: as p1 lies on the plane, its 'caddr' will always be equal to 0.

Not sure about that, see #30 

[gile]

You are absolutely right Lee, it's time I go sleeping...

[Lee Mac]

You are absolutely right Lee, it's time I go sleeping...

Thanks Gile, but I wouldn't worry, you were right with your first code 

[gile]

More, there're both part my library (with normal and origin instead of 3 points)

Code: [Select]

;; gc:elevation
;; Retourne l'ιlιvation du point par rapport au plan
(defun gc:elevation (pt norm org)
  (- (caddr (trans pt 0 norm)) (caddr (trans org 0 norm)))
)

;; gc:ProjectOnPlane
;; Retourne la projection de pt sur le plan
(defun gc:ProjectOnPlane (pt norm org)
  ((lambda (p o)
     (trans (list (car p) (cadr p) (caddr o)) norm 0)
   )
    (trans pt 0 norm)
    (trans org 0 norm)
  )
)

[Lee Mac]

More, there're both part my library (with normal and origin instead of 3 points)

It happens to the best of us 

[qjchen]

Code: [Select]

(defun ClosestPointonPlane ( pt p1 p2 p3 )
  (
    (lambda ( n )
      (setq pt (trans pt 0 n)) (trans (list (car pt) (cadr pt) [color=red]0.[/color]) n 0)
    )
    (v^v (mapcar '- p2 p1) (mapcar '- p3 p1))
  )
)

cool,Gile, and thanks Lee Mac for your beautiful code.

Last night is a sleepless night(my baby wake me up time and time again), I think out I shouldnt use cross *, but should use dot *. And when morning I realize it as follows and shorten a bit. But your trans shock me, it is more short.

It is time for me to think trans over and over.

Thank you all, I learn a lot from this post.

Code: [Select]

(defun q:geo:point-dis-to-plane4(p p1 p2 p3)
   ((lambda(n)
      (/ (abs (apply '+ (mapcar '* n (mapcar '- p p1))))
          (distance '(0. 0. 0.) n)
      )
   )
   (gc:CrossProduct (mapcar '- p2 p1) (mapcar '- p3 p1)))
)