Topic: A diversion for the recreationally challenged.

[Kerry]

I remember spending about 20 min trying to figure out the syntax for ACET-STR-FORMAT.

Side note: The bad thing about having a wireless mouse is that there is no cable to rip out when you're frustrated.

at least that one (ACET-STR-FORMAT) is listed in acetutil.chm

[JohnK]

idea?

Everyone pick a util and write a replacement?

[alanjt]

idea?

Everyone pick a util and write a replacement?

I like the idea.

[Lee Mac]

idea?

Everyone pick a util and write a replacement?

I like the idea.

My lame attempt from last year some time:

http://www.theswamp.org/index.php?topic=28895.0

[Oak3s]

Great idea!
I will watch

[Lee Mac]

Was bored, so here is my quick version of acet-ss-zoom-extents  

Code: [Select]

(defun swamp-ss-zoom-extents ( ss / bb )
  ;; © Lee Mac 2010

  ;; (swamp-ss-zoom-extents <SelectionSet>)
  ;; Purpose: Zooms to the Extents of a SelectionSet
  ;; Arguments:
  ;; ss: SelectionSet
  ;; Returns:  
  ;; List of LowerLeft, UpperRight of SSBoundingBox
  
  (
    (lambda ( i / e ll ur )
      (while (setq e (ssname ss (setq i (1+ i))))
        (vla-getBoundingBox (vlax-ename->vla-object e) 'll 'ur)

        (setq bb (cons (vlax-safearray->list ll)
                       (cons (vlax-safearray->list ur) bb))
        )
      )
    )
    -1
  )
  (
    (lambda ( result )
      (apply 'vla-ZoomWindow (cons (vlax-get-acad-object) (mapcar 'vlax-3D-point result)))
      result
    )
    (mapcar
      (function
        (lambda ( operation ) (apply 'mapcar (cons operation bb)))
      )
     '(min max)
    )
  )
)
And perhaps acet-ss-to-list (yeah I'm just picking the easier ones!)

Code: [Select]

(defun swamp-ss-to-list ( ss )
  ;; © Lee Mac 2010

  ;; (swamp-ss-to-list <SelectionSet>)
  ;; Purpose: Returns list of entity names contained in a SelectionSet
  ;; Arguments:
  ;; ss: SelectionSet
  ;; Returns:
  ;; List of Entity Names

  (
    (lambda ( i / e l )
      (reverse
        (while (setq e (ssname ss (setq i (1+ i))))
          (setq l (cons e l))
        )
      )
    )
    -1
  )
)
Couldn't resist these three:

Code: [Select]

;; (swamp-dtor <degrees>)
;; Purpose: Converts Degrees to Radians
;; Arguments:
;; d: Real Number representing an angle in Degrees
;; Returns:
;; Real Number representing an angle in Radians

(defun swamp-dtor ( d ) (* pi (/ d 180.0)))


Code: [Select]

;; (swamp-rtod <radians>)
;; Purpose: Converts Radians to Degrees
;; Arguments:
;; r: Real Number representing an angle in Radians
;; Returns:
;; Real Number representing an angle in Degrees

(defun swamp-rtod ( r ) (* 180.0 (/ r pi)))


Code: [Select]

;; (swamp-dxf <key> <elist>)
;; Purpose: Returns the association of key in a dxf association list
;; Arguments:
;; key: integer
;; elist: dxf association list (as returned by entget)

(defun swamp-dxf ( key elist ) (cdr (assoc key elist)))


Code: [Select]

;; (swamp-ss-redraw <SelectionSet> <Mode>)
;; Purpose: Redraws the supplied SelectionSet
;; Arguments:
;; ss  : SelectionSet
;; mode: redraw mode (1=show, 2=hide, 3=highlight, 4=unhighlight)
;; Returns: nil

(defun swamp-ss-redraw ( ss mode )
  (
    (lambda ( i / e )
      (while (setq e (ssname ss (setq i (1+ i))))
        (redraw e mode)
      )
    )
    -1
  )
)

[Oak3s]

I didnt look up what the added benefit would be to use acet-ss-zoom-extents so this question might be unreasonable but:
Could any alternatives be presented with some sort of documentation explaining what it does, returns...and maybe how...as this is the frustration with acet***...lack of documentation. At least that is my frustration.

*Edited by Oak3s 11.5.10
Thank you Lee for the documentation!!!

[Lee Mac]

I didnt look up what the added benefit would be to use acet-ss-zoom-extents so this question might be unreasonable but:
Could any alternatives be presented with some sort of documentation explaining what it does, returns...and maybe how...as this is the frustration with acet***...lack of documentation. At least that is my frustration.

Haha true, I still haven't give any documentation 

[Oak3s]

After reading what I posted I want to just make the comment that I appreciate all the help and knowledge that has been given/shared on this forum. Lee, I have read and followed much of your material and would not want in anyway to ask for more without you and others knowing that what has been presented is a gift and received as such. By asking for more I am in no way down playing the efforts that were put forth. Thank you very much...all of you.

[Lee Mac]

After reading what I posted I want to just make the comment that I appreciate all the help and knowledge that has been given/shared on this forum. Lee, I have read and followed much of your material and would not want in anyway to ask for more without you and others knowing that what has been presented is a gift and received as such. By asking for more I am in no way down playing the efforts that were put forth. Thank you very much...all of you.

You're very welcome Oak3s, I'm glad that you can benefit from the stuff I post 

Don't worry, I wouldn't write this stuff if I didn't enjoy it 

[alanjt]

Don't worry, I would write this stuff if I didn't enjoy it 

lol

[Oak3s]

I caught that too. 

[Lee Mac]

Don't worry, I would write this stuff if I didn't enjoy it 

lol

Hahahaha 

[T.Willey]

Maybe the library should have a different prefix?  Maybe instead of ' acet ' use ' swamp ', or something.   

[Kerry]

yeah,
the same with using VLA- for home built methods ... confuses me.