Topic: Error after making field, referred to the Xref

[frostmourn]

Hello all. I have got a problem during working with external references. Here the file AC-11 was used in the file AC-22 as attached Xref. Then doing the following code in it:
 

Code - Auto/Visual Lisp: [Select]

1. (defun c:123 ( /  LST adoc str_lst)
2.         (vl-load-com)
3.         (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
4.         (vlax-for x
5.                 (vla-get-blocks adoc)
6.                 (if (equal (vla-get-isxref x) :vlax-true) (setq LstXref (cons x LstXref)))
7.         )
8.         (foreach x
9.                 (get-block-contents (car LstXref))
10.                 (if (wcmatch (vla-get-objectname x) "*Text")
11.                         (setq LST (cons x LST))
12.                 )
13.         )
14.         (setq str_lst
15.                 (mapcar
16.                         '(lambda (x)
17.                                         (LM:ConstructFieldString x "TextString" "")
18.                         )
19.                         LST
20.                 )
21.         )
22.         (foreach x
23.                 (sstolist_vla (ssget "_X" '((8 . "Specification") (0 . "TEXT"))))
24.                 (vla-put-textstring x (car str_lst))
25.                 (setq str_lst (cdr str_lst))
26.                 x
27.         )
28.         (vla-regen adoc acActiveViewport)
29. )
30.  
31. ;; LM:ConstructFieldString
32. (
33.     (lambda ( )
34.         (vl-load-com)
35.         (if (null acdoc)
36.             (setq acdoc (vla-get-activedocument (vlax-get-acad-object)))
37.         )
38.         (eval
39.             (list 'defun 'LM:ConstructFieldString '(ent prop format / ent )
40.                 (list 'if 'ent
41.                     (list 'strcat "%<\\AcObjProp Object(%<\\_ObjId "
42.                         (if
43.                             (and
44.                                 (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
45.                                 (vlax-method-applicable-p (vla-get-utility acdoc) 'getobjectidstring)
46.                             )
47.                             (list 'vla-getobjectidstring (vla-get-utility acdoc) 'ent ':vlax-false)
48.                            '(itoa (vla-get-objectid ent))
49.                         )
50.                         ">%)." 'prop '(if (not (eq "" format)) (strcat " \\f \"" format "\">%") ">%")
51.                     )
52.                 )
53.             )
54.         )
55.     )
56. )
57.  
58. (defun sstolist_vla (ss / i lst)
59.         (setq i 0)
60.         (if ss
61.                 (repeat (sslength ss)
62.                         (setq lst (append lst (list (vlax-ename->vla-object (ssname ss i)))) i (1+ i))
63.                 );end of repeat
64.         )
65.         lst
66. )
67.  
68. (defun get-block-contents (ent / def res _kpblc-conv-vla-to-list)
69.                           ; exam: (get-block-contents (car (entsel "\n&#1042;&#1099;&#1073;&#1077;&#1088;&#1080;&#1090;&#1077; &#1073;&#1083;&#1086;&#1082;")))
70.    (defun _kpblc-conv-vla-to-list (value / res)
71.      (cond ((listp value) (mapcar (function _kpblc-conv-vla-to-list) value))
72.           ((= (type value) 'variant) (_kpblc-conv-vla-to-list (vlax-variant-value value)))
73.           ((= (type value) 'safearray)
74.            (if (>= (vlax-safearray-get-u-bound value 1) 0)
75.              (_kpblc-conv-vla-to-list (vlax-safearray->list value))
76.              ) ;_ end of if
77.            )
78.           ((and (= (type value) 'vla-object) (vlax-property-available-p value 'count))
79.            (vlax-for sub value (setq res (cons sub res))) ;_ end of vlax-for
80.            )
81.           (t value)
82.           ) ;_ end of cond
83.     ) ;_ end of defun
84.  
85.   (cond ((and ent
86.               (= (type ent) 'ename)
87.               (= (cdr (assoc 0 (entget ent))) "INSERT")
88.               ) ;_ end of and
89.          (setq res (get-block-contents (vlax-ename->vla-object ent)))
90.          )
91.         ((and ent (= (type ent) 'vla-object) (wcmatch (strcase (vla-get-objectname ent)) "*BLOCK*"))
92.                         (setq def (vla-item (vla-get-blocks (vla-get-document ent)) (vla-get-name ent)))
93.                         (setq res ; (list
94.                                 ((lambda (/ _lst) (vlax-for subent def (setq _lst (cons subent _lst))) (reverse _lst)))
95.                           ; (_kpblc-conv-vla-to-list (vla-getattributes ent))
96.                           ; (_kpblc-conv-vla-to-list (vla-getconstantattributes ent))
97.                           ; ) ;_ end of list
98.                         )
99.         )
100.         ) ;_ end of cond
101.   res
102. )

As a result we are obtaining a list of field codes, refering to the text entities on a specified layer in the Xref. And now if we paste codes to the texts in AC-22 trying to make working field, then after saving drawing will constantly get an error window - "recommended to do RECOVER procedure" (don't remember right wording).
I have tried to paste only textstrings; to process a simple block instead of Xref - all is good. Also tried using of Acad2016, saving in old versions, no matter. After re-opening file works correctly, audit shows 0 errors. Fields are the necessary condition here. Can anybody give a solution or explanation at least? Will be happy even could to set off an error window.
System - Autocad 2010 x64 sp3 rus, SPDSGraphics 8.0, windows 7 pro x64 sp1. Thanks in advance.
Sorry for probably mistakes.

[ronjonp]

Not related to your code but ... first thing I see you should not be doing is putting special characters in your file names.

This is the dl'd file I see .. something weird going on.

[frostmourn]

Hmm, very strange... I see ordinary letters. It's something related with cyrillic encoding, I think.
Ok, here are files with only numbers using (by the way, it had no effect according to my problem...).