Author Topic: Lisp to move attributes  (Read 9231 times)

0 Members and 1 Guest are viewing this topic.

TJAM51

  • Guest
Lisp to move attributes
« on: November 09, 2007, 11:19:11 am »
I am seeking a lisp routine thet would allow me to move with either crossing or single pick any attribute. I would like to pick the attribute and then drag it to it's new location.


Thanks

T.Willey

  • Needs a day job
  • Posts: 5189
Re: Lisp to move attributes
« Reply #1 on: November 09, 2007, 11:21:24 am »
Can't be done with simple code.  You would have to roll your own code like 'ssget'.  There is an option with 'ssget' to get nested entities, but I haven't be able to get it to select attributes on a regular basis, so I wouldn't trust it.
Tim

I don't want to ' end-up ', I want to ' become '. - Me

Please think about donating if this post helped you.

Guest

  • Guest
Re: Lisp to move attributes
« Reply #2 on: November 09, 2007, 11:47:37 am »
Why is there a poll for this?!?  :?

CADaver

  • Guest
Re: Lisp to move attributes
« Reply #3 on: November 09, 2007, 12:11:43 pm »
what's wrong with grips???

VovKa

  • Swamp Rat
  • Posts: 850
  • Ukraine
Re: Lisp to move attributes
« Reply #4 on: November 09, 2007, 12:23:43 pm »
grips are cool! but sometimes i use my own routines with (nentsel)

T.Willey

  • Needs a day job
  • Posts: 5189
Re: Lisp to move attributes
« Reply #5 on: November 09, 2007, 12:28:02 pm »
Here is a quick example of what I'm talking about.  It only works with crossing right now, but how you fix that is to not use 'ssget' first, but use 'getpoint' and 'getcorner' and use 'ssget' with those two points to create a crossing selection.  You can test where the second point is relative to the first point, and then you know if you have a crossing or a windowing pick style, but I will leave that to you.

