Topic: plotting lisp

[ELOQUINTET]

hey guys i just encountered the problem too when printing an old job which used a different printer. keep me informed on the updates thanks

dan

[CAB]

Daron,

In this code pslayout = LayoutObj

Code: [Select]

   (setq
      curdwg   (vla-get-ActiveDocument (vlax-get-Acad-Object))
      pslayout (vla-get-Layout (vla-get-PaperSpace curdwg))
    )
 ; Call RefreshPlotDeviceInfo before GetPlotDeviceNames
    (vla-RefreshPlotDeviceInfo pslayout)
    (setq sty (vlax-safearray->list
      (vlax-variant-value (vla-GetPlotStyleTableNames pslayout))
    ))

    (setq cfg (vlax-safearray->list
      (vlax-variant-value (vla-Get-PlotConfigurations pslayout))
    ))


Code: [Select]

LayoutObj = #<VLA-OBJECT IAcadLayout 069c7a2c>

[CAB]

Well I found the answer,
Stole this code today,

It sets all layouts in the drawing to a "page setup" entered by the user.
I'm going to modify to allow some sort of pick list, I guess that would have to be dcl dialog box or
a numbered list displayed on the text screen to pick from.
Anyone have a "Text Screen" pick list routine?

CAB

Code: [Select]

(defun c:psetup (/ lst page res)
 (setq lst (mapcar 'strcase (getPagesetups)))
 (while (not page)
  (setq page (strcase (getstring T "\nspecify pagesetup to apply: ")))
  (if (or (= "" page) (not (member page lst)))
   (progn (princ "\npagesetup not found") (setq page nil))
   )
  )


 (initget "All Current")
 (if
  (not
   (setq
    res
    (getkword
     "\n[All/Current]apply pagesestup to which layout(s) : ")))
  (setq res "All")
  )


 (if (= "All" res)
   ; ignore Model Space
  (foreach x (vl-remove "Model" (layoutlist)) (putPagesetup x page))
  ;(foreach x (layoutlist) (putPagesetup x page)) ; Include Model Space
  (putPagesetup (getvar "ctab") page)
  )
 (princ "\nFinished")
 (princ)
 )



; Jason Piercey . May 16th, 2003
; assign a pagesetup to a layout
; [layout] - string, layout name
; [setup] - string, pagesetup to assign
; return: T or nil
(defun putPagesetup (layout setup / layouts plots)
 (defun item-p (collection item)
  (if
   (not
    (vl-catch-all-error-p
     (vl-catch-all-apply
      '(lambda () (setq item (vla-item collection item))))))
   item
   )
  )
 (and
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (or *doc* (setq *doc* (vla-get-activedocument *acad*)))
  (setq layouts (vla-get-layouts *doc*))
  (setq plots (vla-get-plotconfigurations *doc*))
  (setq layout (item-p layouts layout))
  (setq setup (item-p plots setup))
  (not (vla-copyfrom layout setup))
  )
 )


(defun massoc (key alist / x nlist)
 (foreach x alist
  (if (eq key (car x))
   (setq nlist (cons (cdr x) nlist))
   )
  )
 (reverse nlist)
 )

; Return: list of all pagesetups defined in the current drawing or nil
(defun getPagesetups ()
 (massoc 3 (dictsearch (namedobjdict) "Acad_PlotSettings"))
 )



[ronjonp]

Hey CAB,

Did you ever set up this routine with a dialogue to pick the pagesetups from?

[CAB]

If you mean "Import Page Set Up" from another drawing,
then NO.

[ronjonp]

Not from other drawings. Just a pick list to set all tabs to a certain pagesetup. Kinda like the one in your plottabs routine minus the plotting part.

[CAB]

No but I threw this together.
Needs testing.

Code removed, see update in another post.

[T.Willey]

No but I threw this together.
Needs testing.

Seemed to work on my one drawing.  Only one layout, but it copied it over.  The only problem I had was that my titles were too long to see.

[Kerry]

No but I threw this together.
Needs testing.

bloody amazing ! , your attitude.

[CAB]

Updated the DCL file with wider list boxes.

[CAB]

No but I threw this together.
Needs testing.

bloody amazing ! , your attitude.

You'll have to clarify, I'm slow at times.

[Kerry]

expressing my admiration for how helpfull you are. !

[CAB]

Well thank you sir.
I love to write code & play tennis.
Neither of which I do that well compared to the talent I see here & there.
But I do it for me so that's ok. So i do it every chance I get.

[CAB]

The updated code is Here

[CAB]

Not from other drawings. Just a pick list to set all tabs to a certain pagesetup. Kinda like the one in your plottabs routine minus the plotting part.

ron
is that what you were looking for?