Topic: Block attribute visability

[caveman]

Hey,

I'm trying to create a function to allow me to toggle the attribute visibility on groups of blocks.
Basically - the same result as the visibility toggle in the battman command which i can use with selection sets.

I have been having a play with the attdef entities (70 - Attribute flags: 1 = Attribute is invisible (does not appear)) - from acad help.
but not getting the results I'm after.

I'm not overly confident with the entity mods side of things so if someone could point me in the right direction I would greatly appreciate

Cheers
M
 

[CAB]

Check this out.

Code: [Select]

(vla-get-Invisible att)
No time to help but you should find what you need.

[gile]

Hi,

If I don't misunderstand the question, here's a trick.

Code: [Select]

(defun c:test (/ ss n blk att elst vis)
  (and
    (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (setq n 0)
    (while (setq blk (ssname ss n))
      (setq att (entnext blk)
    n (1+ n)
      )
      (while (and
       att
       (setq elst (entget att))
       (= (cdr (assoc 0 elst)) "ATTRIB")
     )
(setq vis (assoc 70 elst)
      att (entnext att)
)
(entmod (subst (cons 70 (Boole 6 1 (cdr vis))) vis elst))
(entupd blk)
      )
    )
  )
  (princ)
)

[CAB]

Welcome to the Swamp caveman.
Just poped in for this:

Code: [Select]

(defun c:testOFF (/ ss idx ename att)
  (and
    (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (setq idx -1)
    (while (setq ename (ssname ss (setq idx (1+ idx))))
      (foreach att (vlax-invoke (vlax-ename->vla-object ename) 'getattributes)
        (vla-put-Invisible att :vlax-true)
      )
    )
  )
  (princ)
)


(defun c:testON (/ ss idx ename att)
  (and
    (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (setq idx -1)
    (while (setq ename (ssname ss (setq idx (1+ idx))))
      (foreach att (vlax-invoke (vlax-ename->vla-object ename) 'getattributes)
        (vla-put-Invisible att :vlax-flase)
      )
    )
  )
  (princ)
)

[ronjonp]

And a variant of CAB's code

Code: [Select]

(defun c:testToggle (/ ss idx ename att)
  (and
    (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (setq idx -1)
    (while (setq ename (ssname ss (setq idx (1+ idx))))
      (foreach att (vlax-invoke
     (vlax-ename->vla-object ename)
     'getattributes
   )
(if (= (vla-get-invisible att) :vlax-true)
  (vla-put-Invisible att :vlax-false)
  (vla-put-Invisible att :vlax-true)
)
      )
    )
  )
  (princ)
)


[caveman]

You guys are awesome - thats exactly what I was after.
Far better than the way I was trying to go about it 
Really appreciate everyones help.

Cheers
M

[CAB]

Good job Gile and Ron.

[Pad]

This lisp changes all of the attributes of a block invisible.
Is it possible for it to only change certain layer's attributes invisible?

eg.
The attached block has 3 attribs.
Level
Code
&
Number

I'd like to be able to make code and number layers invisible, regardless of the block they are in, but leave the level layer attribute visible.

Thanks
Pad

[CAB]

Welcome to the Swamp.

Do you need a lisp to do it?
If not type battman at the command line.
Exptresstools must be loaded though.

[CAB]

You can play with this.

Code: [Select]

(defun c:testOFF (/ ss idx ename att)
  (and
    (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (setq idx -1)
    (while (setq ename (ssname ss (setq idx (1+ idx))))
      (foreach att (vlax-invoke (vlax-ename->vla-object ename) 'getattributes)
        (if (member (vla-get-tagstring att) '("LEVEL" "CODE"))
          (vla-put-Invisible att :vlax-true)
        )
      )
    )
  )
  (princ)
)

[Pad]

Thanks Cab

that works a treat.
Yes the lisp is preferable to battman (which until today i didn't know about).

I have a lisp which bursts all my attributed blocks so that the codes and numbers can be deleted and the point is replaced with a cross block for presentation purposes.
Sometimes I think it may be preferable to leave the blocks unexploded so the attributes are still connected to the point, with the code and numbers invisible that sorts the presentation problem.
I may try and integrate the two lisps and have a prompt to choose which option, the burst or the invisible.

Cheers
Pad