Topic: find drawings containing layer

[Jeff_M]

what I would do is....

In the acaddoc.lsp (on your computer as well as other users) add this:

Code: [Select]


(if (tblsearch "layer" "z-barcode")
 (command "-layer" "ON" "z-barcode" "Thaw" "z-barcode" "P" "N" "z-barcode")
)


According to the help file

If you use the command function in an acad.lsp, acaddoc.lsp or MNL file, it should be called only from within a defun statement. Use the S::STARTUP function to define commands that need to be issued immediately when you begin a drawing session. The S::STARTUP function is described in S::STARTUP Function—Post-Initialization Execution.

I don't recall the specifics as to why they say this, but I believe it had to do with some commands not behaving properly before Acad has completely initialized.

[Keith™]

Hmm... never read that before and I have never had a problem ... but the issue is easily resolved by doing the following ...

Code: [Select]


(if (setq lay (tblobjname "layer" "z-barcode"))
  (progn
    (setq laydata (entget lay))
    (setq templay (subst (cons 62 (abs (cdr (assoc 62 laydata)))) (assoc 62 laydata) laydata))
    (setq templay (subst (cons 70 0) (assoc 70 templay) templay))
    (entmod (subst (cons 290 0) (assoc 290 templay) templay))
  )
)


[ronjonp]

Keith,

Code: [Select]

(if (tblsearch "layer" "z-barcode")
 (command "-layer" "ON" "z-barcode" "Thaw" "z-barcode" "P" "N" "z-barcode")
)

How do you make this return a prompt to the command line that layer does not exist?

want something like:

Code: [Select]

(if (tblsearch "layer" "z-barcode")
  (then
    (command "-layer"  "ON"       "z-barcode"  "Thaw"
    "z-barcode"  "P"       "N"    "z-barcode"
   )
    (else
      (prompt "Layer does not exist")
    )
  )
)

[sinc]

The "command" function works by running Autocad commands in the current drawing session.  The acad.lsp and acaddoc.lsp routines are run BEFORE the Autocad drawing session is initialized, so there is no Autocad session to run the Autocad command in.  Therefore, "command" won't work.

When the drawing session finishes initializing, the first thing it does is run the "S::STARTUP" function.  Therefore, if you want to do something at startup that uses the "command" function, you need to add it to this function.

[Keith™]

You re soooo... close ....

Code: [Select]

(if (tblsearch "layer" "z-barcode")
    (command "-layer" "ON" "z-barcode" "Thaw" "z-barcode" "P" "N" "z-barcode" "")
    (prompt "Layer does not exist")
)


Using the second version without the command call...

Code: [Select]

(if (setq lay (tblobjname "layer" "z-barcode"))
  (progn
    (setq laydata (entget lay))
    (setq templay (subst (cons 62 (abs (cdr (assoc 62 laydata)))) (assoc 62 laydata) laydata))
    (setq templay (subst (cons 70 0) (assoc 70 templay) templay))
    (entmod (subst (cons 290 0) (assoc 290 templay) templay))
  )
  (prompt "Layer does not exist")
)



VLisp version ...

Code: [Select]

(setq *acad* (vlax-get-acad-object)
      *doc* (vla-get-activedocument *acad*)
      *layers* (vla-get-layers *doc*)
      found nil
)
(vlax-for *layer* *layers*
  (if (= (vla-get-Name *layer*) "0")
    (progn
      (vla-put-layeron *layer* :vlax-true)
      (vla-put-freeze *layer* :vlax-false)
      (vla-put-Lock *layer* :vlax-false)
      (vla-put-plottable *layer* :vlax-false)
      (setq found T)
    )
  )
)
(if (not found)
  (prompt "Layer does not exist")
)


[Keith™]

The "command" function works by running Autocad commands in the current drawing session.  The acad.lsp and acaddoc.lsp routines are run BEFORE the Autocad drawing session is initialized, so there is no Autocad session to run the Autocad command in.  Therefore, "command" won't work.

When the drawing session finishes initializing, the first thing it does is run the "S::STARTUP" function.  Therefore, if you want to do something at startup that uses the "command" function, you need to add it to this function.

I tested the above scenario on A2k4 ... the results are:

Regenerating model.

AutoCAD Express Tools Copyright © 2002-2003 Autodesk, Inc.

ACAD2004.LSP loaded
ACAD2004DOC.LSP loaded
ACADDOC.LSP loaded
-layer
Current layer:  "0"
Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/Freeze/Thaw/LOck/Unlock/stAte]:
ON
Enter name list of layer(s) to turn on: 0 Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/Freeze/Thaw/LOck/Unlock/stAte]:
Thaw
Enter name list of layer(s) to thaw: 0 Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/Freeze/Thaw/LOck/Unlock/stAte]:
P
Enter a plotting preference [Plot/No plot] <Plot>: N
Enter layer name(s) for this plot preference <0>: 0 Enter an option
[?/Make/Set/New/ON/OFF/Color/Ltype/LWeight/Plot/Freeze/Thaw/LOck/Unlock/stAte]:
AutoCAD menu utilities loaded.
ACAD.LSP loaded

Note the order in which the files are loaded .....

AutoCAD Express Tools
ACAD2004.LSP
ACAD2004DOC.LSP
ACADDOC.LSP
ACAD.MNL
ACAD.LSP

Also note that the command called in ACADDOC.LSP executed without fault and also note that modelspace was regenerated before any of these modules loaded. To me that indicates a readiness to accept commands.

As I said... I have used that scenario for many years, probably since R10, of course we only used ACAD.LSP until R14, but I have experienced no negative problems.

[ronjonp]

Thanks Keith   . I wish I could learn this stuff. I spent about 45 minutes yesterday trying different variations