Topic: math, geometric help needed

[Amsterdammed]

Hello there,

i have a geometric problem, i have, some lamps with a certain cable length and need to conetc to one centre connector, how can i find with lisp that hatched area (see example)

Thanks,

Bernd

[gile]

Hi,

Do you really want to do it programmatically ?
You can avoid it using the REGION command, select all circles, then INTERSECT command and select the regions.

[gile]

Here's a LISP which uses this method

<Edit: corrected missing astrerisk>

Code: [Select]

(defun c:minters (/ ss clst rlst)
  (vl-load-com)
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
  (if (ssget '((0 . "CIRCLE")))
    (progn
      (vlax-for c (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(setq clst (cons c clst))
      )
      (vla-delete ss)
      (setq space (if (= 1 (getvar 'cvport))
    (vla-get-PaperSpace *acdoc*)
    (vla-get-ModelSpace *acdoc*)
  )
      )
      (setq rlst (vlax-invoke space 'AddRegion clst))
      (setq reg (car rlst)
    rlst (cdr rlst)
      )
      (while rlst
(vla-Boolean reg acIntersection (car rlst))
(setq rlst (cdr rlst))
      )
      (if (< 0.0 (vla-get-Area reg))
(progn
  (setq hatch (vla-AddHatch
space
acHatchPatternTypePredefined
"ANSI31"
:vlax-false
0
      )
  )
  (vlax-invoke hatch 'AppendOuterLoop (list reg))
  (vla-delete reg)
)
      )
    )
  )
  (princ)
)

[Amsterdammed]

Thanks
I guess you are right, that is a good idea. I Will try it.

Bernd

[Lee Mac]

Gile,

I think you missed an asterisk 

Code: [Select]

(or *acad* (setq *acad[color=blue]*[/color] (vlax-get-acad-object)))


[gile]

Right 

[Lerner]

I must be missing something here. Can't this be done by picking one point with the standard hatch command?