Topic: Select sets variables [reference type]- an FYI

[T.Willey]

Selection set variables are set to the same object in memory.  Maybe some code might explain it better.  I just learned this today so I thought I would share.

Code: [Select]

(
 (lambda (/ ss ss1)
  (setq ss (ssget))
  (setq ss1 ss)
  (print (sslength ss))
  (print (sslength ss1))
  (ssdel (ssname ss 0) ss)
  (print (sslength ss))
  (print (sslength ss1))
  (princ)
 )
)


19
19
18
18

I didn't think this would happen, but after doing some coding in C# it seems that the variables 'ss' and 'ss1' are reference variables.  The both reference the same block of memory.

If anything I have stated is wrong, please let me know.

[MP]

True story and good observation Tim. It's also why when you pass a selection set to a function you have to be careful (because it's treated as a reference).

Brief illumination:

Code: [Select]

(   (lambda ( / foo ss )

        (defun foo ( ss )
            (if (and
                    (eq 'pickset (type ss))
                    (< 0 (sslength ss))
                )
                (ssdel (ssname ss 0) ss)
            )
        )

        (if (setq ss (ssget "x"))

            (progn

                (princ
                    (strcat
                        "Selection set ss's length before (foo ss): "
                        (itoa (sslength ss))
                        "\n"
                    )   
                )

                (foo ss)

                (princ
                    (strcat
                        "Selection set ss's length after (foo ss): "
                        (itoa (sslength ss))
                        "\n"
                    )   
                )
            )
           
            (princ "Errrm, try this in a dwg with some entities.")
           
        )

        (princ)

    )
)
Not suggesting you don't know this Tim; it's for the benefit of those that might not.

[T.Willey]

True story and good observation Tim. It's also why when you pass a selection set to a function you have to be careful (because it's treated as a reference).

Brief illumination:

Code: [Select]

<snip>
Not suggesting you don't know this Tim; it's for the benefit of those that might not.

Thanks for that Michael.  I didn't even think of that, but it makes good sense when I do. 

Glad to see you posting again, hope all is/was well and good with you.