Topic: Tell me why I did it like this. :)

[Lee Mac]

Smarty-pants 

[JohnK]

`Smarty-pants'? If you a referring to my IQ, yes. If you are referring to my code, *meh* more like experience and a few books (In AutoLISP: it is better to operate on a list. In programming: it is always better to K.I.S.S.).

But you had to see something like that coming didn't you (I thought I taught you how to build a substitution model)? ...You were putting a heck of a lot of information on the Stack; you would have done better to use a recursive procedure with an iterative process instead. I would be willing to bet that my procedure would still have been faster but at least yours would have been able to handle a longer string then it currently does.

Anyways, I'm going to a friends house for food and a movie. Take care.

[Kerry]

Lee,
This would be a far faster method (NOTE: I reformatted this function in the VLIDE for Kerry ).

Code: [Select]

;; < .. >

I thank you, my therapist thanks you. 

[MP]

Don't know how this performs comparably but it's how I would do it:

Code: [Select]

(defun SplitByCaps ( text / lst )
    (vl-list->string
        (cons
            (car (setq lst (vl-string->list text)))
            (apply 'append
                (mapcar
                    (function (lambda (x) (if (zerop (logand 32 x)) (list 32 x) (list x))))
                    (cdr lst)
                )
            )    
        )    
    )
)

[alanjt]

my contribution...

Code: [Select]

(defun AT:SplitByCaps (s)
  (apply
    (function strcat)
    (cons (substr s 1 1)
          (mapcar (function (lambda (i)
                              (if (<= 65 i 90)
                                (strcat " " (chr i))
                                (chr i)
                              )
                            )
                  )
                  (cdr (vl-string->list s))
          )
    )
  )
)

Code: [Select]

(defun AT:SplitByCaps-2 (s / l)
  (apply
    (function strcat)
    (cons (chr (car (setq l (vl-string->list s))))
          (mapcar (function (lambda (i)
                              (if (<= 65 i 90)
                                (strcat " " (chr i))
                                (chr i)
                              )
                            )
                  )
                  (cdr l)
          )
    )
  )
)
slight change on MP's

Code: [Select]

(defun SplitByCaps (text / lst)
  (vl-list->string
    (cons
      (car (setq lst (vl-string->list text)))
      (apply (function append)
             (mapcar
               (function (lambda (x)
                           (if (<= 65 i 90)
                             (list 32 x)
                             (list x)
                           )
                         )
               )
               (cdr lst)
             )
      )
    )
  )
)

[JohnK]

I don't think i saved the string i used to test but i just constructed it with a minor bit of code. I can see if i can get some time to do it again on Monday but i will place my bet now that MP will take first place and alanjt (third version) will be second place.

[Lee Mac]

Nice coding guys (as always lol)

[Lee Mac]

MP,

Nice idea, but a few other chars don't have the 32-bit set...

Code: [Select]

(SplitByCaps "This[is]a^Te_st")
>> "This [is ]a ^ Te _st"
I like your thinking however.

[MP]

I hear what you're sayin' I've never seen those characters in camel cased enum names.

[Lee Mac]

I hear what you're sayin' I've never seen those characters in camel cased enum names.

Fair point - I was in the 'generic function' mindset...

[MP]

Good point Lee / Concede, genericized:

Code: [Select]

(defun SplitByCaps ( text / lst )
    (vl-list->string
        (cons
            (car (setq lst (vl-string->list text)))
            (apply (function append)
                (mapcar
                    (function (lambda (x) (if (< 64 x 91) (list 32 x) (list x))))
                    (cdr lst)
                )
            )   
        )   
    )
)

[Lee Mac]

 

[JohnK]

*GACK* MP, your second function was the exact same route i was planning at first too but i couldn't think of how to append it (I tried appending after the uppermost cons) and i gave up and went the easy route. Ah, its so obvious now that i seen how you applied the append I should make myself sit on the floor the rest of the day. *lol*

Anyways, i am assembling a speed test right now. I will report back when i get it done.

[alanjt]

*GACK* MP, your second function was the exact same route i was planning at first too but i couldn't think of how to append it (I tried appending after the uppermost cons) and i gave up and went the easy route. Ah, its so obvious now that i seen how you applied the append I should make myself sit on the floor the rest of the day. *lol*

Anyways, i am assembling a speed test right now. I will report back when i get it done.

slight change on MP's

Code: [Select]

(defun SplitByCaps (text / lst)
  (vl-list->string
    (cons
      (car (setq lst (vl-string->list text)))
      (apply (function append)
             (mapcar
               (function (lambda (x)
                           (if (<= 65 i 90)
                             (list 32 x)
                             (list x)
                           )
                         )
               )
               (cdr lst)
             )
      )
    )
  )
)

[JohnK]

alanjt, *ACK!*