Topic: roof making lisp

[dussla]

hello  , friend
i will ask again , sorry many asks and helps  ~

if you see my attatched image , you can see my wanted routine
if i select   a , b ,  c  and put  distance(d)  value    , then  routine  will draw  next image
pls can you understand ~?
thank you always ~

[DEVITG]

How about if you upload a true  ACAD DWG???

[Kerry]

Let us see what you've done so far ...

[dussla]

PLS , I ADDED  DWG FILE

[CAB]

I'll get you started but you will need to complete any modifications to the lisp.

Code: [Select]

(defun c:RoofCap (/ p1 p2 p3 dis ofs an1 an2 an3 p1a p1b p2a p2c)
  (prompt "\nPick 3 points for roof. End, Peak, End.")
  (if (and
        (setq p1 (getpoint "\nPick 1st of 3 points."))
        (setq p2 (getpoint "\nPick 2nd of 3 points."))
        (setq p3 (getpoint "\nPick 3rd of 3 points."))
        (setq dis (getdist "\nEnter Length of Cap."))
      )
    (progn
      (setq ofs 20. ; offset from roof line
            p1a (polar p2 (angle p2 p1) dis)
            p2a (polar p2 (angle p2 p3) dis)
            an1 (+ (angle p2 p1) (/ pi 2.))
            an2 (+ (angle p2 p1) (* pi 1.5))
      )
      (if (> (distance p3 (polar p1a an2 ofs)) (distance p3 (polar p1a an1 ofs)))
        (setq an1 an2)
      )
      (setq an2 (+ (angle p2 p3) (/ pi 2.))
            an3 (+ (angle p2 p3) (* pi 1.5))
      )
      (if (> (distance p1 (polar p1a an3 ofs)) (distance p1 (polar p1a an2 ofs)))
        (setq an2 an3)
      )
      (setq p1b (polar p1a an1 ofs)
            p2c (polar p2a an2 ofs)
            int (inters p1b (polar p1b (angle p1 p2) 10)
                        p2c (polar p2c (angle p3 p2) 10) nil)
      )
      (command "_pline" "_non" p1a "_non" p2 "_non" p2a "_non"
               p2c "_non" int "_non" p1b "_CLose")
    )
  )

  (princ)
)

[dussla]

really , really  thank you cab  always
routine is very good ~

[alanjt]

yoink!