Topic: Delete Item from a block

[hudster]

How can I delete items nested in blocks without using refedit?

I need to delete some hatches and wipeouts from about 1600 blocks.

Cheers for any help

[T.Willey]

Here is one way.

Code: [Select]

(defun c:EraseObjectFromBlock (/ ActDoc BlkCol Sel Ent)
; Erase object selected from block, in block collection, so all blocks will update.

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vla-EndUndoMark Actdoc)
(vla-StartUndoMark ActDoc)
(setq BlkCol (vla-get-Blocks ActDoc))
(setvar "errno" 0)
(while (not (equal (getvar "errno") 52))
 (if
  (and
   (setq Sel (nentsel "\n Select nested object to erase from block: "))
   (> (length Sel) 2)
   (not
    (vl-position
     nil
     (mapcar
      '(lambda (x / BlkName BlkObj)
       (setq BlkName (cdr (assoc 2 (entget x))))
       (and
        (not (vl-catch-all-error-p (setq BlkObj (vl-catch-all-apply 'vla-Item (list BlkCol Blkname)))))
        (= (vla-get-IsXref BlkObj) :vlax-false)
        (= (vla-get-IsLayout BlkObj) :vlax-false)
       )
      )
      (last Sel)
     )
    )
   )
   (/= (cdr (assoc 0 (entget (setq Ent (car Sel))))) "ATTRIB")
  )
  (progn
   (vla-Delete (vlax-ename->vla-object Ent))
   (vla-Regen ActDoc acActiveViewport)
  )
  (prompt "\n Object selected can not be erased with this command.")
 )
)
(vla-EndUndoMark ActDoc)
(princ)
)


[whdjr]

Are there 1600 different blocks or just 1600 that need to be updated?
Are they all in one file or in differnt files? 

[hudster]

each wall is an individual block, with a hatch and a wipeout in each one, I could explode them but I prefer to leave as much of the drawing unaltered as possible.

I want to be able to select an item, hatching for example, and then delete it from a selection set I've made.

Cheers for the lisp T.Willey, that does what i need it to do, but it's the long way, if that could be modified so that when I select an object in a block, say a hatch, it then deletes that hatch from all the blocks in the drawing, it would be perfect.

[Arizona]

What is unique/consistant about these hatch objects?
Are they a specific style, or on a specific layer?
Is there other hatching in the drawing?
Is this all in one block or many blocks?

Sorry for all the questions, I'm just trying to get a better idea of what you are doing...

[hudster]

Every wall is a block, consisting of two outside lines, two internal lines, 3 hatches and a wipeout.
Every wall is a unique block.
There is hatching in the windows as well, but not so much as in the walls.
The unique/consistent things about the hatches is that they are all on layer 0 and use the same hatch styles.

[whdjr]

When you say every wall is unique does that mean that you created the walls or they are like dynamic blocks where they an anonymous name?  Because even though DBs have an anonymous name they all still have an .effectivename'.

[hudster]

It's an architects drawing, and every wall is called wall001, wall002 etc etc, for 1600 walls. The same with every entity on the drawing, toilet001, toilet002 etc etc.

He doesn't use autoCAD so it probably makes sense with his system, but looks nuts to me.

[whdjr]

If all these hatches are on the same layer you could try the ExpressTools command 'laydel',it deletes everything a selected layer and purges it from the dwg.  It says it works in blocks too.

[hudster]

The hatches are all on the same layer as the walls, unfortunately.

Thanks for the help though.

I think it'll need a lisp to delete all the hatches from the drawing.

[CAB]

So collect all the wall blocks (ssget "x" '((2 . "WALL*")))
Loop through each block
Look at each entity for hatch with matching pattern, collect the ename
Delete the ename from the block

Sounds simple enough.

[hudster]

OK.

I could do the first bit, but you did that for me here, but the rest is a mystery.

can you give me a few pointers.

[T.Willey]

OK.

I could do the first bit, but you did that for me here, but the rest is a mystery.

can you give me a few pointers.

You wouldn't really do it the way Alan says.  You want to search the block definitions, and then delete the object for there.  I think it is easier to go the ActiveX route with this.  To step through the block collection for the current drawing you would do

Code: [Select]

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vlax-for Blk (vla-get-Blocks ActDoc)
 ....
)
This is saying that you want to search all blocks in the block collection.

While you are searching the blocks collection, you want to search each blocks definition, so you would do that like

Code: [Select]

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vlax-for Blk (vla-get-Blocks ActDoc)
 (if (wcmatch (strcase (vla-get-Name Blk)) "WALL*")
  (vlax-for Obj Blk
   ....
  )
 )
)
This is saying that you want to search all objects that make up the blocks definition if the name of the blocks starts with the characters "WALL".

Now you want to test the object to see if it is a wipeout or a hatch pattern, and if so delete them

Code: [Select]

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vlax-for Blk (vla-get-Blocks ActDoc)
 (if (wcmatch (strcase (vla-get-Name Blk)) "WALL*")
  (vlax-for Obj Blk
   (if
    (or
     (= (vla-get-ObjectName Obj) "AcDbHatch")
     (= (vla-get-ObjectName Obj) "AcDbWipeout")
    )
    (vla-Delete Obj)
   )
  )
 )
)

Now you want to put that into a function you can call from the command line, so add a defun to it (whatever you like, you can change the name)

Code: [Select]

(defun c:CleanUpBlocks (/ ActDoc)

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vlax-for Blk (vla-get-Blocks ActDoc)
 (if (wcmatch (strcase (vla-get-Name Blk)) "WALL*")
  (vlax-for Obj Blk
   (if
    (or
     (= (vla-get-ObjectName Obj) "AcDbHatch")
     (= (vla-get-ObjectName Obj) "AcDbWipeout")
    )
    (vla-Delete Obj)
   )
  )
 )
)
(princ)
)
To use ActiveX controls you have to have

Code: [Select]

(vl-load-com)Somewhere that will get loaded into Acad at least once per session (if loaded more that once no big deal).

Hope that makes sense.


Edit: I guess you would want to make sure that the blocks you are trying to search are not a layout or an xref, to do so the code would change to look like

Code: [Select]

(defun c:CleanUpBlocks (/ ActDoc)

(setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
(vlax-for Blk (vla-get-Blocks ActDoc)
 (if
  (and
   (equal (vla-get-IsXref Obj) :vlax-false)
   (equal (vla-get-IsLayout Obj) :vlax-false)
   (wcmatch (strcase (vla-get-Name Blk)) "WALL*")
  )
  (vlax-for Obj Blk
   (if
    (or
     (= (vla-get-ObjectName Obj) "AcDbHatch")
     (= (vla-get-ObjectName Obj) "AcDbWipeout")
    )
    (vla-Delete Obj)
   )
  )
 )
)
(princ)
)

[CAB]

Tim,
I stand corrected, Nice example.
Using plain lisp would be messy at best.

[hudster]

When I try to run this lisp, i get an error message

; error: bad argument type: VLA-OBJECT nil

What am I doing wrong. I've typed in (vl-load-com) first but it makes no difference.