Topic: Trig wieners ...

[Kerry]

.............. The way AutoPlant creates ...............

yep, I've played around with the Com interface .... the one branded ProSteel, when KiwiSoft owned it .. can't imagine it's changed much since Bentley bought them out.

[MP]

I've played around with the Com interface .... the one branded ProSteel, when KiwiSoft owned it .. can't imagine it's changed much since Bentley bought them out.

It's still ProSteel / KiwiSoft underneath it all, ergo the PS and Ks_ prefixes ...

Code: [Select]

    ...
    (setq shapeinfo
        (vlax-create-object
            "PSCOMWRAPPER.Ks_ComShapeInfo"
        )
    )
    ...

[MP]

After all said and done it distills down to one function:

Code: [Select]

(defun _GetPileCutoffElev ( pile / shapeinfo points result )

    ;;  Caller's responsibility to ensure a valid AutoPlant
    ;;  structural pile object is passed as well as ensuring
    ;;  AutoPlant structural enabler arx/dbx files are loaded
    ;;  prior to calling this function or splat: rake in face.
    ;;  ---------------------------------------------------
    ;;  Thanks to Kerry Brown for distilling assistance.

    (setq shapeinfo
        (vlax-create-object
            "PSCOMWRAPPER.Ks_ComShapeInfo"
        )
    )

    (vlax-invoke
        shapeinfo
       'SetObject
        pile
    )

    (vlax-invoke
        shapeinfo
       'Getinfo
    )

    (setq result

        (if
       
            ;;  determine type of pile ...

            (<
                (apply 'distance
                    (mapcar
                       '(lambda (p) (list (car p) (cadr p)))
                        (setq points
                            (mapcar
                               '(lambda (x) (vlax-get shapeinfo x))
                               '(MidLineStart MidLineEnd)
                            )
                        )

                    )
                )
                0.001
            )

            ;;  it's a normal pile, get the highest z value   

            (apply 'max (mapcar 'last points))

            ;;  it's a battered pile, get the normalized z value
            ;;           
            ;;  see image at:
            ;;           
            ;;      http://www.theswamp.org/screens/mp/batteredpile.png
            ;;           
            ;;  ASCII representation is idealized elevation, side ab
            ;;  is the CL of the pile; p1 = point a, p2 = point b.
            ;;
            ;;             elev               
            ;;            ------ + b (p2)
            ;;                  /|\
            ;;                 / | \     
            ;;                /  |  \     result
            ;;               / e +---+ d --------
            ;;              /    |
            ;;      (p1) a +-----+ c
            ;;
            ;;  Angles in representation are not proportionate: Angle
            ;;  a-b-d = 90, whereas angle e-b-d equals angle c-a-b.
            ;;
            ;;  Side bd is the radius of the pile.
            ;;
            ;;  Elevation at point 'e' is the desired result.

            (   (lambda ( p1 p2 radius)
                    (-  (apply 'max (mapcar 'last (list p1 p2)))
                        (*  radius
                            (/  (distance p1 (list (car p2) (cadr p2)))
                                (distance p1 p2)
                            )
                        )
                    )
                )
                (car points)   
                (cadr points)
                (/ (vlax-get pile 'Width) 2.0)
            )   
        )   
    )               

    (vlax-release-object shapeinfo)

    result

)

[Kerry]

interesting word, 'weiner' 'wiener'

[MP]

interesting word, 'weiner' 'wiener'

Steady fella, I meant it in the context of 'HotDogs'; i.e. "someone who
performs dangerous stunts to attract attention to himself". Not #3.

[CADaver]

haven't looked at the code, but you do realize that the elevation of point D is the same as point E?

[MP]

you do realize that the elevation of point D is the same as point E?

I do. Are you saying you know a more efficient way than ...

Code: [Select]

(-  (apply 'max (mapcar 'last (list p1 p2)))
    (*  radius
        (/  (distance p1 (list (car p2) (cadr p2)))
            (distance p1 p2)
        )
    )
)
... to get the cutoff elevation given only (3D) points A, B and the pile radius?



{ Subtitle: If so please share. }