Topic: Retrieving a list of mapped network printers and their paths

[psuchewinner]

Ok,
Hopefully this will be easy for someone but I can not figure out how do retrieve a list of of printers and their associated paths from my computer.  Our printers here are on a network and I would like to be able to populate a list box with the names of the printers that are available (or are mapped) on a users computer.  I am thinking of something like that which appears in the "Printer/Plotter" area of the create a new pagesetup dialog.  Can anyone help? 

[MP]

Code: [Select]

(defun _GetNetworkPrinters ( / WshNetwork oPrinters result i )

    ;;  2007/12/xx Michael Puckett
    ;;
    ;;  Translated from http://tinyurl.com/2496ow
    ;;
    ;;  typical result --
    ;;
    ;;  (
    ;;      ("PDFFILE:"       . "Win2PDF")
    ;;      ("XPSPort:"       . "Microsoft XPS Document Writer")
    ;;      ("IP_nn.n.nn.nnn" . "\\\\server\\Plotter Name 1")
    ;;      ...
    ;;      ("IP_nn.n.nn.nnn" . "\\\\server\\Plotter Name n")
    ;;  )
    ;;

    (setq
        WshNetwork (vlax-create-object "WScript.Network")
        oPrinters  (vlax-invoke WshNetwork 'EnumPrinterConnections)
    )
   
    ;;  weird, count is a method, not a property of oPrinters
   
    (repeat (setq i (vlax-invoke oPrinters 'Count))
   
        (if (zerop (rem (setq i (1- i)) 2))
            (setq result
                (cons
                    (cons
                        ;;  weird, item is a method,
                        ;;  not a property of oPrinters
                        (vlax-invoke
                            oPrinters
                           'Item
                            i
                        )
                        (vlax-invoke
                            oPrinters
                           'Item
                            (1+ i)
                        )
                    )   
                    result
                )           
            )
        )
   
    )
   
    (vlax-release-object oPrinters)
   
    (vlax-release-object WshNetwork)
   
    result
   
)

[psuchewinner]

Perfect, EXACTLY what I was looking for!
Thank you.......Thank you very much.

[GDF]

Perfect, EXACTLY what I was looking for!
Thank you.......Thank you very much.

Yes, very nice!

[MP]

Thanks guys and you're most welcome.