Topic: Storing notes in a dwg

[SMadsen]

Glad if you can use it, Mark

[Mark]

OK...... I'm stuck! Using your example Stig, I get "error: bad DXF group: (CONS 300 DATE)" in the following code. What am i missing?

Code: [Select]


(setq date (rtos (getvar 'cdate) 2 4))
(setq note (getstring T "\nEnter note: "))
        (setq anXrec (entmakex '((0 . "XRECORD")
                                (100 . "AcDbXrecord")
                                (cons 300 date)
                                (cons 301 note)
                                )
                     )
        )


the DXF group codes state

1–369 (except 5 and 105)
 These values can be used by an application in any way

that is under "Object" -> "XRECORD"

[SMadsen]

Mark, try without quoting the arg to ENTMAKEX

[Mark]

you mean like this;

Code: [Select]


(setq anXrec (entmakex ((0 . "XRECORD")
                                (100 . "AcDbXrecord")
                                (cons 300 date)
                                (cons 301 note)
                                )
                     )
        )


I get "error: bad syntax of function call: (0 . "XRECORD")"

[SMadsen]

No no, ...  (list '(0 . "XRECORD")....(cons 300 date)..etc..)

In the example on Afralisp, I only used hardcoded values and could therefore quote the entire list. You are evaluating some of the values so you need to build the list with LIST

[Mark]

thanks Stig. I just got this to work before I read you post. It seems to work

Code: [Select]


(setq date (rtos (getvar 'cdate) 2 4))
(setq note (getstring T "\nEnter note: "))
(setq lst
  (list '(0 . "XRECORD")
'(100 . "AcDbXrecord")
(cons 300 date)
(cons 301 note)
)
 )
        (setq anXrec (entmakex lst))


[Mark]

OK, this is what I have thus far. It will create a dictionary named NOTES_DICT then store xrecords incremented by one starting at one. I haven't got to the reading part yet.  

comments .......... please!

Code: [Select]


(defun get-or-create-Dict (/ adict)

  (if (not (setq adict (dictsearch (namedobjdict) "NOTES_DICT")))
    (progn
      (setq adict (entmakex '((0 . "DICTIONARY")(100 . "AcDbDictionary"))))
      (if adict (setq adict (dictadd (namedobjdict) "NOTES_DICT" adict)))
      )
    (setq adict (cdr (assoc -1 adict)))
    )
  )

(defun get-next-record (/ adict rec cntr)
  (setq adict (get-or-create-Dict)
cntr  "1"
)

  (if (dictsearch adict cntr)
    (while (setq rec (dictsearch adict cntr))
  (setq cntr (itoa (1+ (atoi cntr))))
  )
    )
  cntr
  )

(defun get-or-make-Xrecord (date note cnt / adict date note anXrec)
  (cond
    ((setq adict (get-or-create-Dict))
     (cond
       ((not (setq anXrec (dictsearch adict cnt)))
(setq anXrec
     (entmakex
(list
 '(0 . "XRECORD")
 '(100 . "AcDbXrecord")
 (cons 300 date)
 (cons 301 note)
 )
)
     )
(if anXrec (setq anXrec (dictadd adict cnt anXrec)))
)
       (setq anXrec (cdr (assoc -1 (dictsearch adict cnt))))
       )
     )
    )
  )

(defun add-rec (/ date note recnum)
  (setq date (rtos (getvar 'cdate) 2 4))

  (if (setq note (getstring T "\nEnter note: "))
    (if (setq recnum (get-next-record))
      (get-or-make-Xrecord date note recnum)
      )
    )
  )


[SMadsen]

Excellent

I was just putting together some functions you might use but seems you've covered it already. Now that they're already written I might as well post them, though.

Code: [Select]

(defun get-or-create-Dict (name / myDict dict)
  (setq myDict (dictsearch (namedobjdict) name))
  (or (setq myDict (cdr (assoc -1 myDict)))
      (and (setq dict '((0 . "DICTIONARY") (100 . "AcDbDictionary")))
           (setq myDict (entmakex dict))
           (setq myDict (dictadd (namedobjdict) name myDict))
      )
  )
  myDict
)

(defun create-xNote (date txt xname / myDict xdat xrec)
  (and (setq myDict (get-or-create-Dict "MARK_NOTES"))
       (not (dictsearch myDict xname))
       (setq xdat (list '(0 . "XRECORD")
                        '(100 . "AcDbXrecord")
                        (cons 300 date)
                        (cons 301 txt)
                  )
       )
       (setq xrec (dictadd myDict xname (entmakex xdat)))
  )
  xrec
)

(defun get-all-xNotes (/ xnote myDict xnotes)
  (and (setq myDict (get-or-create-Dict "MARK_NOTES"))
       (while (setq xnote (dictnext myDict (not xnote)))
         (setq xnotes (cons xnote xnotes))
       )
  )
  xnotes
)

(defun get-all-xNames (/ myDict dict xnames)
  (and (setq myDict (get-or-create-Dict "MARK_NOTES"))
       (setq dict (entget myDict))
       (while (setq dict (member (assoc 3 dict) dict))
         (setq xnames (cons (cons (cdar dict) (cdadr dict)) xnames)
               dict   (cdr dict)
         )
       )
  )
  xnames
)

(defun parse-all-xNotes (/ xnotes xrec)
  (foreach n (get-all-xNames)
    (setq xrec (entget (cdr n)))
    (setq xnotes (cons
             (list (cons 2 (car n)) (assoc 300 xrec) (assoc 301 xrec))
             xnotes
           )
    )
  )
)

[Mark]

OH YEA....... thank you Mr. Madsen.

[Mark]

Code: [Select]

(cons (cons (cdar dict) (cdadr dict))
easy for you to say ............... whoa.

[SMadsen]

LOL

(cons (cdr (car dict))(cdr (cadr dict))) .. is that better?

(setq cntr (itoa (1+ (atoi cntr)))) ??

^You should talk! heh

[Mark]

>(cons (cdr (car dict))(cdr (cadr dict))) .. is that better?
much better, I can actually understand that. <g>

[Mark]

Wanna "encrypt" it? I've got that string->binary representation progy. (It converts bothways.)

break it out man............

[JohnK]

Your ready already hugh? Alright, let me see if i can locate the right version. (I did it before i started using the new dir strusture and well i got crap all over the place since i moved all the files into the new struct. )

Ill get on it and post it.

[Mark]

this is a very rough version, but it works.
http://www.theswamp.org/swamp.files/mark/xNotes.lsp

I noticed when I ran this routine my cpu usage went up about 50% for the acad.exe until I saved the dwg. Could someone verify this?