Topic: Changing 3d spline to 2d spline

[csgoh]

Need a kickstart as to how to change the 3d splines to a 2d splines ? I use autocad map 2004.

[csgoh]

additional requirement - to add a constant to all the z -values .

[MP]

{ ... authors will need to be mindful of ucs considerations ... }

[CAB]

Found this: http://tinyurl.com/2tdyh8

[csgoh]

i just found out that using the "flatten" command changes the 3d spline to a 2d lwpolyline.could someone explain why this is so? Cant figure it.

is it just possible to change the z values for the control points, fit ,etc without changing any other properties.

[Joe Burke]

Take a look at the FlatSpline sub-function in SuperFlatten. It's in show your stuff.

Note, it assumes WCS is active because that's how the program works.

[Joe Burke]

Try this.

  ;; Argument: a flat 3D coordinate list.
  ;; (setq l '(414.576 572.128 0.0 494.558 637.135 20.0 562.58 575.117 30.0))
  ;; Returns:
  ;; (414.576 572.128 0.0 494.558 637.135 0.0 562.58 575.117 0.0)
  (defun ZZeroCoord (coord / lst)
    (repeat (/ (length coord) 3)
      (setq lst (cons (car coord) lst)
            lst (cons (cadr coord) lst)
            lst (cons 0.0 lst)
            coord (cdddr coord)
      )
    )
    (reverse lst)
  ) ;end

  ;; Flatten a spline to Z elevation zero in WCS.
  ;; Note, fit points may be lost, but that can happen during
  ;; spline edit operations anyway. The spline should not change
  ;; shape when the view is parallel to WCS.
  (defun c:2DSpline ( / obj ctrlpts testpts kts)
    (if
      (and
        (setq obj (car (entsel "\nSelect spline: ")))
        (setq obj (vlax-ename->vla-object obj))
        (eq "AcDbSpline" (vlax-get obj 'ObjectName))
      )
      (progn
        (setq ctrlpts (vlax-get obj 'ControlPoints)
              testpts (ZZeroCoord ctrlpts)         
        )
        (if
          (or
            (eq acFalse (vlax-get obj 'IsPlanar))
            (not (equal ctrlpts testpts 1e-8))
          )
          (progn
            (setq kts (vlax-get obj 'Knots))
            (vlax-put obj 'ControlPoints testpts)
            (vlax-put obj 'Knots kts)
            (princ "\nSpline was modified. ")
          )
          (princ "\nSpline was not modified. ")
        )
      )
    )
    (princ)
  ) ;end