Topic: Remove-if ... etal

[kdub_nz]

A sort of challenge ..

(vl-directory-files .... includes  ("." ".." etc if the folder is not a root drive

To remove these strings if existing I tried these

 ... any others ??

Code: [Select]


(defun _test01 ()
  (setq bom:ParentFolder "F:\\WDT-BOM-Data"
        Folders          (vl-remove-if (function (lambda (g) (or (= g ".") (= g ".."))))
                                       (vl-directory-files bom:ParentFolder NIL -1)
                         )
  )
)
(defun _test02 ()
  (setq bom:ParentFolder "F:\\WDT-BOM-Data"
        Folders          (vl-remove ".." (vl-remove "." (vl-directory-files bom:ParentFolder NIL -1)))
  )
 
)
(defun _test03 ()
  (setq bom:ParentFolder "F:\\WDT-BOM-Data"
        Folders          (if (= "." (car (setq Folders (vl-directory-files bom:ParentFolder NIL -1))))
                           (if (= ".." (car (setq Folders (cdr Folders))))
                             (setq Folders (cdr Folders))
                           )
                         )
  )
)

(benchMark '((_test01) (_test02) (_test03)))
Benchmarking [M.P. 2005] .........Elapsed milliseconds for 64 iteration(s)/ relative Timing :

    (_TEST02).....796 / 1.0845 <slowest>
    (_TEST01).....766 / 1.0436
    (_TEST03).....734 / 1 <fastest>

edit: clumsy and stupid

[kdub_nz]

... and does anyone know for definite if there is ever only ONE elipsis returned or always either NONE or TWO ??

[MP]

Sorry, I don't know the answer to your last question and I can't run AutoCAD right now to find out.

Untested but what if you use the member function (member g '("." "..")) in _test01 instead of the or construct? It's fewr function calls than the other variants so it might bench faster.

[kdub_nz]

good thought ..  close to the money

Code: [Select]

(defun _test04 ()
  (setq bom:ParentFolder "F:\\WDT-BOM-Data"
        Folders          (vl-remove-if (function (lambda (g) (member g '("." "..") )))
                                       (vl-directory-files bom:ParentFolder NIL -1)
                         )
  )
)

(benchMark '((_test01) (_test02) (_test03) (_test04)))

Benchmarking [M.P. 2005] .........Elapsed milliseconds for 64 iteration(s)/ relative Timing :

    (_TEST04).....797 / 1.0858 <slowest>
    (_TEST03).....781 / 1.064
    (_TEST02).....765 / 1.0422
    (_TEST01).....734 / 1 <fastest>

[MP]

Great, the worst. So much for that idea <facepalm>.

[kdub_nz]

Great, the worst. So much for that idea <facepalm>.

but it's only 'worse' by a poofteenth   

[MP]

Worse by 8.6%. That ain't poofteenth.

[MP]

If memory serves me you'll always get the "." ".." if the directory location is not the root folder, but I'm assuming vl-directory-files behavior mirrors that of the DOS dir command.

[MP]

Code: [Select]

(defun _test? ()
    (setq
        bom:ParentFolder "F:\\WDT-BOM-Data"
        Folders          (if (member ".." (setq Folders (vl-directory-files bom:ParentFolder NIL -1)))
                             (cddr Folders)
                             Folders
                         )
    )
)
untested but ... if the "." ".." always appear in the noted order (and always first in the list) then the above should work.

[kdub_nz]

Thanks Michael,
I'm doing an animated stepthrough at the moment so I'll try that option as soon as the process is finished.

[MP]

You're welcome KB. I gotta crash here pretty quick so I won't see the results 'til tomorrow, but thanks for the opportunity to pitch a few ideas.

[Kerry]

On the old box at home .....

Code: [Select]


(defun _test01 ()
  (setq bom:ParentFolder "F:\\_Develop"
        Folders          (vl-remove-if (function (lambda (g) (or (= g ".") (= g ".."))))
                                       (vl-directory-files bom:ParentFolder NIL -1)
                         )
  )
)
(defun _test02 ()
  (setq bom:ParentFolder "F:\\_Develop"
        Folders          (vl-remove ".." (vl-remove "." (vl-directory-files bom:ParentFolder NIL -1)))
  )
 
)
(defun _test03 ()
  (setq bom:ParentFolder "F:\\_Develop"
        Folders          (if (= "." (car (setq Folders (vl-directory-files bom:ParentFolder NIL -1))))
                           (if (= ".." (car (setq Folders (cdr Folders))))
                             (setq Folders (cdr Folders))
                           )
                         )
  )
)
(defun _test04 ()
  (setq bom:ParentFolder "F:\\_Develop"
        Folders          (vl-remove-if (function (lambda (g) (member g '("." "..") )))
                                       (vl-directory-files bom:ParentFolder NIL -1)
                         )
  )
)

(defun _test05 ()
    (setq
        bom:ParentFolder "F:\\_Develop"
        Folders          (if (member ".." (setq Folders (vl-directory-files bom:ParentFolder NIL -1)))
                             (cddr Folders)
                             Folders
                         )
    )
)
(defun _test06 ()
    (setq bom:ParentFolder "F:\\_Develop")
    (if (= ".." (cadr (setq Folders (vl-directory-files bom:ParentFolder NIL -1))))
        (setq Folders (cddr Folders))
    )
)


Benchmarking [M.P. 2005] .............Elapsed milliseconds for 1024 iteration(s)/ relative Timing :

    (_TEST04).....500 / 1.0684 <slowest>
    (_TEST01).....484 / 1.0342
    (_TEST02).....469 / 1.0021
    (_TEST03).....469 / 1.0021
    (_TEST05).....469 / 1.0021
    (_TEST06).....468 / 1 <fastest>

[MP]

[ronjonp]

Kerry,

What kind of speed does this have?

Code: [Select]

(defun subfolders (path / folder fs lst subs)
  (setq fs (vlax-create-object "Scripting.FileSystemObject"))
  (if (and (setq folder (vlax-invoke fs 'getfolder path))
           (setq subs (vlax-get folder 'subfolders))
      )
    (vlax-for sub subs (setq lst (cons (vlax-get sub 'Path) lst)))
  )
  (vlax-release-object fs)
  (reverse lst)
)
(subfolders "C:\\")
Nevermind  :ugly:

    (_TEST03)........1500 / 3.47 <fastest>
    (_TEST05)........1515 / 3.43
    (_TEST02)........1516 / 3.43
    (_TEST06)........1516 / 3.43
    (_TEST01)........1578 / 3.30
    (_TEST04)........1578 / 3.30
    (SUBFOLDERS).....5203 / 1.00 <slowest>

[VovKa]

Code: [Select]

(defun _test07 ()
  (setq bom:ParentFolder "C:\\Program Files")
  (if (> (strlen bom:ParentFolder) 3)
    (cddr (vl-directory-files bom:ParentFolder NIL -1))
    (vl-directory-files bom:ParentFolder NIL -1)
  )
)
03 and 06 do not work for the root