Topic: Helo me autoload lisp after modify

[vnanhvu]

Hi all !
I use 10 file Lisp. I appload them with remember history.

When i modify 1 file Lisp. How can you write a command to automatic reload this file lisp without use appload/content/remove. ( Only 1 command for update file Lisp ).

Thank you !

[bilançikur]

Maybe you can use AlanJT's code from over here:
http://forums.augi.com/showthread.php?101676-A-routine-that-loads-all-of-my-other-routines&p=977383&viewfull=1#post977383

Create your own function to quickly load (and thus reload) all lisp files in a dedicated folder.

[snownut2]

Are you using AutoCAD ?

Use VLIDE to edit and reload...

[CAB]

I'm always surprised when people don't use VLIDE.
It isn't the best editor but for debugging it can't be beat.

[bilançikur]

VLIDE would be the first choice, of course. But I have forgot about that because we use ZWCAD these days.
So always when I am editing lisp, I use NotePad++, hit ctrl+S to save and then switch bac to Cad and invoke the command to load all lisp in that folder.

[ChrisCarlson]

I could never get the hang of VLIDE, that lisp is genius though thanks for the suggestion.

[HasanCAD]

Is this a good solution?
Creating an intermediate lisp, So each time run the lisp will be loaded.

Code: [Select]

(defun c:lsp1  () (load "C:/Lisp/lsp1.lsp")  (c:/lsp1)  (princ))
(defun c:lsp2  () (load "C:/Lisp/lsp2.lsp")  (c:/lsp2)  (princ))
(defun c:lsp2  () (load "C:/Lisp/lsp3.lsp")  (c:/lsp3)  (princ))
...


[Kerry]

HasanCaD,

Your method is great for the initial load of a routine, I won't work to re-load a revised file though because the command definition will point to the currently loaded code.

I don't think you meant to have the forwardSlash in the command name ?? 

[snownut2]

How about the drag and drop method, drag the lisp file into the current cad window, it should reload...

[Lee Mac]

Here is another idea:

Code: [Select]

(defun load-if-modified ( lsp sym / itm )
    (if (setq lsp (findfile lsp))
        (progn
            (if (and (eval sym) (setq itm (assoc (strcase lsp) load-if-modified:data)))
                (if (equal (cdr itm) (vl-file-systime lsp))
                    (prompt "\nFile not modified.")
                    (progn
                        (prompt "\nFile modified - reloading...")
                        (setq load-if-modified:data
                            (subst
                                (cons (strcase lsp) (vl-file-systime lsp))
                                itm
                                load-if-modified:data
                            )
                        )
                        (load lsp nil)
                    )
                )
                (progn
                    (setq load-if-modified:data
                        (cons
                            (cons (strcase lsp) (vl-file-systime lsp))
                            load-if-modified:data
                        )
                    )
                    (prompt "\nFirst-time loading.")
                    (load lsp nil)
                )
            )
            (if (eval sym)
                ((eval sym))
                (prompt "\nFile not loaded or symbol not defined.")
            )
        )
        (prompt "\nFile not found.")
    )
    (princ)
)
Call with the LISP filename & command symbol, e.g.:

Code: [Select]

(load-if-modified "MyLISP.lsp" 'c:mycommand)