Topic: Improving on entsel

[Chuck Gabriel]

What do you guys do when you want the user to be able to interactively select an entity?

Entsel in its raw form leaves me wanting something more.  If the user misses their pick (easy to do), they don't get any second chances.  I've tried using ssget with the ":S" option, but I wasn't really happy with that either.  I honestly can't remember any longer what it did or didn't do that I didn't like.

I've tried wrapping up entsel in various looping constructs with tests for various conditions, and I've finally come up with something I can live with.  I just wonder if there is a better way.

Code: [Select]

(defun getEntity (msg type / input ent)
  (if
    (vl-catch-all-error-p
      (vl-catch-all-apply
'(lambda ()
   (while
     (and
       (= 3 (car (setq input (grread nil (logior 2 4 8) 2))))
       (or
(null (setq ent (nentselp (cadr input))))
(and
   type
   (/= (strcase type)
       (cdr (assoc 0 (entget (car ent))))
   )
)
       )
     )
   )
)
      )
    )
     nil
     ent
  )
)

My apologies if this has already been done to death.  If it has, I'd love to see the canonical method.

[Mark]

Chuck will you have any problems using 'type' as an argument?

(msg type  / input ent)

[Mark]

Chuck will you have any problems using 'type' as an argument?

(msg type  / input ent)

DUH .... never mind!

[MP]

What do you guys do when you want the user to be able to interactively select an entity?

Anted this post up in the remote chance you'll find it interesting.

If the user misses their pick (easy to do), they don't get any second chances.

Is that a bad thing?

[Chuck Gabriel]

What do you guys do when you want the user to be able to interactively select an entity?

Anted this post up in the remote chance you'll find it interesting.

Thanks.  I did take some inspiration from my memories of that thread.  I actually read that the first time around, studied the code thoroughly, and archived it for future reference.  Maybe now would be a good time to revisit it.

If the user misses their pick (easy to do), they don't get any second chances.

Is that a bad thing?

Speaking as a user, sometimes it frustrates the heck outta me.

[Chuck Gabriel]

While I'm at it, I noticed that the code I posted wasn't handling complex entities the way I wanted.  Here is a new attempt:

Code: [Select]

(defun getEntity (msg type / input ent)
  (if
    (vl-catch-all-error-p
      (vl-catch-all-apply
'(lambda ()
   (while
     (and
       (= 3 (car (setq input (grread nil (logior 2 4 8) 2))))
       (or
(null (setq ent (nentselp (cadr input))))
(and
   type
   (/= (strcase type)
       (if (> (length ent) 2)
(cdr (assoc 0 (entget (caar (reverse ent)))))
(cdr (assoc 0 (entget (car ent))))
       )
   )
)
       )
     )
   )
)
      )
    )
     nil
     ent
  )
)


[daron]

Hmm. I'm still not getting this one. What goes in the msg and type arguments? Why isn't msg being used in the code but required as an argument? Is it because of the vl-catch-all-'s? How is the type argument being used and not returning a problem and what do you put in for its argument?

[CAB]

Check mine out Chuck.
http://www.theswamp.org/index.php?topic=6992.msg93574#msg93574

[T.Willey]

If I understand, you want to loop entsel until the user hits enter to exit it... If so I just do it like (for selection a block for example)

Code: [Select]

(setvar 'ErrNo 0)
(while (not (equal (getvar 'ErrNo) 52))
    (if
        (and
            (setq Sel (entsel "\n Select block: "))
            (setq EntData (entget (car Sel)))
            (= (cdr (assoc 0 EntData)) "INSERT")
        )
        (progn
            (prompt "\n Got block, select again.")
        )
    )
)


[CAB]

Chuck,
Do you realize that type is a function and you are using it as a variable?

[daron]

Chuck,
Do you realize that type is a function and you are using it as a variable?

I think that's what Mark was alluding to, but seems to have gained understanding of its usefulnes.

Chuck will you have any problems using 'type' as an argument?

(msg type  / input ent)

DUH .... never mind!

And what I am still waiting on an answer for.

Hmm. I'm still not getting this one. What goes in the msg and type arguments? Why isn't msg being used in the code but required as an argument? Is it because of the vl-catch-all-'s? How is the type argument being used and not returning a problem and what do you put in for its argument?

CAB, in case you did catch all that, I was just putting it all together for safe keeping.

[CAB]

Wow, jumped in the end here and missed all that.   
Guess I'll read the entire thread now.

[Chuck Gabriel]

Hmm. I'm still not getting this one. What goes in the msg and type arguments?

Msg is supposed to be a prompt.  See below.  The type parameter allows you to filter for specific entity types.

Why isn't msg being used in the code but required as an argument? Is it because of the vl-catch-all-'s?

That would be an error.  It's supposed to be a prompt, but I changed some things around and forgot to put the prompt back in.  Thanks for pointing that out.  I need to fix it.

[Chuck Gabriel]

If I understand, you want to loop entsel until the user hits enter to exit it... If so I just do it like (for selection a block for example)

Code: [Select]

(setvar 'ErrNo 0)
(while (not (equal (getvar 'ErrNo) 52))
    (if
        (and
            (setq Sel (entsel "\n Select block: "))
            (setq EntData (entget (car Sel)))
            (= (cdr (assoc 0 EntData)) "INSERT")
        )
        (progn
            (prompt "\n Got block, select again.")
        )
    )
)


Interesting.  ERRNO is not documented in the AutoCAD 2000i docs.

[Chuck Gabriel]

Chuck will you have any problems using 'type' as an argument?

(msg type  / input ent)

DUH .... never mind!

No.  It was a good point.  I forgot that type is a reserved word.  I'll change it to etype.