Topic: Mview question

[MSTG007]

Is there a way to lock all mviews in the dwg tabs (several) in one dwg at one time?

rather than going into each layout tab and turning it on and off?

thanks

[ELOQUINTET]

this is about the best i can do. it doesn't work across layouts but it cuts out some steps. make a button and put this in

^C^CMV;L;ON;ALL


if you find a way lemme know

[MSTG007]

bingo... will do

[CADaver]

I think I got this from someone here:

Code: [Select]


;;MVIEW HIDE IN ALL LAYOUTS
(defun c:MVH(/ THISTAB VPLST)
  (setq THISTAB (getvar "CTAB"))
  (foreach LAYOUT (layoutlist)
    (setvar "CTAB" LAYOUT)
    (setq vplst (ssget "x" (list (cons 0 "viewport"))))
    (command "mview" "hide" "on" VPLST ""))
  (setvar "CTAB" THISTAB)
  (princ)
)

;;MVIEW LOCK IN ALL LAYOUTS
(defun c:MVLO(/ THISTAB VPLST)
  (setq THISTAB (getvar "CTAB"))
  (foreach LAYOUT (layoutlist)
    (setvar "CTAB" LAYOUT)
    (setq vplst (ssget "x" (list (cons 0 "viewport"))))
    (command "mview" "LOCK" "on" VPLST ""))
  (setvar "CTAB" THISTAB)
  (princ)
)

;;MVIEW UNLOCK IN ALL LAYOUTS
(defun c:MVU(/ THISTAB VPLST)
  (setq THISTAB (getvar "CTAB"))
  (foreach LAYOUT (layoutlist)
    (setvar "CTAB" LAYOUT)
    (setq vplst (ssget "x" (list (cons 0 "viewport"))))
    (command "mview" "LOCK" "off" VPLST ""))
  (setvar "CTAB" THISTAB)
  (princ)
)


[Jeff_M]

Here's a couple that affect ALL PS viewports without switching Tabs while doing it. Much faster, especially with lots of tabs.

Code: [Select]


(defun c:lockallVP ()
  (vl-load-com)
  (ssget "x" '((0 . "VIEWPORT")))
  (vlax-for item (vla-get-activeselectionset
  (vla-get-activedocument
    (vlax-get-acad-object)))
    (vla-put-displaylocked item :vlax-true)
    )
  )
(defun c:unlockallVP ()
  (vl-load-com)
  (ssget "x" '((0 . "VIEWPORT")))
  (vlax-for item (vla-get-activeselectionset
  (vla-get-activedocument
    (vlax-get-acad-object)))
    (vla-put-displaylocked item :vlax-false)
    )
  )


Jeff

[MSTG007]

WONDERFUL!  yes wonderful!   thank you:)