Code: [Select]
(defun c:Testing (/ ss ObjList PtList ll ur SelObjList tempPtList SelMode TestList)

(if (setq ss (ssget))
(progn
(foreach lst (ssnamex ss)
(cond
(
(or
(equal (car lst) 3)
(equal (car lst) 2)
)
(setq ObjList (cons (vlax-ename->vla-object (cadr lst)) ObjList))
(if (equal (car lst) 2)
(setq SelMode "Window")
(setq SelMode "Crossing")
)
)
((equal (car lst) -1)
(foreach sub-lst (cdr lst)
(setq PtList (cons (cadr sub-lst) PtList))
)
)
)
)
(foreach obj ObjList
(foreach att (vlax-invoke obj 'GetAttributes)
(setq TestList nil)
(vla-GetBoundingBox att 'll 'ur)
(setq tempPtList
(list
(setq ll (safearray-value ll))
(setq ur (safearray-value ur))
(list (car ur) (cadr ll) (caddr ll))
(list (car ll) (cadr ur) (caddr ll))
)
)
(foreach pt tempPtList
(if
(and
(< (caar PtList) (car pt) (caadr PtList))
(< (cadar PtList) (cadr pt) (cadr (caddr PtList)))
)
(progn
(setq TestList (cons T TestList))
(redraw (vlax-vla-object->ename att) 3)
)
)
)
(if (= SelMode "Window")
(if (equal (length TestList) 4)
(setq SelObjList (cons att SelObjList))
)
(if TestList
(setq SelObjList (cons att SelObjList))
)
)
)
)
)
)
SelObjList
)
Tim

I don't want to ' end-up ', I want to ' become '. - Me

Please think about donating if this post helped you.

VovKa

  • Swamp Rat
  • Posts: 850
  • Ukraine
Re: Lisp to move attributes
« Reply #6 on: November 09, 2007, 05:38:04 pm »
when grips are hard to distinguish
Code: [Select]
(defun C:MOVEATT (/ Ent EntProps LastPoint LastEnt *error*)
  (defun *error* (msg)
    (if LastEnt
      (entdel LastEnt)
    )
    (vl-cmdf "._UNDO" "_END")
    (if (or (= msg "Function cancelled") (= msg "quit / exit abort"))
      (princ)
      (princ (strcat "\nError: " msg))
    )
  )
  (setvar "CMDECHO" 0)
  (vl-cmdf "._UNDO" "_BEGIN")
  (if
    (and
      (progn (while (not
      (and (setq Ent (nentsel "\nSelect an attribute: "))
   (= (cdr (assoc 0 (setq EntProps (entget (car Ent))))) "ATTRIB")
      )
    )
     )
     Ent
      )
      (setq LastPoint (cadr Ent)
    LastEnt   (entmakex
(cons
  (cons 0 "TEXT")
  (subst
    (cons 73 (cdr (assoc 74 EntProps)))
    (assoc 74 EntProps)
    (subst
      (cons
10
(cdr
  (assoc
    (if
      (= 0 (cdr (assoc 72 EntProps)) (cdr (assoc 74 EntProps)))
       10
       11
    )
    EntProps
  )
)
      )
      (assoc 10 EntProps)
      (vl-remove-if
(function (lambda (g)
    (vl-position (car g) '(-1 0 2 5 70 73 100 280 330))
  )
)
EntProps
      )
    )
  )
)
      )
      )
    )
     (progn
       (setvar "LASTPOINT" LastPoint)
       (command "._MOVE" LastEnt "" (cadr Ent) PAUSE)
       (if (not (equal LastPoint (getvar "LASTPOINT")))
(progn (entmod
  (subst (assoc 11 (entget LastEnt))
(assoc 11 EntProps)
(subst (assoc 10 (entget LastEnt)) (assoc 10 EntProps) EntProps)
  )
)
(entupd (car Ent))
)
       )
       (entdel LastEnt)
     )
  )
  (vl-cmdf "._UNDO" "_END")
  (princ)
)
« Last Edit: November 10, 2007, 04:26:21 am by VovKa »

Least

  • Guest
Re: Lisp to move attributes
« Reply #7 on: November 30, 2007, 11:11:47 am »
Vovka, thats quite usefull, but it would be fantastic if the lisp could be modified so that there is an option to pick more than one attribute at a time.
I have no idea how to do that though..?
thanks

daron

  • Guest
Re: Lisp to move attributes
« Reply #8 on: November 30, 2007, 12:57:23 pm »
I thought ssget had a nentsel type flag?

Quote from: the dev-docs
When using the :N selection method, if the user selects a subentity of a complex entity such as a BlockReference, PolygonMesh, or old style polyline, ssget looks at the subentity that is selected when determining if it has already been selected. However, ssget actually adds the main entity (BlockReference, PolygonMesh, etc.) to the selection set. It is therefore possible to have multiple entries with the same entity name in the selection set (each will have different subentity information for ssnamex to report). Because the :N method does not guarantee that each entry will be unique, code that relies on uniqueness should not use selection sets created using this option.

T.Willey

  • Needs a day job
  • Posts: 5189
Re: Lisp to move attributes
« Reply #9 on: November 30, 2007, 01:29:13 pm »
I thought ssget had a nentsel type flag?

Quote from: the dev-docs
When using the :N selection method, if the user selects a subentity of a complex entity such as a BlockReference, PolygonMesh, or old style polyline, ssget looks at the subentity that is selected when determining if it has already been selected. However, ssget actually adds the main entity (BlockReference, PolygonMesh, etc.) to the selection set. It is therefore possible to have multiple entries with the same entity name in the selection set (each will have different subentity information for ssnamex to report). Because the :N method does not guarantee that each entry will be unique, code that relies on uniqueness should not use selection sets created using this option.
Doesn't work as one would hope.  At least I wasn't able to make it work the way I wanted.  That is why I wrote this routine.
Tim

I don't want to ' end-up ', I want to ' become '. - Me

Please think about donating if this post helped you.

VovKa

  • Swamp Rat
  • Posts: 850
  • Ukraine
Re: Lisp to move attributes
« Reply #10 on: November 30, 2007, 03:57:49 pm »
Vovka, thats quite usefull, but it would be fantastic if the lisp could be modified so that there is an option to pick more than one attribute at a time.
I have no idea how to do that though..?
thanks
one day it really annoyed me to aim at grips. so, i wrote that function with only one purpose - to move an attribute with just two clicks.
i think it's possible (maybe with the help of Tim Willey's routine) to do what you ask. i'll look at it.

T.Willey

  • Needs a day job
  • Posts: 5189
Re: Lisp to move attributes
« Reply #11 on: November 30, 2007, 04:06:05 pm »
Here is mine, with some changes made the the sub posted in the other thread.  I think I got all the subs.
Code: [Select]
(defun c:MoveAttText (/ ActDoc Plss CurSpace ObjList tempPtList PtList tempPline BasePt NewPt *error*)

(defun *error* (msg)

(command)
(if (> (sslength Plss) 0)
(command "_.erase" Plss "")
)
(vla-EndUndoMark ActDoc)
)

(defun GetCurrentSpace (Doc / BlkCol SpaceList CurSpace ActSpace temp1)
; Returns the "block object" for the active space
; Thanks to Jeff Mishler

(if (= (getvar "cvport") 1)
(vla-get-PaperSpace Doc)
(vla-get-ModelSpace Doc)
)
)


(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vla-EndUndoMark ActDoc)
(vla-StartUndoMark ActDoc)
(setq Plss (ssadd))
(setq CurSpace (GetCurrentSpace ActDoc))
(if (setq ObjList (SelAtts "Select attributes and/or text to move: " T))
(foreach obj ObjList
(setq tempPtList (GetBBPoints obj))
(setq PtList nil)
(foreach pt tempPtList
(setq PtList (cons (car pt) PtList))
(setq PtList (cons (cadr pt) PtList))
)
(setq tempPline
(vlax-invoke
CurSpace
'AddLightWeightPolyline
(reverse PtList)
)
)
(vla-put-Closed tempPline :vlax-true)
(ssadd (vlax-vla-object->ename tempPline) Plss)
)
)
(if (> (sslength Plss) 0)
(progn
(setvar 'cmdecho 1)
(command "_.move"
Plss
""
(setq BasePt (getpoint))
pause
)
(setq NewPt (getvar 'lastpoint))
(setvar 'cmdecho 0)
(command "_.erase" Plss "")
(foreach obj ObjList
(vlax-invoke obj 'Move BasePt NewPt)
)
)
)
(vla-EndUndoMark ActDoc)
(princ)
)
Code: [Select]
(defun SelAtts (Message bAllowText / Sel EntData Pt1 Pt3 gr p1 p2 p3 p4 po ss SelMode SelObjList flag)
; updated by gile @theSwamp.org to show the selection correctly.
; updated by T.Willey to allow the option to select text objects, not mtext
; updated by T.Willey, added new sub to see if the selection box and the bounding box of the objects
;    selected cross, so that a true crossing is simulated

(defun DoBoxesCross (PtList1 PtList2 / Intersect cnt cnt2)

(setq cnt 0)
(while
(and
(not Intersect)
(< cnt 4)
)
(setq cnt2 0)
(repeat 4
(if
(inters
(nth cnt PtList1)
(nth
(if (equal cnt 3)
0
(1+ cnt)
)
PtList1
)
(nth cnt2 PtList2)
(nth
(if (equal cnt2 3)
0
(1+ cnt2)
)
PtList2
)
T
)
(setq Intersect T)
)
(setq cnt2 (1+ cnt2))
)
(setq cnt (1+ cnt))
)
Intersect
)
;----------------------------------------------------------------------------------------------------
(defun GetAttSelection (ss SelMode / ObjList PtList TestList ll ur tempPtList SelObjList)

(foreach lst (ssnamex ss)
(cond
((equal (car lst) 3)
(setq ObjList (cons (vlax-ename->vla-object (cadr lst)) ObjList))
)
((equal (car lst) -1)
(foreach sub-lst (cdr lst)
(setq PtList (cons (cadr sub-lst) PtList))
)
)
)
)
(foreach obj ObjList
(cond
((= (vla-get-ObjectName obj) "AcDbBlockReference")
(foreach att (vlax-invoke obj 'GetAttributes)
(if
(and
(/= (vla-get-TextString att) "")
(= (vla-get-Invisible att) :vlax-false)
)
(progn
(setq TestList nil)
(vla-GetBoundingBox att 'll 'ur)
(setq tempPtList
(list
(setq ll (safearray-value ll))
(setq ur (safearray-value ur))
(list (car ur) (cadr ll) (caddr ll))
(list (car ll) (cadr ur) (caddr ll))
)
)
(foreach pt tempPtList
(if
(and
(< (caar PtList) (car pt) (caadr PtList))
(< (cadar PtList) (cadr pt) (cadr (caddr PtList)))
)
(setq TestList (cons T TestList))
)
)
(if (= SelMode "Windowing")
(if (equal (length TestList) 4)
(setq SelObjList (cons att SelObjList))
)
(if
(or
TestList
(DoBoxesCross PtList tempPtList)
)
(setq SelObjList (cons att SelObjList))
)
)
)
)
)
)
(
(or
(= (vla-get-ObjectName obj) "AcDbText")
(= (vla-get-ObjectName obj) "AcDbAttributeDefinition")
)
(if
(or
(/= (vla-get-TextString obj) "")
(and
(vlax-property-available-p obj 'TagString)
(/= (vla-get-TagString obj) "")
)
)
(progn
(setq TestList nil)
(vla-GetBoundingBox obj 'll 'ur)
(setq tempPtList
(list
(setq ll (safearray-value ll))
(setq ur (safearray-value ur))
(list (car ur) (cadr ll) (caddr ll))
(list (car ll) (cadr ur) (caddr ll))
)
)
(foreach pt tempPtList
(if
(and
(< (caar PtList) (car pt) (caadr PtList))
(< (cadar PtList) (cadr pt) (cadr (caddr PtList)))
)
(setq TestList (cons T TestList))
)
)
(if (= SelMode "Windowing")
(if (equal (length TestList) 4)
(setq SelObjList (cons obj SelObjList))
)
(if
(or
TestList
(DoBoxesCross PtList tempPtList)
)
(setq SelObjList (cons obj SelObjList))
)
)
)
)
)
)
)
SelObjList
)
;----------------------------------------------------------------------------------------------------
(defun gr-sel (/ loop gr pt)

(setq loop T)
(while (and (setq gr (grread T 12 2)) (/= (car gr) 3) loop)
(cond
((= (car gr) 5)
(setq pt (cadr gr))
)
(
(or
(member gr '((2 13) (2 32)))
(or (= (car gr) 11) (= (car gr) 25))
)
(setq loop nil
pt   nil
)
)
)
)
(if pt
(cond
((car (nentselp pt)))
(pt)
)
)
)
;---------------------------------------------------------------------------------------------------------
(setvar "ErrNo" 0)
(while
(and
(princ (strcat "\n" Message))
(setq sel (gr-sel))
)
(if (listp sel)
(progn
(setq p1  (list (car sel) (cadr sel))
pt1 (trans p1 1 2)
)
(princ "\nSpecify the opposite corner: ")
(while (and (setq gr (grread T 12 1)) (/= (car gr) 3))
(if (= 5 (car gr))
(progn
(redraw)
(setq pt3 (trans (cadr gr) 1 2)
p2 (trans (list (car pt3) (cadr pt1)) 2 1)
p3 (list (caadr gr) (cadadr gr))
p4 (trans (list (car pt1) (cadr pt3)) 2 1)
)
(if (< (car pt1) (car (trans p2 1 2)))
(progn
(setq SelMode "Windowing")
(grvecs (list 255 p1 p2 255 p2 p3 255 p3 p4 255 p4 p1))
)
(progn
(setq SelMode "Crossing")
(grvecs
(list -255 p1 p2 -255 p2 p3 -255 p3 p4 -255 p4 p1)
)
)
)
)
)
)
(redraw)
(if
(if bAllowText
(setq ss (ssget "_C" p1 p3 '((0 . "INSERT,TEXT,ATTDEF"))))
(setq ss (ssget "_C" p1 p3 '((0 . "INSERT"))))
)
(setq SelObjList (append SelObjList (GetAttSelection ss SelMode)))
)
)
(progn
(setq EntData (entget Sel))
(if
(or
(= (cdr (assoc 0 EntData)) "ATTRIB")
(and
bAllowText
(vl-position (cdr (assoc 0 EntData)) '("TEXT" "ATTDEF"))
)
)
(progn
(setq SelObjList
(cons (vlax-ename->vla-object Sel) SelObjList)
)
(redraw Sel 3)
)
)
)
)
(foreach att SelObjList
(redraw (vlax-vla-object->ename att) 3)
)
)
(foreach att SelObjList
(redraw (vlax-vla-object->ename att) 4)
)
SelObjList
)
Tim

I don't want to ' end-up ', I want to ' become '. - Me

Please think about donating if this post helped you.

Fatty

  • Guest
Re: Lisp to move attributes
« Reply #12 on: November 30, 2007, 04:37:23 pm »
Thanks T.Willey
Moccasin is my favourite color from this time
:))

~'J'~

Least

  • Guest
Re: Lisp to move attributes
« Reply #13 on: December 03, 2007, 05:28:51 am »
Thank you Vovka if you could that would be fantastic.

T.Willey, I just tried your lisps and have run into a slight problem.

I copied both routines as posted
MoveAttText.lsp and SelAtts.lsp

and apploaded them both and then run movetttext (i'm using autocad 2005).

Command: MoveAttText
Select attributes and/or text to move:
Select attributes and/or text to move: *Cancel*

I cannot seem to get pass the selection part of the routine, space bar seems to cancels.
I can select the attributes, but i cant move onto the next phase.

Thanks again
Least


T.Willey

  • Needs a day job
  • Posts: 5189
Re: Lisp to move attributes
« Reply #14 on: December 03, 2007, 10:59:33 am »
Try 'Right Clicking'.  I don't use space bar when selecting stuff, so the code might not accept it.  I will test when I get a chance.
Tim

I don't want to ' end-up ', I want to ' become '. - Me

Please think about donating if this post helped you.