Topic: entmake/ActiveX race

[SMadsen]

Daron, changed your function so that it works with ready-built values, and moved the timer functions outside so that function calls are the same (outside the stack):

Code: [Select]

(defun startTimer () (setq time (getvar "DATE")))

(defun endTimer (func)
  (setq time    (- (getvar "DATE") time)
        seconds (* 86400.0 (- time (fix time)))
  )
  (gc)
  (outPut seconds func)
)

(defun outPut (secs def)
  (gc)
  (princ (strcat "\nTimed " def ": " (rtos secs 2 6)))
  (princ)
)
(defun instest (/ ms ins)
  (setq ms  (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
        ins (vlax-3d-point 0.0 0.0 0.0)
  )
  (startTimer)
  (repeat 1000
    (vla-InsertBlock
      ms ins "circ" 1.0 1.0 1.0 0.0)
  )
  (endTimer "instest")
)

With this, I get an average of 1.29 (a few runs in fresh drawings). The entmake equivalent runs an average of 0.80 here (again, few runs in fresh drawings).
That's a 60% difference, more or less.

[daron]

Thank you Stig. I can't believe the difference adding variables makes. I would've thought adding variables would slow things down.  Here's the last run using my Stig-modified function.
0.984988

I am using 2004. It seems to be slower than 2002, but all were tested off my machine in 2004.

[SMadsen]

I would've thought adding variables would slow things down.

You mean getting dressed, starting the car, driving to the grocery, finding a free parking slot, locate a bag of salt on the shelves, standing in line until it's your turn to pay, starting the car, driving home, opening the bag of salt and filling the shaker would be faster than reaching out and grab a readily filled salt shaker on the kitchen table top?

[daron]

Thanks for the visual Stig. So, settings variables invariably speeds things up, huh? Man, I still have so much to learn.

[CAB]

Hey that's even faster

Command: TIMER
Timed instest: 0.361012
Command:
Command: TIMER
Timed instest: 0.380002
Command:
Command: TIMER
Timed instest: 0.401004
Command:
Command: TIMER
Timed instest: 0.419994
Command:
Command: TIMER
Timed instest: 0.421000
Command:
Command: TIMER
Timed instest: 0.399998
Command:
Command: TIMER
Timed instest: 0.410981
Command:
Command: TIMER
Timed instest: 0.431018
Command:
Command: TIMER
Timed instest: 0.440030
Command:
Command: TIMER
Timed instest: 0.460991
Command:
Command: TIMER
Timed instest: 0.470003
Command:
Command: TIMER
Timed instest: 0.480987
Command:
Command: TIMER
Timed instest: 0.501023

[daron]

That is far quicker, but man that entmake runs circles (no pun intended) around ActiveX.

[SMadsen]

CAB, makes me feel better to see that a pc way way superior to mine also shows signs of slowing down eventually  Thanks!

[SMadsen]

Heh  nice choice of words
How about trying AddInsert in its native environment, VBA, and compare it to ENTMAKE in it's native environment?
ActiveX is still just an interface to AutoLISP. It's glue, not core.

[daron]

That's a good idea. I'll have to try and create this function in vba. It may not be pretty, but I'll give it a shot. Maybe I can get some help writing it from the veebeeaye forum if I need it, or maybe they can help me improve it when I get it as far as I can.

[ronjonp]

Here is Stigs results on my computer:

Timed instest: 7.889999

Here is Daron's results on my computer:

Timed instest: 8.170988

Good? Bad?

[SMadsen]

I think you tested only one function?

^Is why the EndTimer function ends with an identifier string.

[Mark]

I tried one more function, vlax-invoke-method and the results......

One dwg, each one ran once.

Command: (instest1)
Timed instest1: 0.484970
Command: (instest2)
Timed instest2: 0.749986
Command: (inscircle)
Timed insCircle: 0.312008

Code: [Select]

;; Darons modified by Stig
(defun startTimer () (setq time (getvar "DATE")))

(defun endTimer (func)
  (setq time       (- (getvar "DATE") time)
        seconds (* 86400.0 (- time (fix time)))
        )
  (gc)
  (outPut seconds func)
  )

(defun outPut (secs def)
  (gc)
  (princ (strcat "\nTimed " def ": " (rtos secs 2 6)))
  (princ)
  )
(defun instest1 (/ ms ins)
  (setq ms  (vla-get-modelspace
              (vla-get-activedocument (vlax-get-acad-object))
              )
        ins (vlax-3d-point 0.0 0.0 0.0)
        )
  (startTimer)
  (repeat 1000
    (vla-InsertBlock ms ins "circ" 1.0 1.0 1.0 0.0)
    )
  (endTimer "instest1")
  )


;; Stigs
(defun insCircle (/ bname)
  (setq bname "circ")
  (startTimer)
  (repeat 1000
    (entmake (list '(0 . "INSERT")
                   '(100 . "AcDbEntity")
                   '(100 . "AcDbBlockReference")
                   (cons 2 "circ")
                   (cons 8 "0")
                   '(10 0.0 0.0 0.0)
             )
    )
  )
  (endTimer "insCircle")
)

;; Darons modified by Stig modified by Mark
(defun instest2 (/ ms ins)
  (setq ms  (vla-get-modelspace
              (vla-get-activedocument (vlax-get-acad-object))
              )
        ins (vlax-3d-point 0.0 0.0 0.0)
        )
  (startTimer)
  (repeat 1000
          (vl-catch-all-apply
            '(vlax-invoke-method ms 'InsertBlock ins "circ" 1.0 1.0 1.0 0.0)
            )
          )
  (endTimer "instest2")
  )


[daron]

So, the moral of this story is:
Entmake - tried and true for lisp.
ActiveX - go glue. We'll see how the core does soon enough. Working on the vba timer function. Currently, it runs faster than anything else I've tried.
vlax - don't invoke method.

[SMadsen]

Cool

[daron]

Here's the vba version. SCMDave helped and finished it up.

Code: [Select]

Public Function InsertTest()
  Dim i As Integer
  Dim StartTime As Variant
  Dim EndTime As Variant
 
  Dim lngStart As Long
  Dim lngEnd As Long
  Dim InsPt(0 To 2) As Double
  Dim mspace As AcadModelSpace
  Set mspace = ThisDrawing.ModelSpace
 
  StartTime = ThisDrawing.GetVariable("DATE")
 
  'lngStart = GetTickCount

  For i = 1 To 1000
    mspace.InsertBlock InsPt, "Circ", 1, 1, 1, 0
  Next i
  EndTime = ThisDrawing.GetVariable("DATE")
 
  'lngEnd = GetTickCount
  MsgBox "Total Time = " & CStr((EndTime - StartTime) * 86400)

End Function
My time came in at almost one second. All testers, put it in a module and run it and record your times here. Thanks.